Discussion :

[johnVSsmith]

Bonjour à tous,

Je suis débutant en Flash et je rencontre un petit soucis.

Je travaille avec Flash CS5.5 en version d'évaluation.

A partir d'un champ caméra, je voudrais photographier ce que l'on voit depuis la caméra dans un objet bitmapdata. Ceci fonctionne bien, mais la fonction draw affiche une image de 160x120 alors que je voudrais qu'elle fasse 640x480.

Je ne sais si la taille de l'objet vidéo sur la scène a une importance, mais je l'ai mis à 320x240.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
//paramètres
Stage.scaleMode = "noScale";
Stage.align = "";
System.showSettings(0);
 
import flash.display.BitmapData;
 
//attache le flux video
localCamera = Camera.get();
myCam.attachVideo(localCamera);
myCam.setMode(640,480,15);
 
var bitmap = new flash.display.BitmapData(640, 480, false, 0x00000000);
this.createEmptyMovieClip("copie", 2);
copie.attachBitmap(bitmap, 2, "auto", true);
copie._x = 200;
 
// dessine l'image
btn.onRelease = function() {
	bitmap.draw(myCam);
};

Si quelqu'un pourrait m'aider, merci d'avance

[headmax]

webcam-stream 480x320 pixels sur la scène

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
    var video:Video;
    var camera:Camera;
 
    setupCamera(480,320);
 
    function setupCamera(w:int,h:int):void {
        camera = Camera.getCamera();
        camera.addEventListener(StatusEvent.STATUS, camStatusHandler);
        camera.setMode(w,h,stage.frameRate);
 
        video = new Video(w,h);
        video.attachCamera(camera);
        addChild(video);
    }
 
    function camStatusHandler(event:StatusEvent):void {
        // Camera.Muted or Camera.Unmuted -> User's security
        trace(event.code);
    }

Button shotBtn qui appel la méthode createSnapshot();

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
    var imgBD:BitmapData;
    var imgBitmap:Bitmap;
 
    shotBtn.addEventListener(MouseEvent.CLICK, createSnapshot);
 
    function createSnapshot(event:MouseEvent):void {
        imgBD = new BitmapData(video.width,video.height);
        imgBD.draw(video);
 
        imgBitmap=new Bitmap(imgBD);
        addChild(imgBitmap);
    }

button qui supprimera le dernier snapshot généré

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
    removeBtn.addEventListener(MouseEvent.CLICK, removeSnapshot);
 
    function removeSnapshot(event:MouseEvent):void {
        removeChild(imgBitmap);
    }

Envoyer le snapshot a PHP

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
    import com.adobe.images.JPGEncoder;
 
    var imgBA:ByteArray;
    var jpgEncoder:JPGEncoder;
 
    jpgEncoder = new JPGEncoder(90);
    sendBtn.addEventListener(MouseEvent.CLICK, sendImage);
 
    function sendImage(event:MouseEvent):void {
        imgBA = jpgEncoder.encode(imgBD);
 
        var sendHeader:URLRequestHeader = new URLRequestHeader("Content-type","application/octet-stream");
 
        var sendReq:URLRequest = new URLRequest("path-to-php.php");
        sendReq.requestHeaders.push(sendHeader);
        sendReq.method = URLRequestMethod.POST;
        sendReq.data = imgBA;
 
        var sendLoader:URLLoader;
        sendLoader = new URLLoader();
        sendLoader.addEventListener(Event.COMPLETE, imageSentHandler);
        sendLoader.load(sendReq);
    }

Le fichier php appelé dans le script as3 "nom.php"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
    <?php
    if ( isset ( $GLOBALS["HTTP_RAW_POST_DATA"] )) {
        $uniqueStamp = date(U);
        $filename = $uniqueStamp.".jpg";
        $fp = fopen( $filename,"wb");
        fwrite( $fp, $GLOBALS[ 'HTTP_RAW_POST_DATA' ] );
        fclose( $fp );
     
        echo "filename=".$filename."&base=".$_SERVER["HTTP_HOST"].dirname($_SERVER["PHP_SELF"]);
    }
    ?>

Voilà j'avais trouvé ce script sur le net, ça pourrait surement t'aider à comprendre les différentes étapes pour réaliser ce que tu souhaite.
A+