Discussion :

[theolarrousse]

Bonjour,

j'ai un petit problème et pas envie de passer par 50 manip...
Je suis vraiment novice aussi, merci de votre patiente si je comprends rien^^

Voilà mon pb:

j'ai plusieurs lignes par patients avec des dates et surtout une variable GAP ( de 0 à 327 jours au maximum).
Ce que j'aimerais c'est supprimer les patients qui ne contienne pas de GAP supérieur à 90 jours.
MAIS, je dois garder toutes les observations pour ces patients et pas seulement garder les GAP supérieur à 90.

Si je suis pas clair je vous illustre ça


Patient1: Date1 GAP125
Patient1: Date2 GAP0
Patient1: Date3 GAP0
Patient1: Date4 GAP55
Patient2: Date1 GAP0
Patient2: Date2 GAP0
Patient2: Date3 GAP3
Patient2: Date4 GAP60

Donc ce que je veux c'est supprimer le patient 2 et obtenir ça:

Patient1: Date1 GAP125
Patient1: Date2 GAP0
Patient1: Date3 GAP0
Patient1: Date4 GAP55


Merci beaucoup,
Théo

[m.brahim]

Bonjour,

Je te propose cette solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
data test;
input patient $ date $ gap$;
cards;
Patient1  Date1 GAP125
Patient1  Date2 GAP0
Patient1  Date3 GAP0
Patient1  Date4 GAP55
Patient2  Date1 GAP0
Patient2  Date2 GAP0
Patient2  Date3 GAP3
Patient2 Date4 GAP60
patient3 date1 GAP91
; run;
 
proc sql;
create table test1 as select t1.*  
from test as t1 group by patient 
having max(input(substr(gap,4),8.))>90 
;
quit;

Cordialement

[hossward]

Bonjour,
Une solution sans SQL :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
data Table_1 ;
input Patient $ Date $ GAP $;
cards;
Patient1: Date1 GAP125
Patient1: Date2 GAP0
Patient1: Date3 GAP0
Patient1: Date4 GAP55
Patient2: Date1 GAP0
Patient2: Date2 GAP0
Patient2: Date3 GAP3
Patient2: Date4 GAP60
; run ;  
 
data Table_2 ;
flag=0 ;
do until (last.Patient);
   set Table_1 ; by patient notsorted ;
  if compress(GAP, 'GAP')*1 >90 then flag=1 ;
 
end;   
do until (last.Patient);
   set Table_1 ; by patient notsorted ;
   if flag then output;
   drop flag ;
end;
run;

Ward

[theolarrousse]

Merci beaucoup,

je test ces deux manip demain matin et je vous tiens au courant!

Bonne journée

[theolarrousse]

Bonjour,

ces deux méthodes furent d'une extraordinaire efficacité!

Merci encore et désolé pour mon orthographe désastreux dans mon premier message.

Théo.