Discussion :

[GnuVince]

J'ai trouvé via le Wayback machine le vieux shootout de Doug Bagley (l'ancêtre de l'actuel Computer Language Shootout). On y trouve notament un programme qui fait la somme des entiers dans un fichier. Voici la solution de l'époque:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
let sum = ref 0
let rec loop () = sum := !sum + read_int (); loop ()
let _ = try loop () with End_of_file -> Printf.printf "%d\n" !sum

Je n'aimais pas trop l'utilisation d'un ref, donc j'ai décidé de ré-écrire le programme:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
let rec sumfile sum =
  try sumfile (sum + read_int ())
  with End_of_file -> sum
 
let _ = Printf.printf "%d\n" (sumfile 0)

Malheureusement, avec un très gros fichier (seq 1 1000000 > fichier.txt), ce nouveau programme plante avec une segmentation fault. Quelqu'un pourrait m'expliquer pourquoi?

[Cacophrene]

Bonjour,

Amusant, je m'attendais à une erreur de type stack_overflow. En effet, l'appel récursif de la fonction sumfile est dans try...with, ce qui implique d'empiler les appels successifs. Si le fichier est très gros tu dois saturer la pile d'appels. L'utilisation d'une référence permet d'éviter ce problème. Essaie cette version sur ton gros fichier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
let rec sumfile sum =
  match try Some (read_int ()) with End_of_file -> None with
  | None -> sum
  | Some x -> sumfile (sum + x)

Pourquoi segfault et pas stack_overflow ? Je n'ai pas de réponse claire à ce sujet. Je crois me souvenir que certaines versions d'OCaml déclenchent une segfault en cas de débordement de pile sur certaines plateformes, mais bof... vieux souvenir douteux, donc je n'affirme rien.

Edit : en bytecode tu as bien Stack_overflow. C'est en natif seulement que j'obtiens une segfault.

Cordialement,
Cacophrène

[gasche]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
let sum = ref 0 in begin
  try while true do
    sum := !sum + read_int ()
  done with End_of_file ->
    print_int !sum; print_newline ()
end

[Cacophrene]

Bonjour,

En utilisant une référence et un while, on en revient à la solution de Doug Bagley. Notez aussi que le résultat est négatif parce qu'on dépasse max_int avec un gros fichier.

Cordialement,
Cacophrène

[GnuVince]

Merci Cacophrene, toujours très informatif de vous lire.

Bonne journée.