Discussion :

[Nikkobass]

Bonjour,

je développe actuellement un programme utilisant une listview dans laquelle chaque item peut etre cliqué, doublecliqué ou déplacé par drag'n drop.

Or, je n'arrive pas à concilier les 3 evenements: des que j'implémente le drag n' drop (initialisé par un event mousedown), le click et le double click ne sont plus détectés. Ils reviennent des que j'enleve le "dodragdrop" de ma sub mousedown.

Est ce que kkun a déja rencontré ce problème?

[salrouge]

jai pas rencontré ce probleme avant mais, je sais pas si ca va marcher si tu appelle l'evenement click manuellement dans MouseDown ! je lai pas essayer mais je pense que ca doit marcher
a+

[JPelli]

Bonjour,
Essaie en définissant une zone dans laquelle le dragDrop ne peut démarrer.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
''' <summary>
  '''  Retourne un rectangle dans lequel le dragdrop ne démarre pas
  ''' </summary>
  ''' <param name="e"></param>
  ''' <returns></returns>
  ''' <remarks></remarks>
  Public Function F_RectDragDrop(ByVal e As System.Windows.Forms.MouseEventArgs) As Rectangle
    Dim Rect As New Rectangle
    Dim DragSize As Size = SystemInformation.DragSize
    Rect.X = CInt(e.X - (DragSize.Width / 2))
    Rect.Y = CInt(e.Y - (DragSize.Height / 2))
    Rect.Height = DragSize.Height
    Rect.Width = DragSize.Width
    Return Rect
  End Function

Dans l'événement MouseDown

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub LB_MouseDown(ByVal sender As System.Object, _
                                   ByVal e As System.Windows.Forms.MouseEventArgs) _
            Handles LB.MouseDown
           'gestion du DragDrop
        select case e.button
          Case Windows.Forms.MouseButtons.Left
            DragBox = F_RectDragDrop(e)         'Créer le rectangle
       end select
 end sub

Dans l'événement MouseMove

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
  ''' <summary>
  '''  Démarrer le dragDrop si le curseur sort de la zone prédéfinie dans l'événement Mouse_down
  ''' </summary>
  ''' <param name="sender"></param>
  ''' <param name="e"></param>
  ''' <remarks></remarks>
  Private Sub LB_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) _
            Handles LB.MouseMove
    If e.Button = Windows.Forms.MouseButtons.Left Then
       If Not DragBox.Contains(e.X, e.Y) Then
               LB.DoDragDrop(BSMed.Current, DragDropEffects.All)
            End If
    end if
end sub

Je crois que j'avais trouvé l'explication dans l'aide mais je ne sais plus dans quelle rubrique.
Bon boulot Jean

[Nikkobass]

merci de vos réponses rapides, j'ai utilisé ta méthode Jean: ca marche nickel!!
Effectivement, beau boulot