Discussion :

[Cryos]

Bonjour à tous !

J'essaye de récupérer dans une variable le chemin courant d'un script, c'est à dire le répertoire où est executé le script. Enfin si je pouvais récupérer l'objet "Folder" correspondant à ce dossier ça m'irait aussi...

J'ai fais le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim courant_dir
courant_dir = WScript.ScriptFullName 'Me donne le lien complet "c:\script.vbs"
Replace courant_dir, WScript.ScriptName, "" 'Devrait me donner c:\ mais me redonne "c:\script.vbs" :aie:

Si quelqu'un pouvait m'aider ça serait pas de refus !
Merci d'avance

[l_autodidacte]

Teste ce

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim courant_dir
courant_dir = WScript.ScriptFullName 
courant_dir=left(courant_dir,InStrRev(courant_dir,"\"))
msgbox courant_dir

dans un fichier à part.

[Cryos]

Merci l_autodidacte ça fonctionne ! (en prime j'ai compris comment, c'est le principal ) Problème résolu.

En revanche saurais-tu m'expliquer pourquoi le replace ne convenait pas / ne fonctionnait pas dans mon cas ?

[pitchalov]

Bonjour, ton replace aurait mieux fonctionné comme cela :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

courant_dir = Replace (courant_dir, WScript.ScriptName, "")

[Cryos]

Bien joué pitchalov ça fonctionne maintenant.
La documentation VBS de Replace n'indique pas que replace retourne une valeur. Je me fais avoir à chaque fois.
Merci !

[Feneck91]

Je peux aussi te proposer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
'--------------------------------------------------------------------------
' Récupérer le chamin sans le nom de fichier.
'
' Tient compte de \ ou /, les deux sont détectés.
'
' Paramètres :
'-------------
'   strPathName : Chemin + Nom de fichier
'
' Retour :
'---------
'   Le chemin du répertoire du chemin passé en paramètre.
'
'--------------------------------------------------------------------------
Function GetPath(strPathName)
    Dim strCopyPathName
    strCopyPathName = Replace(strPathName,"/","\",1,-1,vbTextCompare)
    GetPath = Left(strPathName,InStrRev(strCopyPathName,"\",-1,vbTextCompare))
End Function
 
'--------------------------------------------------------------------------
' Récupérer le chamin d'où est lancé le script
'
' Paramètres :
'-------------
'   aucun
'
' Retour :
'---------
'   Le chemin du répertoire d'où est lancé le script.
'
'--------------------------------------------------------------------------
Function GetCurrentPath()
    GetCurrentPath = GetPath(WScript.ScriptFullName)
End Function