Discussion :

[Dan25]

Bonjour,
J'aimerais savoir s'il est possible de copier / coller un fichier texte dans le corps d'un mail ?
J'utilise MailSend pour envoyer des mails récapitulant les erreurs éventuelles des sauvegardes et plutôt que d'avoir à ouvrir une pièce jointe, il serait plus adapté d'avoir le résultat de la sauvegarde dans le corps du mail.
Merci d'avance pour vos lumières

[hackoofr]

Bonjour,
J'aimerais savoir s'il est possible de copier / coller un fichier texte dans le corps d'un mail ?
J'utilise MailSend pour envoyer des mails récapitulant les erreurs éventuelles des sauvegardes et plutôt que d'avoir à ouvrir une pièce jointe, il serait plus adapté d'avoir le résultat de la sauvegarde dans le corps du mail.
Merci d'avance pour vos lumières

Salut Juste une petite question qui me vient a l'esprit
Est-ce-que dans Ce "Mailsend" gère t-il la gestion d'erreurs, je veux dire Savoir si votre mail a été bien envoyé ou non ou bien d'autres erreurs etc.... ???

[Dan25]

Bonjour,
Je ne pense pas qu'il gère la gestion d'erreurs. Sur le principe je l'utilise pour sauvegarder mes données stockées sur plusieurs serveurs. Donc, si je ne reçois pas le nombre de mails correspondant au nombre de serveurs, c'est qu'il y a un problème.

[hackoofr]

Bonjour,
J'aimerais savoir s'il est possible de copier / coller un fichier texte dans le corps d'un mail ?
J'utilise MailSend pour envoyer des mails récapitulant les erreurs éventuelles des sauvegardes et plutôt que d'avoir à ouvrir une pièce jointe, il serait plus adapté d'avoir le résultat de la sauvegarde dans le corps du mail.
Merci d'avance pour vos lumières

La pièce-jointe est au format texte je pense ? et elle est généré par un logiciel de sauvegarde c'est ça ?
Vous n'avez pas essayer un petit brouillon en Vbscript au lieu d'utiliser "Mailsend" pour voir un peu plus clair ?
Vous pouvez consulter cette discussion Conception d'un script de sauvegarde avec envoie de mail en cas d'échec

[Dan25]

Bonjour,
Le code ci-dessous permet de lire le contenu d'un fichier texte. Je peux le faire afficher dans un msgbox ou par wscript.echo, mais je ne parviens pas à le faire passer dans une variable pour l'envoyer par mail. Voyez-vous une combine qui permettrait de réaliser ceci ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
 
Const conForReading = 1
 
'Declare variables
Dim objFSO, objReadFile, contents
 
'Set Objects
Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set objReadFile = objFSO.OpenTextFile("H:\Sauvegardes\Logs\Robocopy_Erreurs.txt", 1, False)
Set Sh=CreateObject("WScript.Shell")
 
'Read file contents
contents = objReadFile.ReadAll
 
'Close file
objReadFile.close
 
'Display results
wscript.echo contents

Si je fais vMsg="""Ceci est le texte de mon message""" ça fonctionne
si je fais vMsg=contents (contents contient une ligne de texte) ça ne fonctionne pas
Merci d'avance pour vos conseils

[ProgElecT]

Salut

Si j'ajoute en début de ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim vMsg, Sh

et ceci en fin de ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
vMsg = contents
wscript.echo vMsg

cela fonctionne, pas chez toi ?

[Dan25]

Bonsoir,
Merci pour ton aide.
Je n'avais pas mis le code complet. Ce que tu me proposes s'y trouvait déjà.
Voici le code complet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Option Explicit
 
Const conForReading = 1
 
'Declare variables
Dim objFSO, objReadFile, contents, Sh, vDest, vMailSrv, vDomain, vExpediteur, vExecution, vSujet, vMsg, vPJ
 
'Set Objects
Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set objReadFile = objFSO.OpenTextFile("H:\Sauvegardes\Logs\Robocopy-Data2_Erreurs.txt", 1, False)
Set Sh=CreateObject("WScript.Shell")
 
'Read file contents
contents = objReadFile.ReadAll
 
'Close file
objReadFile.close
 
'Display results
wscript.echo contents
 
 
vDest="informatique@rdc.com"
vMailSrv="smtp.rdc.com"
vDomain="rdc.com"
vExpediteur="Sauvegarde_Data2@rdc.com"
vSujet="""Sauvegarde Data2"""
'vMsg="""Ci-joint le CR de la sauvegarde du serveur Data2""" '& contents
vMsg=contents
vPJ="H:\Sauvegardes\Logs\Robocopy_Data2_Erreurs.txt,text/plain"
vExecution="D:\Scripts\Sauvegarde\MAILSEND.EXE -f " & vExpediteur & " -d " & vDomain & " -smtp " & vMailSrv & " -t " & vDest & " -sub " & vSujet & " -M " & vMsg & " -a " &  vPJ & " +cc +bc"
Sh.run vExecution
 
'Cleanup objects
Set objFSO = Nothing
Set objReadFile = Nothing
 
'Quit script
WScript.Quit()

[ProgElecT]

Si contents contient des espaces, je tenterais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

vMsg= chr(34) & contents & chr(34)

par contre je ne connais rien en ce qui concerne la technique d'envoi par mail.

[hackoofr]

Essaye ce code avec un message mail en HTML en Bonus au lieu du texte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Const conForReading = 1
 
'Declare variables
Dim objFSO, objReadFile, contents, Sh, vDest, vMailSrv, vDomain, vExpediteur, vExecution, vSujet, vMsg, vPJ,messageHTML
 
'Set Objects
Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set objReadFile = objFSO.OpenTextFile("H:\Sauvegardes\Logs\Robocopy_Data2_Erreurs.txt", 1, False)
Set Sh=CreateObject("WScript.Shell")
 
'Read file contents
contents = objReadFile.ReadAll
 
'Close file
objReadFile.close
 
'Display results
wscript.echo contents
vDest="informatique@rdc.com"
vMailSrv="smtp.rdc.com"
vExpediteur="Sauvegarde_Data2@rdc.com"
vSujet="""Sauvegarde Data2"""
'vMsg="""Ci-joint le CR de la sauvegarde du serveur Data2""" '& contents
vMsg=contents
vPJ="H:\Sauvegardes\Logs\Robocopy_Data2_Erreurs.txt"
 
Set objMessage = CreateObject("CDO.Message") 
objMessage.Subject = vSujet 
objMessage.From = vExpediteur  
objMessage.To = vDest 
 
messageHTML=vMsg&"<br><br>Ceci est un message en HTML envoyé par hackoo"
 
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = vMailSrv
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
objMessage.Configuration.Fields.Update
'Ajout d'un message en HTML en affichant une image hébergé dans un serveur distant
objMessage.HTMLBody="<center><font size=4 FACE=Comic sans MS Color=red>"&messageHTML&"<br><br><img src=http://photomaniak.com/upload/out.php/i1102064_IDNlogo.gif>"
If vPJ <> "" Then
objMessage.AddAttachment(vPJ) 'On peut ajouter aussi une image ou un fichier dans la piéce-jointe
end if
on error resume next 
objMessage.Send
 
 If Err.Number <>0 Then
            Msgbox "le mail n'a pas pu être envoyé !",16,"Erreur d'envoi du Mail"
	    MsgBox Err.Description,16,"Erreur d'envoi du Mail"
Else
	    Msgbox "Le mail a été bien envoyé !",64,"Information"
End If

[Dan25]

Bonjour,
Merci pour vos réponses.
Concernant l'utilisation de MailSend il faut effectivement ajouter chr(34), alors que ce n'est pas le cas par Cdo.
Merci pour cette info ProgElecT.
En passant par l'envoi de mail par cdo, ça fonctionne très bien, même s'il ne faut pas que j'utilise le format Html, car j'envoie un texte formaté par Robocopy (presque un tableau) qui comporte des espaces... et qui n'est plus lisible en html.
J'avais déjà essayé d'utiliser l'envoi de mail par Cdo, mais je n'avais pas réussi à le configurer correctement.
Merci beaucoup pour ce boulot hackoofr
Très cordialement
Dan

[hackoofr]

Bonjour,
En passant par l'envoi de mail par cdo, ça fonctionne très bien, même s'il ne faut pas que j'utilise le format Html, car j'envoie un texte formaté par Robocopy (presque un tableau) qui comporte des espaces... et qui n'est plus lisible en html.

Concernant les problèmes des guillemets (") et les espaces.On peut résoudre ceci facilement en ajoutant cette petite fonction.
un exemple d'utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
'Fonction pour simplifier les problèmes des guillemets (") et les espaces	
Function qq(strIn) 
    qq = Chr(34) & strIn & Chr(34)
End Function

Donc ton Code devient alors :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
Const conForReading = 1
'Declare variables
Dim objFSO, objReadFile, contents, Sh, vDest, vMailSrv, vDomain, vExpediteur, vExecution, vSujet, vMsg, vPJ
 
'Set Objects
Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set objReadFile = objFSO.OpenTextFile("H:\Sauvegardes\Logs\Robocopy_Data2_Erreurs.txt", 1, False)
Set Sh=CreateObject("WScript.Shell")
 
'Read file contents
contents = objReadFile.ReadAll
 
'Close file
objReadFile.close
 
'Display results

vDest="informatique@rdc.com"
vMailSrv="smtp.rdc.com"
vExpediteur="Sauvegarde_Data2@rdc.com"
vSujet=qq("Sauvegarde Data2")
vMsg=qq("Ci-joint le CR de la sauvegarde du serveur Data2") & vbCrLf & vbCrLf & qq(contents)
vPJ="H:\Sauvegardes\Logs\Robocopy_Data2_Erreurs.txt"
 
 wscript.echo vMsg
 
Set objMessage = CreateObject("CDO.Message") 
objMessage.Subject = vSujet 
objMessage.From = vExpediteur  
objMessage.To = vDest 
  
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = vMailSrv
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
objMessage.Configuration.Fields.Update

objMessage.TextBody=vMsg
If vPJ <> "" Then
objMessage.AddAttachment(vPJ) 
end if
on error resume next 
objMessage.Send
 
 If Err.Number <>0 Then
            Msgbox "le mail n'a pas pu être envoyé !",16,"Erreur d'envoi du Mail"
	    MsgBox Err.Description,16,"Erreur d'envoi du Mail"
Else
	    Msgbox "Le mail a été bien envoyé !",64,"Information"
End If
 
'Fonction pour simplifier les problèmes des guillemets (") et les espaces		
Function qq(strIn) 
    qq = Chr(34) & strIn & Chr(34)
End Function

Alors tu peux tester ce dernier code et dis-moi le résultat
Cordialement

[Dan25]

Merci pour la fonction, c'est effectivement une bonne idée, mais il faudrait l'employer différemment. Je n'ai pas eu beaucoup de temps pour faire les tests, mais le résultat est le suivant : ça ajoute des " devant et derrière l'objet ainsi que devant et derriière le corps du message.

[hackoofr]

Merci pour la fonction, c'est effectivement une bonne idée, mais il faudrait l'employer différemment. Je n'ai pas eu beaucoup de temps pour faire les tests, mais le résultat est le suivant : ça ajoute des " devant et derrière l'objet ainsi que devant et derriière le corps du message.

Bien sûr qu'il faut utiliser différemment c'est juste pour vous démontrer la "souplesse" de cette fonction càd qu'on peut agir comme on le souhaite d'avoir comme résultat : que ce soit dans l'objet ou bien dans le corps de l'e-mail.
Un petit Conseil concernant le mailSend: moi personnellement si j'étais vous j’utilise une solution 100% Vbscript sans chercher a introduire un programme externe comme mailsend qui ne gère pas les erreurs surtout au niveau d'envoi et de réception du mail et pas de souplesse comme dans votre cas ici vous voulez copier / coller un message texte qu'on trouve beaucoup de mal a le gérer comme il faut
Bref,ceci est mon avis et bien sûr vous êtes libre de choisir la solution la plus adéquate pour vous
Voila ce qui concerne ma solution a votre probléme en Vbscript sans passer par le mailsend et cette fois-ci prenez votre temps a le tester convenablement et a tête reposé et dis-moi s'il vous conviendrez ou non ?
Cordialement !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Const conForReading = 1
'Declare variables
Dim objFSO, objReadFile, contents, Sh, vDest, vMailSrv, vDomain, vExpediteur, vExecution, vSujet, vMsg, vPJ
 
'Set Objects
Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set objReadFile = objFSO.OpenTextFile("H:\Sauvegardes\Logs\Robocopy_Data2_Erreurs.txt", 1, False)
Set Sh=CreateObject("WScript.Shell")
 
'Read file contents
contents = objReadFile.ReadAll
 
'Close file
objReadFile.close
 
'Display results
 
vDest="informatique@rdc.com"
vMailSrv="smtp.rdc.com"
vExpediteur="Sauvegarde_Data2@rdc.com"
vSujet="Sauvegarde Data2"
vMsg="Ci-joint le CR de la sauvegarde du serveur Data2" & vbCrLf & vbCrLf & contents
vPJ="H:\Sauvegardes\Logs\Robocopy_Data2_Erreurs.txt"
 
 wscript.echo vMsg
 
Set objMessage = CreateObject("CDO.Message") 
objMessage.Subject = vSujet 
objMessage.From = vExpediteur  
objMessage.To = vDest 
 
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2 
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = vMailSrv
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25 
objMessage.Configuration.Fields.Update
 
objMessage.TextBody=vMsg 'Le message sera formté en texte
If vPJ <> "" Then
objMessage.AddAttachment(vPJ) 
end if
on error resume next 
objMessage.Send
 
 If Err.Number <>0 Then
            Msgbox "le mail n'a pas pu être envoyé !",16,"Erreur d'envoi du Mail"
	    MsgBox Err.Description,16,"Erreur d'envoi du Mail"
Else
	    Msgbox "Le mail a été bien envoyé !",64,"Information"
End If

[Msxty]

Bonjour à tous,

Merci à hackoofr, ton script m'a beaucoup aidé dans ce que je cherchais.
Je tiens à préciser que je suis un débutant en VBScript, mais j'en ai besoin pour un petit projet, et je voudrais savoir comment faire utiliser les informations qui se trouvent dans un fichier texte.

C'est à dire j'ai mon fichier.txt:

vDest="mail@fai.fr"
vExpediteur="mail@fai.fr"
vSujet="Test mail"
vMsg=.....

Et ce que je voudrais c'est que le script puisse prendre les valeurs de chaque variable et les utiliser pour envoyer le mail. Je précise que j'utilise pour base le script de hackoofr.

Merci d'avance pour votre aide.


EDIT:

J'ai trouvé quelque chose qui fonctionne pour récupérer la valeur des variables de mon fichier, sur ce forum, mais ce n'est pas tout à fait ce que je veux car mon fichier est de la forme:

mail@fai.fr;mail@fai.fr;sujet;message

voici le morceau qui lit le fichier:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
strSourceFile="C:\Users\Documents\script\test.txt"
 
Const ForReading = 1, ForWriting = 2 , ForAppending = 8
 
Set objFSo = CreateObject("Scripting.FileSystemObject")
 
wscript.echo "vDest :" & getVariable(0) ' retourne la valeur vExpediteur
wscript.echo "vExpediteur :" & getVariable(1)' retourne la valeur vDest
wscript.echo "vSujet :" & getVariable(2)' retourne la valeur vSujet
wscript.echo "vMsg :" & getVariable(3)' retourne la valeur vMsg
 
Function getVariable(entier)
 Set f = objFSo.OpenTextFile(strSourceFile, ForReading)
   	val=f.ReadLine
	tabFile = Split(val, ";")
	getVariable = tabFile(entier)	
 set f = nothing 
 
End function 
 
vExpediteur = getVariable(0)
vDest = getVariable(1)
vSujet = getVariable(2)
vMsg = getVariable(3)

Comment utiliser ses variables mais de la forme du fichier :

vDest="mail@fai.fr"
vExpediteur="mail@fai.fr"
vSujet="Test mail"
vMsg=.....

[Msxty]

Sinon est ce quelqu'un pourrait m'aider afin de faire une boucle dans un répertoire pour qu'elle puisse compter le nombre de fichier présent et qu'elle exécute ma fonction.

[hackoofr]

Sinon est ce quelqu'un pourrait m'aider afin de faire une boucle dans un répertoire pour qu'elle puisse compter le nombre de fichier présent et qu'elle exécute ma fonction.

Essayez d'ouvrir et de reformuler votre question dés le début dans une Nouvelle Discussion mais pas dans celle-ci qui a été auparavant et n'oubliez pas de mettre un titre significative qui reflète bien votre requête avec les codes sources utilisés.
de votre compréhension