Discussion :

[adam03]

Bonjour a tous

Voila, j'ai problème avec mon programme, j'aimerai afficher dans une textbox une ligne précise d'un fichier (ligne 12).

J'ai chercher et essayer des sources mais je n'en ai pas trouver pour lire une ligne précise.

Merci de votre aide
Bonne journée
adam

[ProgElecT]

Salut, bienvenue sur DVP

Deux façon de faire
-1, ouvrir le fichier et faire une boucle avec ReadLine, au 12ème mettre le résultat du ReadLine dans le textbox et quitter la boucle.

-2, ouvrir le fichier en y mettant la totalité du fichier dans une variable, fermer le fichier, faire un Split de la variable avec pour argument Délimité (2ème paramètre) vbNewLine, mettre le résultat de VaribleSplit(11) dans le textbox.

Tu peux faire une recherche dans ce forum avec les mots en gras, si tu as des problèmes de mise en pratique, signales nous les en spécifiant ou sa coince.

[ProgElecT]

J'ai vue que tu étais passé voir la proposition, comme tu n'as pas utilisé le bouton .
Un exemple des 2 méthodes
Sur un Form, 2 CommandButtons et un TextBox et ce

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
Option Explicit
Dim Msg$
Dim NumFich As Integer
Dim NbrLgn As Integer
Dim CheminNomFichier As String
 
Private Sub Form_Load()
'************* Adapter le chemin et nom du fichier *************************
CheminNomFichier = "C:\PersoFrancis\GridAvecChecked\LesDonnées.txt"
End Sub
 
Private Sub Command1_Click()
ChargeBDtxt1
End Sub
Public Sub ChargeBDtxt1()
Msg$ = ""
NumFich = FreeFile
Open CheminNomFichier For Input As #NumFich
Msg$ = Input(FileLen(CheminNomFichier), NumFich)
Close #NumFich
If Msg$ = "" Then
 MsgBox "le fichier est vide", vbCritical
 Exit Sub
End If
 
'variables intermediaires à 1 indice, pour contenir chaque ligne
Dim DecoupeContenuLg() As String
'création du tableau "DecoupeContenuLg",chaque numero d'index correspondrat à une N ligne-1
DecoupeContenuLg = Split(Msg$, vbCrLf)
'recuperation du Nbr de lignes
NbrLgn = UBound(DecoupeContenuLg) - 1 '(-1 car le fichier ce termine par une ligne vierge)
 
'maintenant que le Nbr de lignes est connue
'verifier que la ligne 12 existe
If NbrLgn >= 11 Then '11 car la premiére ligne est d'index 0
 Text1.Text = DecoupeContenuLg(11)
 Else
 Text1.Text = "il n'y a pas 12 lignes dans le fichier"
End If
End Sub
 
Private Sub Command2_Click()
ChargeBDtxt2
End Sub
Public Sub ChargeBDtxt2()
Msg$ = ""
NumFich = FreeFile
Open CheminNomFichier For Input As #NumFich
NbrLgn = 0
'Do While NbrLgn < 12 'si le fichier venait à contenir moins de 12 lignes, une erreur se produirait
Do While Not EOF(NumFich) 'il est preferable de choisir cette condition
 NbrLgn = NbrLgn + 1
 Line Input #NumFich, Msg$
 'sortire de la boucle si la ligne N° 12 est atteinte
 If NbrLgn = 12 Then Exit Do
Loop
Close #NumFich
If Msg$ = "" Then
 MsgBox "le fichier est vide", vbCritical
 Exit Sub
End If
If NbrLgn = 12 Then 'verifier que la ligne 12 existe
 Text1.Text = Msg$
 Else
 Text1.Text = "il n'y a pas 12 lignes dans le fichier"
End If
End Sub