Formulaire de consultation des personnes connectees

**Renardo** · 29/04/2007, 17h19

Bonjour
J'ai utiliser le code de Dolphy pour consulter les personnes connectees a une bd celui ci fonctionne tres bien il y a juste un petit detail Tous les ordinateur entrant dans la bd sont bien afficher mais si un ordinateur sort de la bd il reste dans la liste des connectes y a t'il une solution pour remedier a cela.
Lien code Dolphy
http://dolphy35.developpez.com/artic.../BasesReseaux/
Merci d'avance pour vos reponse

**LedZeppII** · 29/04/2007, 19h40

Bonsoir,

le fichier ldb contient la trace de tous Ordinateur/Utilisateurs qui ont ouvert la base, jusqu'à ce qu'il soit détruit.

Voici un lien vers une autre méthode (ADO) pour voir qui est connecté :
kb198755 (EN)
kb198755 (FR)

A+

**Dolphy35** · 29/04/2007, 20h05

Salut Renardo,

je viens de retester le code voir si il y avait une coquille, mais non il fonctionne bien.
Au début du module on efface bien le contenu de la table avant de là recharger.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    'Vide la Table contenant la liste des pc connectés
    DoCmd.RunSQL "DELETE * FROM tblConnectes"

le principe est de lire le fichier ldb de la dorsale, celui-ci ajoute le nom lors de la connexion à celle-ci.
Je ne comprend car dès la rupture de liaison le fichier ldb est mis à jour.

petit test à faire => ouvre le fichier ldb de la Dorsale avec un éditeur de text (bloc note, etc ...) si les Pc y sont toujours le soucis vient du fichier, si non il y a un soucis dans le code.

Dolphy

**Renardo** · 29/04/2007, 20h41

Merci pour vos reponse a tous les deux
Dolphy, je vais faire les testes que tu ma dit et je te tien au courrant
un point quand meme quand je deconecte un ordi la il reste dans liste mais quand je conecte un autre ordi la liste se met a jour

Je vient de verifier le fichier ldb et apres avoir deconecte un des ordi de la base il est toujour afficher dans le fichier

**Dolphy35** · 30/04/2007, 00h57

re,

Envoyé par Renardo

Je vient de verifier le fichier ldb et apres avoir deconecte un des ordi de la base il est toujour afficher dans le fichier

Le soucis vient d'ici, le fichier ldb ne se me pas à jour, c'est étrange

, je vais voir si je trouve quelque chose et je te tiens au courant

Dolphy

**LedZeppII** · 30/04/2007, 11h42

Bonjour,

Extrait KB N° 208778

Contenu du fichier .ldb
Pour chaque personne qui ouvre une base de données partagée, le moteur de base de données Jet écrit une entrée dans le fichier .ldb de la base de données. La taille de chaque entrée .ldb est de 64 octets. Les 32 premiers octets contiennent le nom de l'ordinateur (par exemple JeanDuval). Les 32 octets suivants contiennent le nom de sécurité (par exemple Admin). La quantité maximale d'utilisateurs simultanés prise en charge par le moteur de base de données Jet est 255 ; par conséquent, la taille du fichier .ldb n'est jamais supérieure à 16 kilo-octets.

Lorsqu'un utilisateur ferme une base de données partagée, l'entrée relative à cet utilisateur n'est pas supprimée du fichier .ldb. Toutefois, elle peut être remplacée lorsqu'un autre utilisateur ouvre la base de données. Cela signifie que vous ne pouvez pas utiliser le fichier .ldb seul pour déterminer qui utilise actuellement la base de données.

C'est pour ça que je préfère la méthode par ADO.

A+

**Renardo** · 30/04/2007, 12h09

Bonjour LedZeppII
j'ai lut plusieur chose la dessus et en effet j'ai crue comprendre se que tu dit
mais comme Dolphy avait l'aire etonner que cela ne fonctionne pas j'avait des doute.
Quand a ta source je suis en train de l'etudier le code fonctione maintenant il faut que j'essai de l'integree dans mon programme si tu as quelque astuce je suis preneur et voir meme une demo (Je ne fait pas du Vba depuis tres longtemp donc j'ai encore quelque lacune)
Merci

**Dolphy35** · 30/04/2007, 12h27

Salut,

Envoyé par LedZeppII

Bonjour,

Extrait KB N° 208778

Contenu du fichier .ldb
Pour chaque personne qui ouvre une base de données partagée, le moteur de base de données Jet écrit une entrée dans le fichier .ldb de la base de données. La taille de chaque entrée .ldb est de 64 octets. Les 32 premiers octets contiennent le nom de l'ordinateur (par exemple JeanDuval). Les 32 octets suivants contiennent le nom de sécurité (par exemple Admin). La quantité maximale d'utilisateurs simultanés prise en charge par le moteur de base de données Jet est 255 ; par conséquent, la taille du fichier .ldb n'est jamais supérieure à 16 kilo-octets.

Lorsqu'un utilisateur ferme une base de données partagée, l'entrée relative à cet utilisateur n'est pas supprimée du fichier .ldb. Toutefois, elle peut être remplacée lorsqu'un autre utilisateur ouvre la base de données. Cela signifie que vous ne pouvez pas utiliser le fichier .ldb seul pour déterminer qui utilise actuellement la base de données.

C'est pour ça que je préfère la méthode par ADO.

A+

je suis étonné de la dernière partie, j'utilise ce code et je n'ais jamais eu de soucis mes entrée dans le ldb se mettent à jour à chaque connexion/deconnexion

je viens de tester le code ADO de MS, il possède déjà deux entrées alors que personnes ne sont connectées à la bdd et me renvoi que c'est deux entrées sont connectées

pour précision je suis Access2003.

LedZeppII => peux-tu me donner plus d'info sur la façon dont tu utilise le code ADO et quelle version tu utilise.
Renardo => quel est ta version d'Access.

Dolphy

**Renardo** · 30/04/2007, 14h16

Bonjour Dolphy
J'ai access 2003 et ma base est au format access 2000 je l'est mise au format 2003 mais cela n'a rien changer.

**LedZeppII** · 30/04/2007, 16h06

Bonjour Dolphy,

j'utilise le code MS presque tel qu'il est.
On voit une connexion supplémentaire car le code en ouvre une.

Version Access : 2000
Version ADO : 2.5
Nous sommes passé en 2003 depuis peu : donc pas assez de recul.

L'article que j'ai cité sur le contenu du fichier ldb est le même pour 2000 et 2002.
En tout cas c'est un phénomène que j'avais déjà constaté : Tous les utilisateurs présents dans le fichier ldb ne sont pas forcement connectés.

A+

**Renardo** · 30/04/2007, 17h03

LedZeppII
A partir du code comment faire pour recuperer les connectes dans une zone de liste
merci

**LedZeppII** · 30/04/2007, 18h56

Bonjour Renardo,

Voici mon code (pas très élaboré) pour une zone de liste lstUsers ayant ces caractériques ...
Origine source : liste valeurs
Contenu : <rien>
Colonne liée 1
Nbre de colonnes : 4
En-tête colonnes : Oui
Largeurs colonnes : 3,5cm;3cm;2cm;2cm

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub ShowUsers(strDBfullName As String)
Dim oCn As ADODB.Connection, r As ADODB.Recordset
Dim strDBfullName As String, strLst As String, strTxt As String
Dim i As Integer, p As Integer
 
Set oCn = New ADODB.Connection
oCn.ConnectionString = "PROVIDER=Microsoft.Jet.OLEDB.4.0;" & _
                       "DATA SOURCE=" & strDBfullName
oCn.Open
 
Set r = oCn.OpenSchema(adSchemaProviderSpecific, , _
                       "{947bb102-5d43-11d1-bdbf-00c04fb92675}")
 
' En tête de colonnes
For i = 1 To r.Fields.Count
    strLst = strLst + r.Fields(i - 1).name & ";"
Next
 
' Données
While Not r.EOF
   For i = 1 To r.Fields.Count
       strTxt = CStr(Nz(r.Fields(i - 1).Value))
       p = InStr(1, strTxt, vbNullChar)
       If p > 1 Then strTxt = Left(strTxt, p - 1)
       strLst = strLst + strTxt & ";"
   Next
   r.MoveNext
Wend
 
r.Close
Set oCn = Nothing
 
Me.lstUsers.RowSource = strLst
 
End Sub

La Sub est dans mon formulaire. Elle est appelée lorsque je clique sur un bouton, par le code de l'évènement Sur Clic.
On lui passe en paramètre le chemin complet + le nom de la base de données.

A+

**Renardo** · 30/04/2007, 20h03

Merci pour ton aide cela fonctionne très bien
Voit tu un inconvénient a placer le code sur la minuterie?(J'ai fait l'essai sa marche)
Merci encore
A plus

**juliojc13** · 03/05/2007, 17h04

Bonjour,

Aujourd'hui, j'ai réalisé cette méthode...

Méthode par ADO:

Cela fonctionne bien de mon côté pour le moment.
J'ai, d'ailleurs, associé à ce code une zone de liste et un bouton de commande pour mettre à jour la liste des connectés sur mon interface.
Je tiens juste à signaler 2 points négatifs auxquels vous pourrez peut-être trouver des solutions:

>Le code n'est pas modulable ou plutôt n'est pas évolutif... Je m'explique...
COMPUTER_USER, dans cette colonne, s'affichent les noms de PC.
Ce que je voudrais faire, c'est que, dans ma zone de liste, s'affichent plutôt les noms des utilisateurs.
Pour cela, j'ai créé une table avec les correspondances noms de PC<>noms des utilisateurs mais ensuite, je n'arrive pas à manipuler pour qu'au final, elle me renseigne les noms des utilisateurs...
Ouvert à toute solution!

>J'aimerais également éviter les doublons de noms de PC dans ma zone de liste. Car, d'après ce qui a été dit et qui s'est vérifié aussi de mon côté, on voit une connexion supplémentaire car le code en ouvre une! En effet, dans mon cas, mon nom de PC s'affiche par deux fois...
Ouvert à toute solution!

Merci d'avance.

**LedZeppII** · 04/05/2007, 19h56

Bonjour,

J'ai modifié le code en reprenant le principe du tutoriel, c'est à dire que je copie les informations de connexions dans une table..

Le code utilise ...
Une table tblConnectes avec deux champs Texte : Ordinateur, Utilisateur
Une zone de liste lstConnectes
Origine source : Table/Requête
Contenu : SELECT Ordinateur, Utilisateur, Count(*) AS NbConnexions FROM tblConnectes GROUP BY Ordinateur, Utilisateur;
Colonne liée 1
Nbre de colonnes : 3
En-tête colonnes : Oui
Largeurs colonnes : 3,5cm;3,5cm;3cm
Une zone de texte txtLstConnectesDateHeure

On appelle la fonction ShowUsers (dont le code se trouve dans le module de code du formulaire)
en lui passant en paramètre le chemin complet et le nom de la base.

Le code de la fonctoin fait appel à une fonction api pour récupérer le nom de l'ordinateur si il n'est pas trouvé
dans la varaible d'environnement COMPUTERNAME.
C'est dans la faq : http://vb.developpez.com/faq/?page=Reseau#nom_machine

Le code de la fonction:

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
Sub ShowUsers(strDBfullName As String)
Dim oCn As ADODB.Connection, r As ADODB.Recordset
Dim arrCnx(), strTxt As String, strThisComputer
Dim blnIgnore As Boolean
Dim p As Integer, row As Integer, col As Integer
 
Set oCn = New ADODB.Connection
oCn.ConnectionString = "PROVIDER=Microsoft.Jet.OLEDB.4.0;" & _
                       "DATA SOURCE=" & strDBfullName
oCn.Mode = adModeRead
 
On Error GoTo ERRH
 
oCn.Open
 
Set r = oCn.OpenSchema(adSchemaProviderSpecific, , "{947bb102-5d43-11d1-bdbf-00c04fb92675}")
' Copie le recordset dans un tableau
' 1ere colonne (indice 0) : Ordinateur
' 2eme colonne (indice 1) : Utilisateur Access
arrCnx = r.GetRows()
r.Close
Set r = Nothing
oCn.Close
Set oCn = Nothing
 
' Nettoye le tableau
For row = LBound(arrCnx, 2) To UBound(arrCnx, 2)
    For col = LBound(arrCnx, 1) To UBound(arrCnx, 1)
        strTxt = CStr(Nz(arrCnx(col, row)))
        p = InStr(1, strTxt, vbNullChar)
        If p > 1 Then strTxt = Left(strTxt, p - 1)
        arrCnx(col, row) = strTxt
    Next
Next
 
' Vide la table tblConnectes
DoCmd.SetWarnings False
DoCmd.RunSQL "DELETE FROM tblConnectes"
DoCmd.SetWarnings True
 
' Récupère le nom de l'Ordinateur
strThisComputer = Environ("COMPUTERNAME")
If strThisComputer = "" Then
   strThisComputer = NomOrdinateur()
End If
 
blnIgnore = True
 
' Ajoute les connexions dans la table à l'exception de la
' première connexion trouvée ayant le même nom d'Ordinateur
' et d'utilisateur que celui qui exécute ce code
For row = LBound(arrCnx, 2) To UBound(arrCnx, 2)
    If arrCnx(0, row) = strThisComputer And _
       arrCnx(1, row) = Application.CurrentUser() _
       And blnIgnore Then
       blnIgnore = False
     Else
       DoCmd.SetWarnings False
       DoCmd.RunSQL "INSERT INTO tblConnectes(Ordinateur, Utilisateur) " & _
             "VALUES('" & arrCnx(0, row) & "', '" & arrCnx(1, row) & "')"
       DoCmd.SetWarnings True
    End If
Next
 
' Raffraichie la liste lstConnectes
Me.lstConnectes.Requery
' Met la date et l'heure de version de la liste dans la
' zone de texte txtLstConnectesDateHeure
Me.txtLstConnectesDateHeure = Now()
Exit Sub
 
ERRH:
If Not r Is Nothing Then
   If r.State <> adStateClosed Then r.Close
   Set r = Nothing
End If
If Not oCn Is Nothing Then
   If oCn.State <> adStateClosed Then oCn.Close
   Set oCn = Nothing
End If
 
MsgBox "Erreur " & CStr(Err.Number) & " : " & Err.Description
 
End Sub

Le GROUP BY dans la requête source de la liste élimine les doublons Ordinateur/Utilisateur

Dans le code, la première connexion ayant le même nom d'ordinateur et d'utilisateur que la machine qui exécute le code
n'est pas ajoutée à la table. Cela élimine la connexion supplémentaire dûe au code.

A+

*AJOUT*
Si tu as une table avec les noms des PC et des utilsateurs tu changes la requête de la zone de liste.
Par exemple si ta table est tblStations(NomStation, NomUtilisateur):

Code sql :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
SELECT NomUtilisateur, NomStation, Count(*) AS NbConnexions 
FROM tblConnectes INNER JOIN tblStations ON tblConnectes.Ordinateur = tblStations.NomStation
GROUP BY NomUtilisateur, NomStation;

**juliojc13** · 04/05/2007, 21h11

Je tiens déjà à te remercier beaucoup pour cette aide...
Du nouveau est arrivé depuis aujourd'hui.
J'ai réussi à afficher les noms des utilisateurs d'une autre manière pas très jolie mais ça fonctionne.
Dans ton code, au niveau de:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
If p > 1 Then strTxt = Left(strTxt, p - 1)
            strLst = strLst + strTxt & ";"

j'y ai rajouté entre ces deux lignes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If strTxt = "PCXXXX1" Then strTxt = "Monsieur Dupont"
If strTxt = "PCXXXX2" Then strTxt = "Monsieur Dupond"
...etc...

Voilà, c'est une autre idée mais bon pas aussi jolie que la tienne...

Pour ce qui est d'éviter les doublons, je te cite:
"Le GROUP BY dans la requête source de la liste élimine les doublons Ordinateur/Utilisateur"
Ceci évite-t-il bien les doublons?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

GROUP BY NomUtilisateur, NomStation;

Cette partie du code dans la requête source de la liste élimine les doublons?
Je ne savais pas que cette fonction , en plus de regrouper, éviter les doublons?

Encore merci beaucoup à toi, je vais tester ce dernier petit souci de doublons la semaine prochaine.

**LedZeppII** · 04/05/2007, 23h38

Je réponds sur les GROUP BY.

Les données regroupées ne sont pas répétées.
Par conséquent il n'y a pas de doublons sur les couples de champs ...
- Ordinateur/Utilisateur dans la 1ère requête (propriété contenu de la zone de liste)
- NomUtilisateur/NomStation dans la 2ème
Ensuite tout dépend à quel niveau on situe le doublon.
S'il n'y a que le nom de PC qui t'intéresse, retire le nom d'utilisateur Access.
D'ailleurs dans la deuxième il n'y est pas.

A+

**Renardo** · 05/05/2007, 11h26

Bonjour
Je vient de tester ton nouveau code il fonctionne a merveille Bravo
maintenant j'ai une autre petite idee qui me trote dans la tête cree un journal ou une table qui garderais toute les connexions et l'heure de connexion des ordinateur.
(Bien que se post soit Resolu je le laisse ouvert car je pense qu'il peut y avoir d'autre idees tres interesente)

**juliojc13** · 09/05/2007, 17h05

Très bonne méthode, je viens de l'expérimenter aujourd'hui et en effet, ça marche à merveille!!! Elle me convient, c'est tout ce que je recherchais!
Pour moi, c'est résolu en tout cas...
Merci beaucoup encore une fois, on y est arrivé!!

Formulaire de consultation des personnes connectees

Sécurité

Discussions similaires

Partager

Partager