déploiment de raccourci sur le bureau par script

**brice_94** · 25/08/2010, 09h02

bonjour,

j'ai modifier la ligne qui posait problème mais maintenant
j'en ai une autre :

ligne: 7
caract. : 6
erreur: instruction attendue
code : 800A0400
source: erreur de compilation M VBscript

**ProgElecT** · 25/08/2010, 17h41

Salut

Envoyé par brice_94

bonjour,
.....
ligne: 7
caract. : 6
....

Mes nous la ligne ou se produit l'erreur car là, pour ma part, je ne voie pas à quoi correspond cette ligne d'erreur.

**l_autodidacte** · 25/08/2010, 21h44

Pourtant sur mes 2 machines(XP Home et XP Pro), il n'y a aucun message d'erreur.
Je viens juste de rectifier le code en mettant les n° de lignes et en permettant l'annulation de l'action à entreprendre.
Reteste-le et regarde si l'erreur persiste ou non.
Il faut savoir(chose connue de tous) qu'une ligne vide(ou saut de ligne) compte et que la variable Msg est affectée sur une SEULE ligne bien qu'en apparence, elle en occupe 4.

**brice_94** · 26/08/2010, 08h54

bonjour,

ok merci c'est bien ce je voulais et avec ça peut-on
rajouter le déploiment de word excel et outlook
je suppose que pour cela il faut qu'il soit déja installer

**l_autodidacte** · 26/08/2010, 16h07

Oui si on indique le chemin de chaque programme(si installé)

**brice_94** · 26/08/2010, 16h20

bonsoir,

merci mais l'indiquer ok mais comment en VBS ?

**l_autodidacte** · 26/08/2010, 17h17

Comme dans ce POST

**brice_94** · 27/08/2010, 09h27

bonjour,

donc si j'ai bien compris je dois rajouter ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
Dim lRet,RegVal,Msg,WS,strDesktop,tb(3)
tb(1)="C:\Program Files\Microsoft Office\Winword.exe"
tb(2)="C:\Program Files\Microsoft Office\Excel.exe"
tb(3)="C:\Program Files\Microsoft Office\Outlook.exe"

c'est bien ça ?

**l_autodidacte** · 27/08/2010, 22h16

Bon voici tout le code en espérant avoir correctement répondu à tes questions:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Option Explicit
Dim WS, strDesktop, oMyShortCut,FSO,myShort
Dim I,Prg,Prg1, Msg,tb(3),lRet,RegVal,Creer
 
Const DestKey="HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel\"
tb(1)="C:\Program Files\Microsoft Office\Winword.exe"
tb(2)="C:\Program Files\Microsoft Office\Excel.exe"
tb(3)="C:\Program Files\Microsoft Office\Outlook.exe"
 
set Fso=CreateObject("Scripting.FileSystemObject")
Set WS = WScript.CreateObject("WScript.Shell")
Msg="Souhaitez-vous afficher les éléments suivants sur le bureau ?" _
     & vbcrlf & vbtab & Ucase("Poste de travail") _
     & VbCrLf & vbtab & uCase("Mes Documents") _
     & VbCrLf & vbtab & Ucase("Favoris Réseau") _
     & VbCrLf & vbtab & Ucase("Internet Explorer") _
     & VbCrLf & vbtab & Ucase("winword") _
     & VbCrLf & vbtab & Ucase("Outlook") _
     & VbCrLf & vbtab & Ucase("Excel") 				          
lRet= MsgBox(Msg,VbYesNoCancel,"Raccourcis bureau")				 
If lRet=VbYes then
   RegVal="0"
   Creer=True
ElseIf lRet=VbNo Then
   RegVal="1"
   Creer=False 
ElseIf lRet=VbCancel Then
   Wscript.Quit
End If									
WS.RegWrite DestKey & "{20D04FE0-3AEA-1069-A2D8-08002B30309D}",RegVal,"REG_DWORD"  ' Poste de travail
WS.RegWrite DestKey & "{450D8FBA-AD25-11D0-98A8-0800361B1103}",RegVal,"REG_DWORD"  ' Mes documents
WS.RegWrite DestKey & "{208D2C60-3AEA-1069-A2D7-08002B30309D}",RegVal,"REG_DWORD"  ' Favoris Réseau
WS.RegWrite DestKey & "{871C5380-42A0-1069-A2EA-08002B30309D}",RegVal,"REG_DWORD"  ' IE pour XP 
WS.RegWrite DestKey & "{645FF040-5081-101B-9F08-00AA002F954E}",RegVal,"REG_DWORD"  ' Corbeille		
strDeskTop=WS.SpecialFolders("DeskTop")       
 
    For I=1 to 3  
      prg=tb(I) :  Prg1=tb(I)
      Prg1=Left(prg1,instrrev(prg1,"\")) 
      prg=Right(prg,len(prg)-instrrev(prg,"\"))
      If Creer Then 
        Set oMyShortCut = WS.CreateShortcut(strDesktop & "\" & prg & ".lnk")
        With oMyShortCut
          .TargetPath = tb(I) 
          .Hotkey = "ALT+CTRL+" & Ucase(Left(prg,1))  
          .WorkingDirectory=Prg1
          .WindowStyle = 1
          .IconLocation= tb(i) & ",0"
          .Save
        End With
      Else
        set myShort=FSO.GetFile(strDesktop & "\" & prg & ".lnk")
        myShort.Delete
      End If
    Next
 
ws.run "%Windir%\System32\rundll32.exe USER32.DLL,UpdatePerUserSystemParameters 0",1,1
Set WS=Nothing
Set FSO= Nothing
Wscript.Quit

Et si tu as d'autres raccourcis vers des programmes à rajouter, il suffit de les déclarer avec tb(4), tb(5).... et changer la portée du compteur I(dans For I = 1 To ...) en conséquence et n'oublie surtout pas d'élargir le tb(4 ou 5 ou ..) dans la définition de celui-ci.

**ProgElecT** · 27/08/2010, 23h39

Pour l_autodidacte

Etant plutôt branché VB6 et que trés occasionnellement VBScript

Envoyé par l_autodidacte

Bon voici
.......
et changer la portée du compteur I(dans For I = 1 To ...) en conséquence
.......

Ma petite contribution

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For I = 1 To Ubound(tb)

**l_autodidacte** · 28/08/2010, 00h15

Ma petite contribution
For I = 1 To Ubound(tb)

Tout à fait s'il ne connait pas la limite sup du compteur.
Ce qui n'est pas le cas mais cela reste toujours valable.

**brice_94** · 29/08/2010, 13h53

bonjour,

merci beaucoup pour vos contributions,

Tout à fait s'il ne connait pas la limite sup du compteur.

tout à fait je suis vraiment nul en dev je n'ai fait que du C et C++
en cours et je n'était pas très fort.

en tout cas merci pour votre aide maintenant ça fonctionne très bien

**brice_94** · 30/08/2010, 13h44

autre question est-ce que je peux avoir la même chose sans la boite
de dialogue qui demande si on veut les raccourci ou non et que en executant
le script il les mets sur le bureau comme sur le script d'avant mais sans la boite de dialogue.
et si il y a possbiliter de renomer winword.exe dans la ligne
tb(1)="c:\Program Files\Microsoft Office\Office14\Winword.exe"
car cette ligne fonctionne mais me cree un raccourcie winword.exe
j'aimerais qui s'apple plutot word.exe

**l_autodidacte** · 30/08/2010, 21h36

Tout à fait possible avec quelques petites modifications du

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Option Explicit
Dim WS, strDesktop, oMyShortCut,FSO,myShort
Dim I,Prg,Prg1,tb(3)
Const RegVal=0 
Const DestKey="HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel\"
tb(1)="C:\Program Files\Microsoft Office\Winword.exe"
tb(2)="C:\Program Files\Microsoft Office\Excel.exe"
tb(3)="C:\Program Files\Microsoft Office\Outlook.exe"
 
set Fso=CreateObject("Scripting.FileSystemObject")
Set WS = WScript.CreateObject("WScript.Shell")
 
WS.RegWrite DestKey & "{20D04FE0-3AEA-1069-A2D8-08002B30309D}",RegVal,"REG_DWORD"  ' Poste de travail
WS.RegWrite DestKey & "{450D8FBA-AD25-11D0-98A8-0800361B1103}",RegVal,"REG_DWORD"  ' Mes documents
WS.RegWrite DestKey & "{208D2C60-3AEA-1069-A2D7-08002B30309D}",RegVal,"REG_DWORD"  ' Favoris Réseau
WS.RegWrite DestKey & "{871C5380-42A0-1069-A2EA-08002B30309D}",RegVal,"REG_DWORD"  ' IE pour XP 
WS.RegWrite DestKey & "{645FF040-5081-101B-9F08-00AA002F954E}",RegVal,"REG_DWORD"  ' Corbeille		
strDeskTop=WS.SpecialFolders("DeskTop")       
 
    For I=1 to 3  
      prg=tb(I) :  Prg1=tb(I)
      Prg1=Left(prg1,instrrev(prg1,"\")) 
      prg=Right(prg,len(prg)-instrrev(prg,"\"))
      prg=Left(prg,Len(prg)-4)
      If Ucase(prg)="WINWORD" then prg=Right(prg,4)
      Set oMyShortCut = WS.CreateShortcut(strDesktop & "\" & prg & ".lnk")
        With oMyShortCut
          .TargetPath = tb(I) 
          .Hotkey = "ALT+CTRL+" & Ucase(Left(prg,1))  
          .WorkingDirectory=Prg1
          .WindowStyle = 1
          .IconLocation= tb(i) & ",0"
          .Save
        End With
    Next
 
ws.run "%Windir%\System32\rundll32.exe USER32.DLL,UpdatePerUserSystemParameters 0",1,1
Set WS=Nothing
Set FSO= Nothing
Wscript.Quit

**brice_94** · 31/08/2010, 09h14

bonjour,

ok merci pour ta contribution

désoler de revenir mais mon tuteur veux encore des modification donc
il veut que:
tb(1)="C:\Program Files\Microsoft Office\Office14\WINWORD.exe"
tb(2)="C:\Program Files\Microsoft Office\Office14\EXCEL.exe"
tb(3)="C:\Program Files\Microsoft Office\Office14\OUTLOOK.exe"
soit crée en word 2010.exe excel 2010.exe et outlook 2010.exe comme raccourcie
autre probleme la création de mes documents ne se fait pas sur Seven 64 bits.

**l_autodidacte** · 31/08/2010, 20h52

Juste après cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Ucase(prg)="WINWORD" then prg=Right(prg,4)

ajoute

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

prg=prg+" 2010.exe"

déploiment de raccourci sur le bureau par script

VBScript

Discussions similaires

Partager

Partager