Discussion :

[guiltouf]

Bonjour la communauté,

J'avais une tite question à laquelle je n'arrive pas à trouver de réponse.
Je suis en train de reprendre une appli en VB d'un de mes stagiaires et je voudrais plutot que fermer l'application quand on clique sur la croix de fermeture, qu'elle s'iconifie dans le systray.

Toutes les routines sont déjà faites pour l'iconification, mais je n'arrive pas à trouver l'évenement qui gère la fermeture.

J'ai tout de même mis un événement dans le Form_unload de ma feuille principale, mais quenéni, elle se ferme quand même => l'événement de fermeture doit se trouver après.

Pourriez-vous me dire où je peux trouver la sale bete ?

Ciao

[Xo]

Regarde du côté du QueryUnload

Ex : le code suivant empêche l'utilisateur de fermer la fenêtre par la "petite croix" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    If UnloadMode <> vbFormCode Then
        cmdQuitter.DoClick
    End If
End Sub

[Lacenaire]

tu peux aussi faire un truc du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
   Cancel = 1
   Ma_Procedure_Systray
End Sub

Cancel=1 empêche la fermeture, tu n'as plus qu'à diriger vers ta routine systray

[Theocourant]

Salut,

L'inconvénient dans ce que vous présentez comme solutions est que QuerryUnload est un événement qui apparaît lorsque l'on quitte (vraiment) l'application car on décharge les forms de la mémoire d'où une application impossible à quitter.

Donc la solution de fixer le Cancel à 1 n'est pas intéressante...
Il faut peut-être passer par une variable globale qui obtient une valeur à l'exécution de l'appli et qui en reçoit une autre à la fermeture avec un menu quitter ...

Bon courage pour la suite

Théo

[Theocourant]

Voici le code que cela peut donner avec un menu Quitter sur la form principale.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Dim Autor_Quitter As Boolean 'Autorisation de quitter l'application
Private Sub Form_Load()
 
    Autor_Quitter = False
 
End Sub
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    If Not Autor_Quitter Then
        Cancel = 1
        ' Procédures de mises en systray
    End If
    'Ferme l'ensemble des forms ouvertes
    For Each f In Forms
        If f <> Me Then
            f.Unload
        End If
    Next
End Sub
 
Private Sub menu_Quitter_Click()
    Autor_Quitter = True
    Me.Unload
End Sub

Voili Voilou MAIS il y a certainement des améliorations à apporter à cela

@peluche

Théo

[zazaraignée]

Salut

Le paramètre UnLoadMode contient le mode de fermeture: par la petitre croix, par un menu ou bouton, etc.

En cherchant dans l'aide, tu pourras trouver quelques codes exemple et les constantes à utiliser pour que ça marche comme tu le veux.

Tu m'excuseras si je ne cherche pas pour toi, tu le retiendras mieux et je suis pressée. Y'a mon déjeuné qui brule!

[guiltouf]

J'essaye vos soluces demain dans la journée et en tout cas, je vous remercie déjà pour votre aide.

Ciao

[Arthaniel]

Tu as regardé dans la FAQ ? J'ai pris ce code à cette p^lace là, il me semble la denière fois. Il y donne un lien vers Microsoft :

http://support.microsoft.com/default...=KB;fr;q176085

Amuse-toi bien...

[guiltouf]

Tiens, bah ça me dit quelque chose ce code C'est le code qu'a utilisé mon stagiaire pour gérer l'iconification de l'appli => ses sources gèrent pas mal.

Donc moi, j'avais essayé de mettre ma msgbox dans form_unload, mais nada. Ma msgbox est bien affichée mais a priori, ce n'est pas la dernière routine qui est exécutée, a malgrès que je lui dise de ne pas exécuter le code qui unload toutes les forms dans cette routine, il les unload quand même et après.

Allé, je vous dis ça demain, car j'ai pas vb sur mon pc perso (moi c'est php ) et donc je vais titiller un peu de vb demain.

Ciao et merci.

[leroissejp]

Bonsoir,
Tu places ce code dans un Module.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
Public Type NOTIFYICONDATA
   cbSize As Long
   hwnd As Long
   uId As Long
   uFlags As Long
   uCallBackMessage As Long
   hIcon As Long
   szTip As String * 64
   End Type
   Public nid As NOTIFYICONDATA
 
   'constantes requises par l'appel API Shell_NotifyIcon :
   Public Const NIM_ADD = &H0
   Public Const NIM_MODIFY = &H1
   Public Const NIM_DELETE = &H2
   Public Const NIF_MESSAGE = &H1
   Public Const NIF_ICON = &H2
   Public Const NIF_TIP = &H4
   Public Const WM_MOUSEMOVE = &H200
   Public Const WM_LBUTTONDOWN = &H201     'Button down
   Public Const WM_LBUTTONUP = &H202       'Button up
   Public Const WM_LBUTTONDBLCLK = &H203   'Double-click
   Public Const WM_RBUTTONDOWN = &H204     'Button down
   Public Const WM_RBUTTONUP = &H205       'Button up
   Public Const WM_RBUTTONDBLCLK = &H206   'Double-click
   Public Declare Function SetForegroundWindow Lib "user32" _
   (ByVal hwnd As Long) As Long
   Public Declare Function Shell_NotifyIcon Lib "shell32" _
   Alias "Shell_NotifyIconA" _
   (ByVal dwMessage As Long, pnid As NOTIFYICONDATA) As Boolean
 
Ce code dans la Form
 
Private Sub Form_Load()
 'la forme doit être entièrement visible avant d'appeler Shell_NotifyIcon
   Me.Show
   Me.Refresh
   With nid
    .cbSize = Len(nid)
    .hwnd = Me.hwnd
    .uId = vbNull
    .uFlags = NIF_ICON Or NIF_TIP Or NIF_MESSAGE
    .uCallBackMessage = WM_MOUSEMOVE
    .hIcon = Me.Icon
    .szTip = "Your ToolTip" & vbNullChar
   End With
   Shell_NotifyIcon NIM_ADD, nid
   End Sub
 
   Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
   'cette procédure reçoit les rappels de l'icône de barre d'état système.
   Dim Result As Long
   Dim msg As Long
    'the value of X will vary depending upon the scalemode setting
    If Me.ScaleMode = vbPixels Then
     msg = X
    Else
     msg = X / Screen.TwipsPerPixelX
    End If
    Select Case msg
     Case WM_LBUTTONUP                  '514 restore form window
      Me.WindowState = vbNormal
      Result = SetForegroundWindow(Me.hwnd)
      Me.Show
      Case WM_LBUTTONDBLCLK     '515 restore form window
      Me.WindowState = vbNormal
      Result = SetForegroundWindow(Me.hwnd)
      Me.Show
     Case WM_RBUTTONUP                  '517 display popup menu
      Result = SetForegroundWindow(Me.hwnd)
    End Select
   End Sub
 
 Private Sub Form_Resize()
    'Nécessaire pour assurer que la fenêtre réduite soit masquée
    If Me.WindowState = vbMinimized Then Me.Hide
   End Sub
 
   Private Sub Form_Unload(Cancel As Integer)
    'cela supprime l'icône de la barre d'état système
    Shell_NotifyIcon NIM_DELETE, nid
   End Sub

Quand tu clique sur réduire , la Form se place en icone dans la systrait prè de l'horloge (c'est licone de la feuille qui apparait) , il suffit de cliquer dessus pour restaurer

jpleroisse

[Chromatic]

serait - il possible d utiliser cela avec access?

j ai essayer d inserer ce code dans mon projet access mais il m indique une erreur de compilation

" Me.Show inconnu "

Pareil pour "Me.icon"