[FLASH MX2004] Utiliser une variable dans le code

**arnolem** · 02/12/2005, 11h51

Bonjour, j'ai un problème tout bête mais qui me fait bien chier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
function UpAlpha(clip:MovieClip) {
	_root.[clip]._alpha += 1;
}

Je pense que vous l'avez, compris, je veux définir un clip suivant la variable utilisée dans la fonction, mais ça ne marche pas, c'est tout con pourtant

**ekameleon** · 02/12/2005, 11h56

hello

1 - l'utilisation de la syntaxe entre crochet se fait avec une "chaine de caractère" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
this.monClip._x = 25 ;
this["monClip"]._y = 40 ;

On peut simplifier ce code au dessus à n'importe quel objet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
var o = {} ;
o["prop"] = "coucou" ;
trace (o.prop) ;
trace (o["prop"]) ;

du coup... ton code est TOTALEMENT FAUX

car tu écris [] aprés un point "." et là cela veut dire que tu cherches à créer un Array ... quand on utilise seul les crochets ... c'est le constructeur d'un tableau (aucun rapport donc)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
var ar = ["coucou"] ;
trace (ar[0]) ;

Du coup si tu veux cibler un clip suffit de l'appeller directement non ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
function upAlpha(clip:MovieClip) {
   clip._alpha += 1;
}

Sinon si tu as son nom en chaine de caractère alors :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
function upAlpha( myClip:String , target:MovieClip ) {
   target[myClip]._alpha += 1;
} 
upAlpha("monClip", _root) ; // je change l'alpha du clip monClip ciblé sur le _root !

Voilà en gros ce qu'il faut savoir.. fait des tests pour comprendre tout cela

eKA+

**arnolem** · 02/12/2005, 12h01

je te remerci, non pour le point avant c'est une erreur de frappe, merci pour ce cour aussi clair, pourquoi ne rédige tu pas des petits tutos sur developpez.com ?

**ekameleon** · 02/12/2005, 12h05

Car j'ai pas le temps de le faire ... lol ... je m'occuperai d'en écrire sur mon site perso (faut dire que j'aide pas qu'ici .. je suis modo sur plusieurs forums et je veux pas faire de jaloux

)
EKA+

**arnolem** · 02/12/2005, 12h06

alors mon problèmer viens du setInterval ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
_root.toto_mc.onRollOver = function() {
	interUp = setInterval(UpAlpha(toto_mc), 5);
};
function UpAlpha(clip:MovieClip) {
	clip._alpha += 1;
}

**ekameleon** · 02/12/2005, 12h14

Oui il vient du setInterval .. car tu as pas lu la doc à ce sujet.... lol

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
function UpAlpha(clip:MovieClip) {
   clip._alpha += 1;
} 
 
var interUp:Number ; // pense à déclarer tes variables avec var c'est important
 
toto_mc.onRollOver = function() {
   interUp = setInterval( UpAlpha, 10, this);
};

Pense à utiliser un this dans une fonction liée à un clip ! ou à l'objet que tu cherches à utiliser ... le this c'est très important en ActionScript... il permet de savoir où tu te trouves au niveau de ton ciblage :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
trace (this) ;

Sinon pourquoi tu utilises un setInterval ? en dessous de 150ms un setInterval fait pas de différence niveau vitesse avec un onEnterFrame... du coup :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
function UpAlpha(clip:MovieClip) {
   clip._alpha += 1;
} 
 
toto_mc.onRollOver = function() {
   this.onEnterFrame = function () {
             this._alpha += 10 ;
            if (this._alpha >= 100) delete this.onEnterFrame ;
   }
};

Que cela soit pour un setInterval ou un onEnterFrame pense à toujours arrêter la boucle infinie quand tu ne t'en sert plus.. sinon le CPU est très rapidement mal mené

EKA+

**arnolem** · 02/12/2005, 12h22

Oki ouai je vais regarder, en fait je t'ai pas mis tout le code, pour la déclaration et de clearInterval c'était Ok, j'ai aussi la fonction onRollOut.

Je te tient au courant

**arnolem** · 02/12/2005, 12h26

ouai ça va etre bon, je te remerci, pour le setInterval, c'est par se que le parametre d'interval va etre dynamique, il ne va pas rester à 5ms, sinon c'est vrai que ça n'a pas de sens

**arnolem** · 02/12/2005, 12h41

si tu est encore la, je vais avoir besoin de toi monsieur, j'ai refait un tour sur le code et j'ai fais un test avec 4 clip, et toujour mon setInterval.
Le problème est que je dois déclarer autant de setInterval que de clip (si tu à une autre idée ?)
mais surtout, lorsque je test, je survole une fois, ça marche, je survole 2 fois, ça marche, par contre la 3ème fois, il ne se passe plus rien !!!

voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
 
//
//Déclaration de variables
//
var eddieInterUp:Number;
var eddieInterDown:Number;
var julInterUp:Number;
var julInterDown:Number;
var alexInterUp:Number;
var alexInterDown:Number;
var tomInterUp:Number;
var tomInterDown:Number;
//
//Déclaration de fonctions
//
function UpAlpha(clip:MovieClip) {
	clip._alpha += 1;
}
function DownAlpha(clip:MovieClip) {
	if (clip._alpha>20) {
		clip._alpha -= 1;
	}
}
//
//Code source
//
_root.eddie_mc.onRollOver = function() {
	clearInterval(eddieInterDown);
	interUp = setInterval(UpAlpha, 5, this);
};
_root.eddie_mc.onRollOut = function() {
	clearInterval(eddieInterUp);
	interDown = setInterval(DownAlpha, 5, this);
};
_root.jul_mc.onRollOver = function() {
	clearInterval(julInterDown);
	interUp = setInterval(UpAlpha, 5, this);
};
_root.jul_mc.onRollOut = function() {
	clearInterval(julInterUp);
	interDown = setInterval(DownAlpha, 5, this);
};
_root.alex_mc.onRollOver = function() {
	clearInterval(alexInterDown);
	interUp = setInterval(UpAlpha, 5, this);
};
_root.alex_mc.onRollOut = function() {
	clearInterval(alexInterUp);
	interDown = setInterval(DownAlpha, 5, this);
};
_root.tom_mc.onRollOver = function() {
	clearInterval(tomInterDown);
	interUp = setInterval(UpAlpha, 5, this);
};
_root.tom_mc.onRollOut = function() {
	clearInterval(tomInterUp);
	interDown = setInterval(DownAlpha, 5, this);
};

A mon avis, c'est le clear qui détruit les variable mais je vois pas comment le redéclarer à chaque fois

**ekameleon** · 02/12/2005, 13h01

Déjà utilise pas le setInterval .. je te l'ai dit cela sert à rien un setInterval quand tu es en dessous de 150 ms ... vaut mieux utiliser un onEnterFrame

Au passage je te déconseille de débuter le nom de tes fonctions par une majuscule... je sais pas si tu as remarqué que dans flash seul les "classes" commencent par une majuscule... niveau nomenclature vaut mieux respecter ceci

Pour ce qui est du _root ! si tu es en local sur la scène principal .. n'utilise pas de _root. Si un jour tu dois changer ton animation et la charger dans une autre tu vas avoir des problèmes

Au mieux utilise un this !! sinon pas de ciblage du tout car tu es en local sur le _root justement.
Sinon utilise une variable temporaire qui sert de raccourci vers ton ciblage.

Pour le coté dynamique des choses.. il faut pas donner des noms complexes à tes objets.. et faut que tes boutons aient pour nom : bt1, bt2 etc...
regarde :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
function upAlpha(clip:MovieClip) {
   clip._alpha += 10 ;
   if (clip._alpha >= 100) {
		clearInterval(this.idTime) ;
   }
}
function downAlpha(clip:MovieClip) {
   clip._alpha -= 10;
   if (clip._alpha <= 20) {
		clearInterval(this.idTime) ;
   }
}
 
var nBts:Number = 5 ; // nombres de boutons
for (var i:Number = 0 ; i<nBts ; i++) {
	this["bt"+i].onRollOver = function() {
	   this.idTime = setInterval(upAlpha, 5, this);
	}
	this["bt"+i].onRollOut = function() {
	   clearInterval(this.idTime);
	   this.idTime = setInterval(downAlpha, 5, this);
	}
}

Voilà ainsi bt1, bt2, ..., bt5 vont avoir tous le même code d'un seul coup ...
EKA+

**arnolem** · 02/12/2005, 13h08

Merci de prendre du temps pour signeler aussi le niveau syntaxique,
peux tu m'expliquer cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
clearInterval(this.idTime) ;

**ekameleon** · 02/12/2005, 13h26

j'ai juste fait en sorte que la variable idTime (l'identifiant numérique unique du setInterval qui est un nombre et qui permet de le retrouver ensuite dans un clearInterval...) et bien cet identifiant vu que c'est un valeur de type Number... je l'ai enregistrer dynamiquement dans l'objet qui m'intéresse en l'occurence le bouton qui l'utilise..
Ainsi je retrouve facilement l'identifiant d'un bouton en ciblant sur le bouton lui même la variable que j'ai créé pour lui ... ainsi chaque bouton à sa propre propriété dynamique idTime (que j'ai inventé... j'aurai pu l'appelé comme je veux) et j'ai pas à déclarer des tonnes de variables à l'extérieur des fonctions)... je reste en local dans le bouton

eKA+

**arnolem** · 02/12/2005, 14h30

je ne sais pas si ton code est complet mais dans mon cas, ça ne marche pas,
Je ne vois pas le problème pourtant, lors du survole, rien ne se passe par contre lorsque je ne survole plus, les clip disparaisse
et apres 3 secondes, il réaparaisse puis disparaisse sans progression de l'alpha

**ekameleon** · 02/12/2005, 14h33

Pourquoi tu utilises pas onEnterFrame tu as un problème sur cette fonction ?

elle est au niveau des clips tout de même + simple d'emploi et surtout elle est faite pour cela !
EKA+

**ekameleon** · 02/12/2005, 14h34

excuse au dessus .. faut pas mettre this.idTime mais clip.idTime dans les clearInterval bien entendu .. j'ai fait une petite erreur mais elle est logique non ?

**arnolem** · 02/12/2005, 14h45

Je ne t'en veux pas

mais j'ai fait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
function upAlpha(clip:MovieClip) { 
   clip._alpha += 10 ; 
   if (clip._alpha >= 100) { 
      clearInterval(clip.idTime) ; 
   } 
} 
function downAlpha(clip:MovieClip) { 
   clip._alpha -= 10; 
   if (clip._alpha <= 20) { 
      clearInterval(clip.idTime) ; 
   } 
} 
 
var nBts:Number = 5 ; // nombres de boutons 
for (var i:Number = 0 ; i<nBts ; i++) { 
   this["bt"+i].onRollOver = function() { 
      this.idTime = setInterval(UpAlpha, 5, this); 
   } 
   this["bt"+i].onRollOut = function() { 
      clearInterval(this.idTime); 
      this.idTime = setInterval(downAlpha, 5, this); 
   } 
}

et il y a toujour un problème, si vraiment c'est pourri, je vais mettre un enterFrame mais en fait j'avais besoin de faire un interval dynamique.
tu en pense quoi ? la le problème c'est qu'au survole, les image perde 10 en alpha a chaque rollOut et rien en rollOver

**ekameleon** · 02/12/2005, 14h53

Tu aimes bien te compliquer la vie en fait

Tu as vu que tu as des majuscules dans ton setInterval sur UpAlpha... et pas dans le nom de la fonction au dessus ? soit attentif

La casse des mots en actionscript est super importante

Là normalement cela marche nickel hein

Maintenant pour aller un peu + loin on peut tenter l'approche d'utiliser la valeur des variables de type Function pour aller + vite et avoir un code + clair :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
var fadeIn = function () {
	this.onEnterFrame = function () {
	   this._alpha += 10 ;
	   if (this._alpha >= 100) delete this.onEnterFrame ;
	}
}
var fadeOut = function () {
	this.onEnterFrame = function () {
	   this._alpha -= 10 ;
	   if (this._alpha <= 20) {
		   this._alpha = 20 ;
		   delete this.onEnterFrame ;
		}
	}
}
 
var nBts:Number = 5 ; // nombres de boutons
for (var i:Number = 0 ; i<nBts ; i++) {
	var bt:MovieClip = this["bt"+i] ;
	bt.onRollOver = fadeOut ;
   	bt.onRollOut = fadeIn ;
}

EKA+

**arnolem** · 02/12/2005, 15h03

Tu a raison pour la majuscul mais ça ne marche pas de toutes facon, bon tu a raison je vais le faire avec l'enterframe, ça me prendra moin la tete, surtout que je ne vois pas pourquoi elle ne marche pas.

Eka, je commence à bien t'aimer, si tu passe en normandie, viens prendre un coup à la maison !

encore merci

**ekameleon** · 02/12/2005, 15h06

Moi en tout cas cela marche... je sais pas aprés comment tu gères cela dans ton fla

La normandie en ce moment c'est trop dans la zone froide de la france lol Faudra attendre un peu avant que je passe par là

je suis trop frileux

Mais bon merci pour l'invitation en tout cas

EKA+

**arnolem** · 02/12/2005, 15h24

parti de ton code, je veux maintenant que chaque bouton ouvre un lien :
J'ai donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
var link1:String = "http://<a href="http://www.developpez.com"" target="_blank">www.developpez.com"</a>
var nBts:Number = 5;
// nombres de boutons 
for (var i = 1; i<nBts; i++) {
	var bt:MovieClip = this["bt"+i];
	bt.onRollOver = fadeOut;
	bt.onRollOut = fadeIn;
	bt.onPress = function () {
		trace("link"+i);
	}
}

Il me renvoi à chaque clic, LINK5
j'ai aussi une autre question, quelle est la différence entre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
bt.onPress = function () {
	trace("link"+i);
}

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

bt.onPress = trace("link"+i);

Merci encore merci (d'etre patient)[/quote]

[FLASH MX2004] Utiliser une variable dans le code

Flash

Discussions similaires

Partager

Partager