Discussion :

[Pimprenelle]

Bonjour à tous,

J'ai parcouru les pages du forum, et je ne pense pas avoir vu de sujet qui pourraient m'aider dans mon problème. Aussi je m'excuse si je fais un doublon.

Voilà mon soucis :

Je déplace un clip à l'aide du clavier, pour ca j'utilise bien entendu un écouteur. Et...logiquement, je n'arrive pas à le déplacer en diagonale.

Voici mon code, inclut dans la classe Avatar

public function Avatar()
{

//création d'un sprite bidon pour mon test
_sprite=new Sprite();
_sprite.graphics.beginFill(0x0000ff,100);
_sprite.graphics.drawCircle(0,0,25);
_sprite.graphics.endFill();
_sprite.x=50;
_sprite.y=100;

//ajout à la liste d'affichage
addChild(_sprite);

//ajout à un écouteur
addEventListener(KeyboardEvent.KEY_DOWN, displacement);

}

public function displacement(evt:KeyboardEvent)
{
switch(evt.keyCode)
{
// déplacement vers la gauche
case Keyboard.LEFT:
_sprite.x-=depx
break;

// déplacement vers le haut
case Keyboard.UP:
_sprite.y-=depy;
break;

// déplacement vers la droite
case Keyboard.RIGHT:
_sprite.x+=depx;
break;

// déplacement vers le bas
case Keyboard.DOWN:
_sprite.y+=depx;
break;

// pas de déplacement
default :
_sprite.x+=0;
}

}

Et dans mon scénario principal tout ce qu'il faut.

J'ai déjà testé de mettre 2 écouteurs pour le même évènement...de ne pas faire de case et de tester séparément les déplacement x et y, mais je ne trouve pas.

Il s'agit surement d'une petite astuce que je pourrais trouver en cherchant un peu (ou beaucoup), mais comme je ne dispose que d'un mois pour réaliser ce jeu, je préfère vous demander (je laisse ma fierté de coté ).

Merci à tous.

Pimprenelle

[boadog]

La réponse à ton problème se trouvait sur ce forum:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
 
stage.focus = this;
 
var droite:Boolean = new Boolean ();
var haut:Boolean = new Boolean ();
var gauche:Boolean = new Boolean ();
var bas:Boolean = new Boolean ();
 
this.addEventListener(KeyboardEvent.KEY_DOWN, toucheDown);
this.addEventListener(KeyboardEvent.KEY_UP, toucheUp);
this.addEventListener(Event.ENTER_FRAME, deplace);
 
function toucheDown(evt:KeyboardEvent) {
	if (evt.keyCode == 38) {
		haut=true;
	}
	if (evt.keyCode == 39) {
		droite=true;
	}
	if (evt.keyCode == 37) {
		gauche=true;
	}
	if (evt.keyCode == 40) {
		bas=true;
	}
}
function toucheUp(evt:KeyboardEvent) {
	if (evt.keyCode == 38) {
		haut=false;
	}
	if ( evt.keyCode == 39) {
		droite=false;
	}
	if (evt.keyCode == 37) {
		gauche=false;
	}
	if (evt.keyCode == 40) {
		bas=false;
	}
}
function deplace(evt:Event) {
	if (droite) {
		monClip.x++;
	}
	if (haut) {
		monClip.y--;
	}
	if (gauche) {
		monClip.x--;
	}
	if (bas) {
		monClip.y++;
	}
}

Est-ce que ça t'aide?

[Pimprenelle]

Ca marche parfaitement ! Merci beaucoup, je n'ai pas pensé à rajouter un 3e écouteur...

Désolée également pour le doublon.

Bonne soirée et surement à bientôt

Pimprenelle