Discussion :

[marti]

Un exemple concret :
voici la table SAS T que je lis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
ID1   ID2  dernoi  V1   V2   V3   V4  V5
1      2     1  
1      3     2
1      4     3 
2      1     2
2      2     3
2      3     0

Je dois ensuite mettre à jour pour chaque enregistrement de cette table SAS T comme suivant :
Si dernoi = 0, je ne fais rien
Si dernoi = 1, je mets à jour V1
Si dernoir = 2, je mets à jour V1, V2
Si dernoi = 3, je mets à jour V1,V2,V3
Si dernoi = 4, je mets à jour V1,V2,V3,V4
etc....
Pour mettre à jour V1, V2, ..., je récupère à l'aide de requêtes SQL les données à partir d'une table Oracle O :

exemple table O :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
ID1    ID2   NOI   V
1       2     1    A
1       3     1    A
1       3     2    B
1       4     1    C
1       4     2    D
1       4     3    E
2       1     1    A
2       1     2    B
2       2     1    C
2       2     2    F
2       2     3    G

On doit donc obtenir la table T mise à jour de la manière suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
ID1   ID2  dernoi  V1   V2   V3   V4  V5
1      2     1     A 
1      3     2     A    B
1      4     3     C    D    E 
2      1     2     A    B
2      2     3     C    F    G 
2      3     0

Merci pour votre aide

[olivier.decourt]

Je ne comprends pas à quoi te sert la variable DERNOI, puisqu'on arrive à la solution sans s'en servir...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
DATA work.t ;
	INFILE CARDS MISSOVER ;
	INPUT ID1   ID2  dernoi  (V1-V5) ($) ;
CARDS ;
1      2     1  
1      3     2
1      4     3 
2      1     2
2      2     3
2      3     0
;
RUN ;
DATA work.o ;
	INPUT ID1    ID2   NOI   V $ ;
CARDS ;
1       2     1    A
1       3     1    A
1       3     2    B
1       4     1    C
1       4     2    D
1       4     3    E
2       1     1    A
2       1     2    B
2       2     1    C
2       2     2    F
2       2     3    G
;
RUN ;
DATA work.o ;
	SET work.o ;
	nomVar = COMPRESS("V"!!noi) ;
RUN ;
PROC TRANSPOSE DATA=work.o OUT=work.oBis (DROP=_name_) ;
	VAR v ;
	ID nomVar ;
	BY id1 id2 ;
RUN ;
DATA work.tFinal ;
	MERGE work.t work.oBis ;
	BY id1 id2 ;
RUN ;

Olivier

[green_fr]

Je comprends bien que "dernoi" sert à déterminer la dernière colonne qu'il faut mettre à jour ? C'est à dire même si on avait une ligne "1 2 2 Z" dans la deuxième table, il fallait pas en tenir compte dans la mis à jour de la première ligne, vu que dernoi y est égale à 1. C'est bien ça ?

[steelspirit]

Merci Marti pour ce cas d'école

Et pourquoi ne pas utiliser une seule étape data ?

Souvent méconnu, les tableaux sont pourtant d'un grand secrours !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
data T(drop=V i);
	set o;
	by ID1 ID2 ;
	ARRAY tab{5} $ V1-V5;
	retain tab;
	if first.ID2 then do;
		do i=1 to dim(tab);
			tab(i)='';
		end;
	end;
	tab(NOI)=V;
	if last.ID2;
run;