Discussion :

[OtObOx]

Bonjour à tous,

je programme quelques macros sur AutoCAD et je cherche un moyen efficace pour savoir de quel coté d'une droite quelconque dans un plan je clique.

Ma droite est définie par 2 points A(x1,y1) et B(x2,y2) et j'ai un point M(x,y) qui n'est pas sur la droite.

Pour l'instant, la méthode que j'ai trouvée, mais qui ne fonctionne pas correctement, c'est de calculer l'angle que j'ai entre AB et AM.
Ca ne fonctionne pas toujours, car les angles retournés sont entre + ou - [0 2PI]

Je me demandais s'il y avait une autre astuce pour faire ça, l'idée étant de trouver le sens du vecteur perpendiculaire à AB dans le plan.

Merci,

Jean-Marc


Edit : j'ai trouvé l'astuce il suffisait de passer par les équations de 2 droites perpendiculaires... Tellement évidente qu'elle ne m'était pas passée par la tête immédiatement

JM

[ToTo13]

Edit : j'ai trouvé l'astuce il suffisait de passer par les équations de 2 droites perpendiculaires... Tellement évidente qu'elle ne m'était pas passée par la tête immédiatement

Euh... oui mais il y a encore plus simple.
Une seule équation droite suffit.
- Si la droite passant par tes deux points (A,B) est y=ax+b, et que tu souhaites savoir où est ton point M(X,Y)
- tu calcules aX+b
- si ax+b > Y alors ton point est en dessous de la droite, sinon il est au dessus.

[OtObOx]

Tu as raison, c'est beaucoup plus simple ainsi Merci pour ce truc que je ne connaissais pas ! Difficile de se remettre au programme de 3e quand ça fait plus de 20 ans qu'on a quitté les bancs de l'école !

Jean-Marc

[ijk-ref]

- Si la droite passant par tes deux points (A,B) est y=ax+b, et que tu souhaites savoir où est ton point M(X,Y)
- tu calcules aX+b

Moué ! Ce n'est pas encore le plus simple et il y a deux problèmes :
- impossible de le déterminer pour une droite verticale
- l'équation n'indique pas du quelle coté se trouve M par rapport au vecteur AB. par exemple une rotation de 180° des points A, B et M ne donne pas le même résultat.

La formule générale est plutôt : signe de "(A^B).M"

"^" : étant le produit vectoriel
"." : étant le produit scalaire

soit (A^B).M = ((Ax, Ay, 1)^(Bx, By, 1)).(Mx, My, 1)

= (Ay - By)*Mx + (Bx - Ax)*My + (Ax.By - Ay.Bx)

[OtObOx]

La solution de Toto13 est simple, mais elle ne convenait pas à mes besoins. La finalité de ma fonction étant de trouver le vecteur unitaire perpendiculaire à une droite et de direction donnée par le clic. J'ai donc écrit quelques procédures qui fonctionnent très bien.

Je les donne ici, c'est pour AutoCAD, et elles ne sont pas optimisées pour certaines, mais elles marchent ! Comme je travaille en 3d, je convertis mes points dans le plan du SCU courant (SCU=Système de Coordonnées Utilisateurs, différent du SCG=Système de Coordonnées Générales) puisque les fonctions ne sont valables que dans le plan.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
 
'---------------------------------------------------------------------------------------
' Procedure : RejetEpaisseur
' Auteur    : Jean-Marc
' Date      : 29/03/2010
' Sujet     : Cette fonction retourne un vecteur de longueur 1 perpendiculaire à une
'             droite définie par 2 points pd et pa et de sens allant vers le 3e point
'             cliqué. Protection si le pt cliqué est sur la droite.
'---------------------------------------------------------------------------------------
'
Private Function RejetEpaisseur(pd As Variant, pa As Variant, pm As Variant, message As String) As Variant
Dim pr, v
Dim ppSCU, prSCU, pdSCU, paSCU, vSCU
 
   On Error GoTo RejetEpaisseur_Error
 
    Do
        pr = ThisDrawing.Utility.GetPoint(pm, message) 'Rejet d'épaisseur dans SCG
        prSCU = ThisDrawing.Utility.TranslateCoordinates(pr, acWorld, acUCS, False)
        paSCU = ThisDrawing.Utility.TranslateCoordinates(pa, acWorld, acUCS, False)
        pdSCU = ThisDrawing.Utility.TranslateCoordinates(pd, acWorld, acUCS, False)
        ppSCU = DroitePerpPassantParUnPoint(pdSCU, paSCU, prSCU)
        vSCU = vect3d(ppSCU, prSCU) 'Vecteur direction dans le SCU
        If longVecteur3d(vSCU) <> 0 Then Exit Do
        MsgBox "Vous avez cliqué sur la ligne !", vbCritical, "Erreur"
    Loop
    vSCU = vectUnit3d(vSCU) 'Vecteur unitaire dans le SCU
    v = ThisDrawing.Utility.TranslateCoordinates(vSCU, acUCS, acWorld, True) 'Convertion dans SCG
    RejetEpaisseur = v
 
   On Error GoTo 0
   Exit Function
 
RejetEpaisseur_Error:
 
    MsgBox "Error " & Err.Number & " (" & Err.Description & ") dans la procédure RejetEpaisseur du Module Cornieres"
    RejetEpaisseur = Null
End Function
 
'---------------------------------------------------------------------------------------
' Procedure : DroitePerpPassantParUnPoint
' Auteur    : Jean-Marc
' Date      : 29/03/2010
' Sujet     : Cette fonction donne le point d'intersection M de deux droites
'             perpendiculaires AB et AM
'---------------------------------------------------------------------------------------
'
Private Function DroitePerpPassantParUnPoint(ptA As Variant, ptB As Variant, ptC As Variant) As Variant
Dim Xa As Double, Ya As Double
Dim Xb As Double, Yb As Double
Dim Xc As Double, Yc As Double
Dim ptD(0 To 2) As Double
Dim a As Double, b As Double
Dim a1 As Double, b1 As Double
 
   On Error GoTo DroitePerpPassantParUnPoint_Error
 
Xa = ptA(0): Ya = ptA(1)
Xb = ptB(0): Yb = ptB(1)
Xc = ptC(0): Yc = ptC(1)
If (Xb - Xa) <> 0 Then
    a = (Yb - Ya) / (Xb - Xa)
    b = Ya - a * Xa
    If a <> 0 Then
        a1 = -1 / a
        b1 = Yc - a1 * Xc
        ptD(0) = (b1 - b) / (a - a1)
        ptD(1) = a * ptD(0) + b
    Else 'Droite horizontale
        ptD(0) = Xc
        ptD(1) = Ya
    End If
Else 'Droite verticale
    ptD(0) = Xa
    ptD(1) = Yc
End If
ptD(2) = ptC(2)
'ptD(2) = ptA(2)
DroitePerpPassantParUnPoint = ptD
 
   On Error GoTo 0
   Exit Function
 
DroitePerpPassantParUnPoint_Error:
 
    MsgBox "Error " & Err.Number & " (" & Err.Description & ") dans la procédure DroitePerpPassantParUnPoint du Module Cornieres"
End Function
 
 
 
'Défini un vecteur3d à partir de 2 points
Private Function vect3d(pointA As Variant, pointB As Variant) As Variant
Dim Tableau(0 To 2) As Double
    Tableau(0) = pointB(0) - pointA(0)
    Tableau(1) = pointB(1) - pointA(1)
    Tableau(2) = pointB(2) - pointA(2)
    vect3d = Tableau
End Function
 
 
 
'Calculer la norme d'un vecteur 3d
Private Function longVecteur3d(vecteur As Variant) As Double
longVecteur3d = Sqr(vecteur(0) ^ 2 + vecteur(1) ^ 2 + vecteur(2) ^ 2)
End Function
 
 
 
'Défini en 3d le vecteur unitaire d'un vecteur
Private Function vectUnit3d(vecteur) As Variant
Dim Tableau(0 To 2) As Double
Dim longueur As Double
    longueur = longVecteur3d(vecteur)
    Tableau(0) = vecteur(0) / longueur
    Tableau(1) = vecteur(1) / longueur
    Tableau(2) = vecteur(2) / longueur
    vectUnit3d = Tableau
End Function

Je vais cependant creuser ce que tu disais, à propos du produit vectoriel et du produit scalaire, car j'ai régulièrement besoin de savoir de quel coté ce situe un point par rapport à une droite.

Jean-Marc

[Nebulix]

Comment définis-tu les "côtés" ?

[OtObOx]

Je pointe dans le vide sur un des deux cotés de la droite à l'écran (ou je rentre un point déjà calculé), et la fonction RejetEpaisseur me retourne un vecteur, de longueur 1, qui est perpendiculaire à la droite, et qui va dans la direction du coté où j'ai sélectionné.
Ensuite, que le vecteur soit en bas, en haut, à gauche ou à droite, je m'en fiche, je recherchais uniquement le sens du vecteur perpendiculaire !

Jean-Marc

[Nebulix]

c'est plus facile quand la question est précise
en oubliant la normalisation, tu dois choisir entre le vecteur V de coordonnées
( -(y2-y1),(x2-x1)) et son opposé.
si le produit scalaire de ce vecteur avec AM :
-(y2-y1)*(x-x1)+(x2-x1)*y-y1) est
nul : M est sur la droite AB
positif :OK
négatif : prends l'opposé(-V)