Discussion :

[loufred]

Bonjour,

je cherche une facon, de connaitre le nombre d'émails recus.

-uniquement le nombre !
-verification toute les minutes...
-avec de préférence du pop3 (free...)

merci de votre aide .

[Invité]

Bonjour

Tes mails tu veux les contrôler où ?

Chez ton FAI ?
Sur Windows Live Mail ?
etc ..

Philippe

[loufred]

bonjour

chez mon FAI

salutations.

[SfJ5Rpw8]

Voici une solution avec WinSock... :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
 
Dim stReponse 
Const TIME_OUT= 30
stReponse =""
stUser = "loufred"
stPass ="a23lsk"
stServeurPOP = "pop.free.fr"
numPort  = 110
Set oWsk = WScript.CreateObject("MSWinsock.Winsock","oWsk_")
oWsk.RemoteHost = stServeurPOP
oWsk.RemotePort = numPort
oWsk.Connect() 
 
TempMax =TIME_OUT
'
 
Do
	WScript.Sleep(1000)
    TempMax = TempMax - 1
Loop While(TempMax > 0 and oWsk.State <> 7) 
if oWsk.State <> 7 then
	WScript.Echo "Défaut connexion, status connection = " & oWsk.State 
	Wscript.Quit
end if
If Not AttenteReponse then
	WScript.Echo "Erreur sur connexion"
	Wscript.Quit
end if
'
' Envoi utilisateur 
'
stReponse = ""
oWsk.SendData "USER " & stUser & vbCrlf
If Not AttenteReponse  then
	WScript.Echo "Erreur sur User"
	Wscript.Quit
end if
'
' Mot de passe
'
stReponse = ""
oWsk.SendData "PASS " & stPass  & vbCrlf
If Not AttenteReponse then
	WScript.Echo "Erreur sur PASS"
	Wscript.Quit
end if
'
' Commande STAT
'
 
stReponse = ""
oWsk.SendData "STAT"  & vbCrlf
If Not AttenteReponse then
	WScript.Echo "Erreur sur STAT"
	Wscript.Quit
end if
 
 
'
' Nouvelle données WinSock
'
Function oWsk_DataArrival(bytesTotal )
	oWsk.GetData stReponse, 8
	Wscript.Echo stReponse  
end Function
'
' Attente donnée winSock , avec Time OUT de 30s
'
Function AttenteReponse 
	TempMax = TIME_OUT
	Do
		WScript.Sleep(1000)
		TempMax = TempMax - 1
	Loop While(TempMax > 0 and stReponse ="") 
	AttenteReponse = Left(stReponse,3) ="+OK"
end Function

encore faut-t'il que tu n'est pas de problème de licence avec WinSock...

[loufred]

désolé pour le retard,
merci beaucoup, ca marche nickel...