Discussion :

[spifspaf]

Bonjour à tous

étant totalement novice dans la matière je suis à la recherche d'un petit script en vbs ou autre capable de :

lancer une fenêtre ie ou firefox pointant sur un site ( ou une page )
et qui puisse la rafraichir toutes les x secondes

le but étant de récupérer une ip dynamique via une page sur un serveur web et de l'enregistrer dans une base de donnée pour ensuite la récupérer l'affichage et le stockage est fait via la page sur le web ( en php )

Merci par avance pour vos réponse et si vous avez une solution différente je suis preneur

[hackoofr]

et Bienvenue sur DVP
Un exemple de code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
Option Explicit
Dim Boucle,strComputer,MsgTitre,objPing,objStatus
Boucle = True
While Boucle = True
strComputer = "smtp.gmail.com"
MsgTitre = "TEST DE CONNEXION INTERNET ET SMTP DE GMAIL"
Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}!\\").ExecQuery("select * from Win32_PingStatus where address = '" & strComputer & "'")
For Each objStatus in objPing
If objStatus.Statuscode = 0 Then
msgbox "TEST SMTP DE GMAIL EST OK . VOUS ETES CONNECTE A INTERNET ET LE SMTP DE GMAIL EST DISPONIBLE ! " & objStatus.Statuscode,64,MsgTitre
Boucle = False
Call Ip_Publique
wscript.quit
else
msgbox "TEST SMTP DE GMAIL EST NO OK . VOUS N'ETES PAS CONNECTE A INTERNET ET LE SMTP DE GMAIL N'EST PLUS DISPONIBLE EN CE MOMENT !" & objStatus.Statuscode,16,MsgTitre
End If
Call ReNewLocalIP
Next
wscript.sleep 60000
Wend
 
Sub Ip_Publique
Dim Titre,URL,ie,objFSO,Data,OutPut,objRegex,Match,Matches
Titre = "Adresse Ip Publique !"
URL = "http://monip.org"
Set ie = CreateObject("InternetExplorer.Application")
Set objFSO = CreateObject("Scripting.FileSystemObject") 
ie.Navigate (URL) 
ie.Visible=false
DO WHILE ie.busy
wscript.sleep 100
LOOP
Data = ie.document.documentElement.innertext 
'MsgBox Data,64,Titre
Set OutPut = objfso.OpenTextFile("monip.txt",8,True)
ie.Quit 
Set ie = Nothing
Set objRegex = new RegExp
objRegex.Pattern = "\b([0-9]{1,3}\.){3}[0-9]{1,3}\b"
objRegex.Global = False
objRegex.IgnoreCase = True
Set Matches = objRegex.Execute(Data)
For Each Match in Matches   
    MsgBox "Mon IP Publique est : " & vbCr & Match.Value ,64,Titre
    OutPut.WriteLine string(40,"-") & vbcr &"  Nous sommes le "& Now & vbcr & string(40,"-") & vbcr & "  Mon IP Publique est : "& Match.Value & vbcr & string(40,"*")
Next
Call OpenLog("monip.txt")
End Sub
 
Sub OpenLog(File)
Dim ws
Set ws = CreateObject("wscript.shell")
ws.run "Notepad " & File,1,True
Set ws = Nothing
End Sub
 
Sub ReNewLocalIP
Dim Ws,command,StrCommand,Resultat
Set Ws = CreateObject("WScript.Shell")
command = "ipconfig /release & ipconfig /flushdns & ipconfig /renew"
StrCommand = "cmd /k "& command &""
Resultat = ws.Run(StrCommand,1,True)
End Sub

[spifspaf]

Merci pour la bienvenue

et merci pour le script j'en utilise une partie en fait qui correspond plus ou moins à ma recherche

Par contre il y a t'il un moyen de " timer " les msgbox ?

[ProgElecT]

Salut

Le principe (code récupéré sur ce site)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Set objShell = CreateObject("WScript.Shell")
i = 5
Do Until i = 0
   Btn = objShell.Popup("Décompteur" & vbNewLine & vbNewLine & I & vbNewLine, 5, i, 0+48+4096)
   If Btn = 1 Then
      Exit Do
   End If
   i = i -1
Loop

Pour ton besoin, objShell.Popup, tu ne le mes pas dans une boucle

[hackoofr]

Par contre il y a t'il un moyen de " timer " les msgbox ?

Qu'entendez-vous par Timer pour les MsgBox
Soyez plus explicite et détaillez votre problème pour bien comprendre votre requête

[spifspaf]

ben pour le timer c'est dans le but que la fenêtre du message affiché puisse se fermer après un décompte

genre sur le script du début de ce post si jamais il y a pas de connexion cela affiche
"TEST SMTP DE GMAIL EST NO OK . VOUS N'ETES PAS CONNECTE A INTERNET ET LE SMTP DE GMAIL N'EST PLUS DISPONIBLE EN CE MOMENT ! "
et si personne ne clique sur ok ben ça ne relance rien du tout !
Je recherche a automatiser cela de car le script sera placé sur un serveur "widaube" 2000 et personne n'ira cliquer dessus pour pouvoir exécuter la suite du script
.... après il me restera à trouver le moyen de le lancer toutes les 10mn

[ProgElecT]

Affiche du texte dans une fenêtre de message contextuelle.

intButton = object.Popup(strText,[nSecondsToWait],[strTitle],[nType])
Arguments
object
Objet WshShell.
strText
Valeur de chaîne contenant le texte que vous voulez faire apparaître dans une fenêtre de message contextuelle.
nSecondsToWait
Facultatif. Valeur numérique indiquant la durée maximale (en secondes) pendant laquelle vous voulez que la fenêtre de message contextuelle soit affichée.
strTitle
Facultatif. Valeur de chaîne contenant le texte que vous voulez voir apparaître comme titre de la fenêtre de message contextuelle.
nType
Facultatif. Valeur numérique indiquant le type de boutons et d'icônes que vous voulez voir dans la fenêtre de message contextuelle. Cela détermine la façon dont la fenêtre de message est utilisée.
IntButton
Nombre entier indiquant le nombre de boutons sur lesquels l'utilisateur a cliqué pour enlever la fenêtre de message. Il s'agit de la valeur renvoyée par la méthode Popup.
Notes
La méthode Popup affiche une fenêtre de message, quel que soit le fichier exécutable hôte en cours d'exécution (WScript.exe ou CScript.exe). Si nSecondsToWaitis équivaut à zéro (par défaut), la fenêtre de message contextuelle reste visible jusqu'à ce qu'elle soit fermée par l'utilisateur. Si nSecondsToWaitis est supérieur à zéro, la fenêtre de message contextuelle se ferme après nSecondsToWait secondes.

ligne 15 du code d' hackoofr

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
objShell.Popup "TEST SMTP DE GMAIL EST NO OK ." & vbNewLine _
	& "VOUS N'ETES PAS CONNECTE A INTERNET ET LE SMTP DE GMAIL N'EST PLUS DISPONIBLE EN CE MOMENT !", 6000,"Votre attention", 0+48+4096

Où trouver l'aide en ligne pour VBScript ?

[hackoofr]

Testez ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Option Explicit
Dim objShell,Boucle,strComputer,MsgTitre,objPing,objStatus,Wait
Set objShell = CreateObject("wscript.shell")
Wait = 5
Do
    strComputer = "smtp.gmail.com"
    MsgTitre = "TEST DE CONNEXION INTERNET ET SMTP DE GMAIL"
    Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}!\\").ExecQuery("select * from Win32_PingStatus where address = '" & strComputer & "'")
    For Each objStatus in objPing
        If objStatus.Statuscode = 0 Then
            objShell.Popup "TEST SMTP DE GMAIL EST OK . VOUS ETES CONNECTE A INTERNET ET LE SMTP DE GMAIL EST DISPONIBLE ! ",Wait,MsgTitre,0+64
            Call Ip_Publique
        else
            objShell.Popup "TEST SMTP DE GMAIL EST NO OK ." & vbNewLine _
            & "VOUS N'ETES PAS CONNECTE A INTERNET ET LE SMTP DE GMAIL N'EST PLUS DISPONIBLE EN CE MOMENT !",Wait,"Votre attention", 0+48
        End If
    Next
    Pause(10) 'Faire une pause de 10 Minutes
Loop
 
Sub Ip_Publique
    Dim Titre,URL,ie,objFSO,Data,OutPut,objRegex,Match,Matches
    Titre = "Adresse Ip Publique !"
    URL = "http://monip.org"
    Set ie = CreateObject("InternetExplorer.Application")
    Set objFSO = CreateObject("Scripting.FileSystemObject") 
    ie.Navigate (URL) 
    ie.Visible=false
    DO WHILE ie.busy
        wscript.sleep 100
    LOOP
    Data = ie.document.documentElement.innertext 
    Set OutPut = objfso.OpenTextFile("monip.txt",8,True)
    ie.Quit 
    Set ie = Nothing
    Set objRegex = new RegExp
    objRegex.Pattern = "\b([0-9]{1,3}\.){3}[0-9]{1,3}\b"
    objRegex.Global = False
    objRegex.IgnoreCase = True
    Set Matches = objRegex.Execute(Data)
    For Each Match in Matches   
        objShell.Popup "Mon IP Publique est : " & Match.Value ,Wait,Titre,0+64
        OutPut.WriteLine string(40,"-") & vbcr &"  Nous sommes le "& Now & vbcr & string(40,"-") & vbcr & "  Mon IP Publique est : "& Match.Value & vbcr & string(40,"*")
    Next
End Sub
 
Function Pause(NbMin)
    wscript.sleep NbMin*1000*60
End Function

[spifspaf]

Chalut

Merci hackoofr et ProgElecT

vraiment nikel pile au poil ce qu'il me faut

chez moi ça fonctionne bien .... je teste dés lundi sur le serveur

Merci encore à vous deux