Discussion :

[PaLoTTe]

Bonjour !

Je suis en train de dev un HTA (HTML Application).

Lors du chargement (Window_Onload), je souhaite récupérer des infos de l'AD et les placés dans un menu déroulant.

Mon <select> s'appelle selectOU et j'ai essayer les lignes suivantes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
selectOU.addItem "TOTO"
selectOU.add "TOTO"
vOption = document.createElement("OPTION")
vOption.Text = "TOTO"
vOption.value = "TITI"
selectOU.add vOption

J'arrive pas trop a trouver la fonction qui me permet d'ajouter des items à mon SELECT...

Quelqu'un aurait une idée ?

Merci.

[omen999]

salut,
tout sur l'objet select par le créateur du hta: http://msdn2.microsoft.com/en-us/library/ms535893.aspx

[RadPAT]

Salut PaLoTTe,

apparemment nous sommes en train de faire la même developpement chacun de notre coté !!

Voici un exemple de ce que j'ai fait pour afficher les PC qui sont dans l'OU Computer de Fabrikam.Com avec une listbox :

D'abord ton extraction classique des pc avec un query LDAP, puis le select qui t'interesse :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
    Const ADS_SCOPE_SUBTREE = 1
 
    Set objConnection = CreateObject("ADODB.Connection")
    Set objCommand =   CreateObject("ADODB.Command")
    objConnection.Provider = "ADsDSOObject"
    objConnection.Open "Active Directory Provider"
    Set objCommand.ActiveConnection = objConnection
 
    objCommand.Properties("Page Size") = 1000
    objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
 
    objCommand.CommandText = "SELECT Name FROM 'LDAP://ou=Computers,dc=fabrikam,dc=com' Where objectClass='computer'"
    Set objRecordSet = objCommand.Execute
 
    If objRecordSet.RecordCount > 0 Then
       objRecordSet.MoveFirst
       Do Until objRecordSet.EOF
          Set objOption = Document.createElement("OPTION")
          objOption.Text = objRecordSet.Fields("Name").Value
          objOption.Value = objRecordSet.Fields("Name").Value
          Pioute1.Add(objOption)
          objRecordSet.MoveNext
       Loop
    End If

Pour RAZ ta listbox tu fais ca :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
    For Each objOption in Pioute1.Options
        objOption.RemoveNode
    Next

et dans le design HTA tu retrouveras ca :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
<fieldset><legend>Computers</legend>
<select size="15" name="Pioute1" Id="Pioute1" style="width:400" ondblClick="testPioute">
</select>

En ce qui me concerne, pour les grosses listes je préfère les lists views c'est plus sympa et tu peux mieux structurer tes infos (par exemple je n'ai jamais trouvé le moyen de faire un tab ou vbtab dans une listbox).
voici 2 imprim écran sur la liste des PC et la liste des Users de notre active directory :

Si tu veux qu'on discute de nos avancées respectives pas de soucis.

A+