Discussion :

[jack-ft]

Bonjour,
est-il possible avec "sed" de dupliquer chaque ligne et de faire une substitution différente sur chacune des 2 copies?
Exemple. Mon fichier d'entrée contient:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
A=B
C=D
E=F

Je veux transformer un coup le "=" en "x=x" et un autre coup en "y=y" de manière à obtenir:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Ax=xB
Ay=yB
Cx=xD
Cy=yD
Ex=xF
Ey=yF

Si c'est trop compliqué en "sed", je passerai à "awk".
Merci d'avance
)jack(

[zipe31]

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
$ cat plop
A=B
C=D
E=F
 
$ sed 's/=/x&x/;h;s/x/y/g;H;g' plop 
Ax=xB
Ay=yB
Cx=xD
Cy=yD
Ex=xF
Ey=yF
 
$

[jack-ft]

Pas mal... et carrément top rapide!
En fait, les 2 substitutions indiquées ne sont qu'un exemple.
Si la 2ème substitution est trop difficile à faire après l'exécution de la 1ère, est-il possible de "mémoriser/rappeler" la ligne originale pour lui appliquer la 2ème substitution seule?
ou, dit autrement, quelle combinaison de "h" "H" ou je ne sais trop quoi faut-il mettre autour de s/=/x&x/ et s/=/y&y/ pour arriver au même résultat?

[zipe31]

Si la 2ème substitution est trop difficile à faire après l'exécution de la 1ère, est-il possible de "mémoriser/rappeler" la ligne originale pour lui appliquer la 2ème substitution seule?
ou, dit autrement, quelle combinaison de "h" "H" ou je ne sais trop quoi faut-il mettre autour de s/=/x&x/ et s/=/y&y/ pour arriver au même résultat?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
$ sed 'h;s/=/x&x/;x;s/=/y&y/g;H;g' plop 
Ax=xB
Ay=yB
Cx=xD
Cy=yD
Ex=xF
Ey=yF
 
$

Ou :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
$ sed 'h;s/=/x&x/;x;s/=/y&y/g;x;G' plop 
Ax=xB
Ay=yB
Cx=xD
Cy=yD
Ex=xF
Ey=yF
 
$

[zipe31]

Les explications :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
h      
On sauvegarde une copie dans la mémoire secondaire
                                
s/=/x&x/      
On modifie l'original
                         
x      
On échange le contenu des mémoires
                                
s/=/y&y/g         
On modifie la copie
                     
H            
On ajoute le contenu de la mémoire principale au contenu de la mémoire secondaire
                          
g
Et on écrase le contenu de la mémoire principale avec le contenu de la mémoire secondaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
h    
On sauvegarde une copie dans la mémoire secondaire
                                  
s/=/x&x/      
On modifie l'original
                        
x      
On échange le contenu des mémoires
                                
s/=/y&y/g      
On modifie la copie
                        
x   
On échange à nouveau le contenu des 2 mémoires
                                   
G 
Et on ajoute le contenu de la mémoire secondaire à la principale.

[jack-ft]

Les explications :
snip

Magnifique!
Je vérifie les contraintes habituelles (le "sed" d'AIX n'aime pas les ";")
et j'ai plus qu'à faire rentrer mon bazar là-dedans!

)jack(

PS: je vous dis pas le nombre de posts de zipe31 que j'ai ajoutés dans mon dossier de bookmarks "sed hints".
Encore merci pour toutes ces précieuses explications!
Si quelqu'un a un jour le courage de regrouper tous ces "plop", qu'il n'hésite pas!
Une collection de petits exemples est parfois plus intéressante qu'un tutoriel (pour les gens pressés... (et qui ne l'est pas?))