Discussion :

[[ZiP]]

Bonjour,

Voici le code que j'utilise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
[ORG 7C00h]                     ; This is where BIOS put me
 
; ---------------------------------------------------------
; Main program
; ---------------------------------------------------------
 
        mov si, msg             ; Print message
        call putstr
 
hang:   jmp hang                ; Hang!
 
 
 
; ---------------------------------------------------------
; Functions and variables used by our bootstrap
; ----------------------------------------------------------
 
msg     db 'Hello Cyberspace!', 0
 
; Print a 0-terminated string on the screen
putstr:
        lodsb                   ; AL = [DS:SI]
        or al,al                ; Set zero flag if al=0
        jz .done                ; Jump to .done if zero flag is set
        mov ah,0x0E             ; Video function 0Eh
        mov bx,0x0007           ; Color
        int 0x10
        jmp putstr              ; Load characters until AL=0
.done:
        retn
 
times 510-($-$$) db 0
db 0x55
db 0xAA

Je le compile avec :

nasm boot2.asm -f bin -o boot2.bin

Puis je créé une image de disquette avec :

bfi -t=144 -f=boot2.img -b=boot2.bin

Lorsque je boot avec dans VirtualBox, rien ne se passe... même pas un message d'erreur... j'ai juste un curseur blanc et fixe en haut à gauche...

Si je laisse le lecteur de disquette vide, j'ai bien un message d'erreur qui indique qu'il n'y a pas de média pour booter...

Si j'utilise un fichier *.img d'une disquette de Windows 95, ça fonctionne !

Est-ce mon code qui n'est pas bon ou alors peut-être l'image de disquette qui n'est pas construite correctement ?

Merci,
ZiP

[bifur]

tu initialise si mais pas ds (le selecteur de segment) initialise le par zéros

sa valeur est inconnu si ça se trouve ce n'est pas zéros (c'est même quasiment sur)

[[ZiP]]

Bonsoir bifur,

Comment ferais-tu ?

J'ai essayé avec un :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

mov ds, 0

Mais il me provoque cette erreur :

boot2.asm:7: error: invalid combination of opcode and operands

Mais je pense que le problème est causé par l'image de la disquette car le code utilisé a été testé par son auteur et fonctionne...

Il faudrait que je trouve une méthode alternative pour créer mon image de disquette avec mon secteur de boot...

Merci,
ZiP

[edfed]

faut faire ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
format binary as 'img'
org 7c00h
push cs ;pour que ds pointe au meme endroit que cs
pop ds
;code de boot qui fait ce que tu veux
times 510-($-$$) db 90h ;nop
db 55h,0aah
times (80*18*2-1)*512 db 0

et là, l'image de disquette fera la bonne taille, et sera compilée en tant que .img, ou autre, si ça marche pas, après, ça veut surement dire que code n'est pas bon.

[[ZiP]]

Bonjour,

J'ai essayé, ça ne fonctionne toujours pas avec votre proposition de code.

Mon fichier fait bien 512 octets.

Je pense que le problème vient de l'image de la disquette et non du fichier boot2.bin.

Je suis à la recherche d'une solution alternative pour créer un fichier *.img qui est une image de disquette correcte.

Merci,
ZiP

[[ZiP]]

Bonjour,

Voici un code qui fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
;-----------------------------------------------
; nasm bootsect.asm -f bin -o bootsect.img -l bootsect.lst
;-----------------------------------------------
 
        org 0h
; Initialisation des registres de segment
        mov ax, 0x07C0
        mov ds, ax
        mov es, ax
        mov ax, 0x8000
        mov ss, ax
        mov sp, 0xF000
 
; Afficher le message
        mov si, hellomessage
        call display_zstr
 
infini:
        jmp infini
 
;-----------------------------------------------
; Fonction d'affichage de chaine à zéro final
;-----------------------------------------------
display_zstr:
        push ax
        push bx
.beg:        
        lodsb
        cmp al, 0
        jz .end
        mov ah, 0x0E
        mov bx, 0x0007
        int 0x10
        jmp .beg
.end:
        pop bx
        pop ax
        ret
 
hellomessage:
        db "Tout petit petit système d'exploitation !", 13, 10, 0
 
times 510 - ($ - $$) db 0x90
dw 0xAA55
times (1 * 18 * 512) - 512 db 0

Par contre, à quoi sert cette ligne :

times (1 * 18 * 512) - 512 db 0

Merci,
ZiP