Discussion :

[MITCH31]

salut,

suite à mon message précédent, voici mon code (qui fonctionne !! ) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Dim bnd As BindingCollection
Set cn = New ADODB.Connection
Set rs = New ADODB.Recordset
Set bnd = New BindingCollection
 
Dim MonSQL As String
 
MonSQL = "SELECT * FROM donnees where donnees.id=13328"
cn.Provider = "MSDataShape"
cn.Open ChaineADO
rs.CursorLocation = adUseClient
rs.Open MonSQL, cn, adOpenDynamic, adLockOptimistic, adCmdText
rs.MoveFirst
If rs.EOF <> True Or rs.BOF <> True Then
    Set bnd.DataSource = rs
    With bnd
        .Add MyText(0), "Text", "Nom", , "Nom"
        .Add MyText(1), "Text", "Prenom", , "Prenom"
        .Add MyText(2), "Text", "Adresse", , "Adresse"
        ...
    End With
End If

mon enregistrement s'affiche parfaitement mais lorsque je modifie la valeur d'un champ sur mon textbox, la maj de ma datasource ne s'effectue pas.
je dois donc passer à côté d'une propriété de type allowupdate sur mon textbox ? non ?

[Mehdi_ab]

Bonjour MITCH31

c'est quoi d'abords le BindingCollection ?

le BindingCollection c'est relier une propriété d'un objet avec une valeur d'un champ d'une Table

dans ton code tu as relier la propriété Text des Objets MyText(0).,MyText(1).... avec les valeurs des champs Nom,Prenom...

Autre exemple :

si par exemple t'as une table qui contient un champ Couleur qui contient des couleurs en hexa , tu veux lier la propiété BackColor d'un Label par exemple pour qu'elle prenne la valeur De Ce Champ

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Bnd.Add label1, "Backcolor","Couleur"

Alors , on relie Juste les valeurs , et pas le Champs Lui Même, c'est Pourquoi ,tu modifie ta zone de texte,les changement ne sont pas affecté dans la base de donnée

Merci

[MITCH31]

salut,

aucun moyen donc d'afficher ma source dans un textbox et de modifier celle ci ?

[AdHoc]

Personnellement je mettrai un bouton "enregistrer" qui permet de faire une requete d'update de l'enregistrement.
Mais faut ecrire du code

[jacma]

Bonjour

On peut parfaitement modifier les valeurs d'un enregistrement, ou en créer un nouveau, en utilisant des champs liés aux données par un collection Binding. Je l'ai d'ailleurs précisé à MITCH. Sinon, à quoi serviraient ces objets :

Pour s'en convaincre, il n'y a qu'à voir le praticiel "Acces aux données ADO" accessible par l'adresse en signature. L'opération y est décrite et UTILISEE.

[MITCH31]

re-salut,

1 - j'ai conservé mon code ci-dessus !
2 - j'ai téléchargé le projet de JACMA (les modifications sont bien prises en compte = modification à partir du textbox)

mais là, je ne sais comment avancer sur ce problème ??

[jacma]

j'ai téléchargé le projet de JACMA (les modifications sont bien prises en compte = modification à partir du textbox)

Ouf, heureusement

mais là, je ne sais comment avancer sur ce problème ??

Là, moi non plus. Je ne vois pas d'anomalie dans ton code...

Si j'ai bien compris, tes TextBox affichent correctement les données issues de ton recordset. Les binding sont donc opérants. Bien que tu ne le précises pas, je pense que tu as des boutons qui te permettent de naviguer dans le recordset.

Que fais-tu (exactement et en détail) après avoir inséré une modification dans une des TextBox? (validation, passage à l'enregistrement suivant, passage à un autre champ, précédent..., fermeture de la feuille, etc.).

[MITCH31]

J'affiche l'ensemble de mes données ds un MSHFlexGrid (pourquoi ? = pour une meilleure ergonomie et une meilleure visibilité (ex= l'ensemble des contacts attachés au user connecté IDuser)

suite à l'évènement : clic sur grille (je récupère l'IDContact) je veux afficher mon contact selectionné dans mon fameux gpe de contrôle TextBox d'ou mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Dim bnd As BindingCollection
Set cn = New ADODB.Connection
Set rs = New ADODB.Recordset
Set bnd = New BindingCollection
 
Dim MonSQL As String
 
MonSQL = "SELECT * FROM CONTACT where CONTACT.id=13328"
cn.Provider = "MSDataShape"
cn.Open ChaineADO
'rs.CursorLocation = adUseClient
rs.Open MonSQL, cn, adOpenDynamic, adLockOptimistic, adCmdText
rs.MoveFirst
 
If rs.EOF <> True Or rs.BOF <> True Then
    Set bnd.DataSource = rs
    With bnd
        .Add MyText(0), "Text", "Nom"
        .Add MyText(1), "Text", "Prenom"
        .Add MyText(2), "Text", "adresse"
    End With
end if

[jacma]

Quelques points:
1°/ pourquoi MSDataShape? A l'évidence tu ne travaille pas sur un recordset hiérarchique et donc une connexion classique avec le simple provider Provider=Microsoft.Jet.OLEDB.4.0 y suffirait.
De toutes façons, je ne pense pas que ta chaîne SQL convienne avec le provider MSDataShape.
2°/ même remarque pour l'utilisation d'une mshFlexGid. Une simple DataGrid serait suffisants, voire une simple liste. Tu as un exemple dans Initiation accès aux données, où un clic sur l'item d'une liste t'affiche les information de l'nregistrement correspndant dans des TextBox.
3°/ La chaîne SQL???...

Enfin bref, un certain nombre de choses. Je crois préférable de repartir sur de bonnes bases, c'est à dire sur le code qui suit.

Il te faut créer un projet, une feuille avec un groupe de 3 txtbox, deux boutons de commande pour la navigation et une datagrid. Tu colles le code dans ta feuille, et cela fonctionne (adapte au besoin la chaîne de connexion en fonction de la position de ta base de données).

Tu peux parcourir le recordset avec les deux boutons de navigation (attention, pas de sécurité pour EOF et BOF). Les textbox et la grille sont synchro (c'est normal, c'est le même recordset pour la grille et la collection binding). Si tu cliques sur une ligne de la grille, les textbox affichent le contenu de l'enregistrement sélectionné. Si du modifies une textbox, passes à l'enregistrement suivant (ou précédent) et reviens sur l'enregistrement modifié, ou encore ferme la feuille et relance, tu verras que la modif a été prise en compte.
Je n'ai pas traité l'ajout d'un nouvel enregistrement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Option Explicit
Dim cn As ADODB.Connection
Private WithEvents rsCorrespondants As ADODB.Recordset
Dim bndCorrespondant As BindingCollection
 
Private Sub Form_Load()
 
  Dim SQL As String
  Dim strConnex As String
  Dim i As Integer
  Set cn = New ADODB.Connection
  Set rsCorrespondants = New ADODB.Recordset
  Set bndCorrespondant = New BindingCollection
 
  'Chaîne de connexion
  strConnex = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\Developpez.com\Essais réponses\Agenda\Agenda.mdb;Persist Security Info=False"
  'Requête SQL
  SQL = "SELECT * FROM Correspondants"
  'Connexion
  cn.Open strConnex
  'Création du recordset
  rsCorrespondants.CursorLocation = adUseClient
  rsCorrespondants.Open SQL, cn, adOpenDynamic, adLockOptimistic, adCmdText
 
  Set DataGrid1.DataSource = rsCorrespondants
 
  'Définit le jeu d'enregistrements comme source de données (DataSource) de la collection Bindings.
  Set bndCorrespondant.DataSource = rsCorrespondants
  With bndCorrespondant
    .Add txtCorresp(0), "Text", "Nom", , "Nom"
    .Add txtCorresp(1), "Text", "Prenon", , "Prenom"
    .Add txtCorresp(2), "Text", "Adresse", , "Adresse"
  End With
 
End Sub
 
Private Sub cmdNav_Click(Index As Integer)
 
  Select Case Index
    Case 0
      rsCorrespondants.MovePrevious
    Case 1
      rsCorrespondants.MoveNext
  End Select
 
End Sub

[jacma]

Bonjour
Vas voir à l'adresse indiquée ci-après. Cela devrait t'intéresser aussi.
http://www.developpez.net/forums/vie...b05785ade2a278

[MITCH31]

Salut,

j'ai oublié de clôturer le problème sorry ! en référence au tutoriel de JACMA et de l'aide ci dessus mon problème est résolu !
je n'avais pas mis en place un bouton qui se plaçait sur l'enregistrement suivant et donc qui validait mes modicications.