Discussion :

[arnofly]

Bonjour,

La question n'est peut-être pas très explicite. J'aimerais que lorsque l'utilisateur positionne sa souris au dessus d'un Panel, cela affiche le Label qui lui correspond et que lorsque la souris quitte ce Panel, le Label disparaisse.

Je n'ai pas encore déterminé le nombre de Panel, mais il y en aura plusieurs.

• Le Panel est ds une TabPage d'un TabControl
• Le Label correspondant au Panel, est ds un GroupBox qui est positionné directement sur la Form.

Pour vous donner une idée, en fait chaque Panel regroupe un texte avec 2 CheckBox (oui ou non) et j'aimerais afficher un "message" (Label) different pour chacun d'entre eux, aidant ainsi l'utilisateur à faire son choix entre les 2 CheckBox. Les "messages apparaitront toujours au même endroit ds la Form (GroupBox nommé "Information") et chaque Pannel aura sont propre message d'information.

Merci à vous.

[olsimare]

Bonjour.

En fait, tu veux faire comme pour un tooltip mais au lieu d'un popup avec le texte d'aide, mettre se texte dans un label.

Personnellement, je ferai un class label perso qui gère la surveillance des entrées/sorties de la souris sur les controls à surveiller (sur le même principe que le tooltip).

Du style :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Public Class HelpTextLabel
    Inherits Label
    Private slHelpTextList As New SortedList(Of String, String)
    Public Sub SetControlHelp(ByVal c As Control, ByVal HelpText As String)
        If slHelpTextList.ContainsKey(c.Name) Then Exit Sub
        slHelpTextList.Add(c.Name, HelpText)
        AddHandler c.MouseEnter, AddressOf SetHelpText
        AddHandler c.MouseLeave, AddressOf EraseHelpText
    End Sub
    Private Sub EraseHelpText(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.Text = ""
    End Sub
    Private Sub SetHelpText(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.Text = slHelpTextList(CType(sender, Control).Name)
    End Sub
End Class

Ensuite, tu mets ce label dans ta form et pour chaque control à documenter tu fais un setControlHelp(lecontrol, letexte).

Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
Public Class Form6
 
    Public Sub New()
        ' Cet appel est requis par le Concepteur Windows Form.
        InitializeComponent()
 
        Me.HelpTextLabel1.SetControlHelp(Me.Button1, "Je suis le bouton 1")
        Me.HelpTextLabel1.SetControlHelp(Me.Button2, "Je suis le bouton 2")
        Me.HelpTextLabel1.SetControlHelp(Me.Button4, "Je suis le bouton 4")
        Me.HelpTextLabel1.SetControlHelp(Me.Button5, "Je suis le bouton 5")
    End Sub
 
End Class

Cdt.

[arnofly]

Slt olsimare,

En fait il me manquait le vocabulaire, mais tu as tout compris, c exactement ce que je cherche à faire. Maintenant, je vais essayer d'appliquer ton conseil.

Merci à toi.

[olsimare]

Bonjour.

Si ça peut t'aider voici un exemple d'utilisation :
Pièce jointe 21827

Cdt.