1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
<%
'--------------------------------------------------------------------
'The "ConvertFormtoXML" Function accepts to parameters.
'strXMLFilePath - The physical path where the XML file will be saved.
'strFileName - The name of the XML file that will be saved.
'--------------------------------------------------------------------
Function ConvertFormtoXML(strXMLFilePath, strFileName)
'Declare local variables.
Dim objDom
Dim objRoot
Dim objField
Dim objFieldValue
Dim objattID
Dim objattTabOrder
Dim objPI
Dim x
'Instantiate the Microsoft XMLDOM.
Set objDom = server.CreateObject("Microsoft.XMLDOM")
'objDom.preserveWhiteSpace = True
objDom.preserveWhiteSpace = False
'Create your root element and append it to the XML document.
Set objRoot = objDom.createElement("contact")
objDom.appendChild objRoot
'Iterate through the Form Collection of the Request Object.
For x = 1 To Request.Form.Count
'Check to see if "btn" is in the name of the form element.
'If it is, then it is a button and we do not want to add it
'to the XML document.
If instr(1,Request.Form.Key(x),"btn") = 0 Then
'Create an element, "field".
Set objField = objDom.createElement("field")
'Create an attribute, "id".
Set objattID = objDom.createAttribute("id")
'Set the value of the id attribute equal the the name of
'the current form field.
objattID.Text = Request.Form.Key(x)
'The setAttributeNode method will append the id attribute
'to the field element.
objField.setAttributeNode objattID
'Create another attribute, "taborder". This just orders the
'elements.
Set objattTabOrder = objDom.createAttribute("taborder")
'Set the value of the taborder attribute.
objattTabOrder.Text = x
'Append the taborder attribute to the field element.
objField.setAttributeNode objattTabOrder
'Create a new element, "field_value".
Set objFieldValue = objDom.createElement("field_value")
'Set the value of the field_value element equal to
'the value of the current field in the Form Collection.
objFieldValue.Text = Request.Form(x)
'Append the field element as a child of the root element.
objRoot.appendChild objField
'Append the field_value element as a child of the field elemnt.
objField.appendChild objFieldValue
End If
Next
'Create the xml processing instruction.
Set objPI = objDom.createProcessingInstruction("xml", "version='1.0'")
'Append the processing instruction to the XML document.
objDom.insertBefore objPI, objDom.childNodes(0)
'Save the XML document.
objDom.save strXMLFilePath & "\" & strFileName
'Release all of your object references.
Set objDom = Nothing
Set objRoot = Nothing
Set objField = Nothing
Set objFieldValue = Nothing
Set objattID = Nothing
Set objattTabOrder = Nothing
Set objPI = Nothing
End Function
'Do not break on an error.
On Error Resume Next
'Call the ConvertFormtoXML function, passing in the physical path to
'save the file to and the name that you wish to use for the file.
ConvertFormtoXML "C:\\sabotiers2\","Contact.xml"
'Test to see if an error occurred, if so, let the user know.
'Otherwise, tell the user that the operation was successful.
If err.number <> 0 then
Response.write("Problème lors de l'enregistrement du texte.")
Else
session("etat") = "Mise à jour effectuée avec succès."
Response.Redirect("default.asp")
End If
%> |
Formattage texte XML dans Flash
Répondre avec citation
Partager