Discussion :

[wizpsycho]

Bonjour j'ai besoin d'aide pour un projet personel.
En gros, je dois écrire un script qui prend plusieurs lecteurs en paramêtre affiche le nom du volume, le type de lecteur (amovible, fixe, réseau virtuel, le système de fichiers et l'espace libre et occupé en Ko, si son espace libre est supérieur au pourcentage entré comme premier paramêtre.

Mais avant ça il faut afficher dans une boite de dialogue (popup)
La date en format JJ/MM/AAAA/
Le nom du script (InfoLecteurs.vbs) et son but....
Apres on afficher les infos du lecteursss..


J'aimerai avoir votre avis, solutions ou piste afin de crée ce script.

[l_autodidacte]

Salut et bienvenue sur DVP


Il s'agit là d'un devoir à la maison si je ne me trompe pas. Personne ne peut le faire à ta place.

Mais il est possible de te diriger vers quelque chose qui peut t'aider à le faire : cette section de la FAQ VBScript qui justement traitement de ce sujet.
Une fois tu as démarré et écrit un peu de code, reviens poser tes questions sur les difficultés qui pourraient te rencontrer tout en montrant ton code.
@+

[wizpsycho]

J'ai trouver merci.

[l_autodidacte]

J'ai trouver merci.

Ton motif de suppression des 2 avant-derniers messages n'est pas bien convainquant.
Il me semble, si je ne me trompe pas, que ce forum s'adresse à tous ceux qui ont besoin d'aide, en l'occurrence toi-même. Or si chacun arrivant à une solution à son problème ne montre pas aux autres ce qu'il a pu trouver, on n'avance pas et ce forum serait inutile. Ce qui n'est pas le cas.

Mais si tu veux dire que "personne de tes collègues" ne doit voir momentanément ton code pour ne pas le copier et le montrer à qui de droit, on comprendrait mieux ta discrétion si tu le montrerais un jour sur ce forum.

ON PEUT TOUT ACCAPARER SAUF LE SAVOIR QUI DOIT ÊTRE PARTAGÉ.

Si ton problème est résolu, n'oublie pas de cliquer sur le bouton juste en bas de la page en cours.

[hackoofr]

Juste un début de script et je vous laisse.......

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Lecteur=""
Set Disques = objWMIService.ExecQuery ("Select * from Win32_LogicalDisk Where DriveType = 3")
For Each objetDisque in Disques
	EspaceLibre = objetDisque.FreeSpace
	EspaceTotal = objetDisque.Size
	EspaceLibrePc = EspaceLibre / EspaceTotal
	Lecteur=Lecteur & "Lecteur " & objetDisque.DeviceID & vbCR
	Lecteur=Lecteur & "Espace total : " & round(EspaceTotal/1073741824,2) & " Go" & vbcr
	Lecteur=Lecteur & "Espace libre : " & round(EspaceLibre/1073741824,2) & " Go"  & " (" & FormatPercent(EspaceLibrePc) &")" & vbcr & vbcr
Next
But = "C'est un script qui prend plusieurs lecteurs en paramêtre affiche le nom du volume,"&vbcr&_
"le type de lecteur (amovible, fixe, réseau virtuel, le système de fichiers et l'espace libre et occupé en Ko,"&vbcr&_
"si son espace libre est supérieur au pourcentage entré comme premier paramêtre."
MsgBox  "Nous sommes le " & Now & vbcr & wscript.ScriptName & " : "& But,64,"Espace Libre,Esapce Totale" 
MsgBox Lecteur,64,"Espace Libre,Esapce Totale"

[hackoofr]

Voici un autre script avec plus d'informations

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
But = "C'est un script qui prend plusieurs lecteurs en paramêtre affiche le nom du volume,"&vbcr&_
"le type de lecteur (amovible, fixe, réseau virtuel, le système de fichiers et l'espace libre et occupé en Go."
Titre = wscript.ScriptName
MsgBox  "Nous sommes le " & Now & vbcr & Titre & " : "& But,64,Titre
Call DiskInfo
 
Sub DiskInfo
	Dim objFSO, colDrives, objDrive, aff, tempaff 
	Set objFSO = CreateObject("Scripting.FileSystemObject")
	Set colDrives = objFSO.Drives 
	For Each objDrive in colDrives	
	if (objDrive.IsReady = true) then	
	EspaceLibre = objDrive.AvailableSpace
	EspaceTotal = objDrive.TotalSize
	EspaceLibrePc = EspaceLibre / EspaceTotal
			aff = aff & vbcrlf & vbcrlf & "LETTRE DU DISQUE : " & objDrive.DriveLetter & vbcrlf
			aff = aff & "NOM DU DISQUE : " & objDrive.VolumeName & vbcrlf
			aff = aff & "NUMERO DE SERIE : " & objDrive.SerialNumber & vbcrlf
			aff = aff & "TYPE DE DISQUE : " & DiskType (objDrive.DriveType) & vbcrlf
			aff = aff & "SYSTEME DE FICHIERS : " & objDrive.FileSystem & vbcrlf
			aff = aff & "PATH : " & objDrive.Path & vbcrlf
			aff = aff & "DOSSIER RACINE : " & objDrive.RootFolder & vbcrlf
			aff = aff & "ESPACE TOTAL : " & round(EspaceTotal/1073741824,2) & " Go" & vbcrlf
			aff = aff & "ESPACE DISPONIBLE : " & round(EspaceLibre/1073741824,2) & " Go" & " (" & FormatPercent(EspaceLibrePc) &")" & vbcrlf
			if (objDrive.ShareName <> "") then		
				aff = aff & vbcrlf & "NOM DE PARTAGE : " & objDrive.ShareName	
			end if	
		else	
			aff = aff& vbcrlf& vbcrlf & "DISQUE " & objDrive.DriveLetter & " NON PRET" & vbcrlf
			aff = aff & "TYPE DE DISQUE : " & DiskType (objDrive.DriveType)	
		end if 	
	Next
	MsgBox colDrives.count & " DISQUES AFFICHES" & vbcrlf & aff,64,Titre
End Sub
Function DiskType (ByVal dType)
	Dim affType
	Select Case dType
		Case 0 : affType = "INCONNU"
		Case 1 : affType = "DISQUE AMOVIBLE"
		Case 2 : affType = "FIXE"
		Case 3 : affType = "DISTANT"
		Case 4 : affType = "CD-ROM"
		Case 5 : affType = "RAMDISK"
	End Select
	DiskType = affType
End Function