Discussion :

[sys.midou]

Bonjour
j'aimerai savoir quelle version d'office365 installé sur le poste de travail x86 ou x64 ?voila le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
    Private Function GetOfficeVersion() As String
        Dim officeVersion As String = "Inconnue"
        Try
            Dim regKey As RegistryKey = Registry.LocalMachine.OpenSubKey("SOFTWARE\Microsoft\Office\ClickToRun\Configuration")
            If regKey IsNot Nothing Then
                Dim platformValue As Object = regKey.GetValue("Platform")
                If platformValue IsNot Nothing Then
                    Dim platform As String = platformValue.ToString()
                    If platform.Equals("x64", StringComparison.OrdinalIgnoreCase) Then
                        officeVersion = "Office 365 64 bits"
                    ElseIf platform.Equals("x86", StringComparison.OrdinalIgnoreCase) Then
                        officeVersion = "Office 365 32 bits"
                    End If
                End If
                regKey.Close()
            End If
        Catch ex As Exception
            ' Gérer les erreurs éventuelles
        End Try
        Return officeVersion
    End Function

A l'exécution j'ai le résultat Inconnue !!
Merci pour votre aide

[popo]

As-tu exécuté ce code en pas à pas ?

Comme ça je dirais que ta clé n'existe pas.
Si ton application est conçue pour du 32 bit, ce code ira lire par défaut ce qui se trouve sous HKLM\Software\Wow6432Node sous un Windows 64 bit.

Soit tu compiles pour une version 64 bits.
Soit tu précises ce que tu lis.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Using hklm = RegistryKey.OpenBaseKey(RegistryHive.LocalMachine, RegistryView.Registry64)
 
    Using key = hklm.OpenSubKey("SOFTWARE\Microsoft\Office\ClickToRun\Configuration")
        ...
    End Using
End Using

[sys.midou]

Merci pour la réponse rapide

la clé existe belle et bien!

quand je lance ce VBS par exemple j'ai bien le résultat office en X64
code VBS

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim WshShell, blnOffice64, strOutlookPath
Set WshShell = WScript.CreateObject("WScript.Shell")
blnOffice64=False
strOutlookPath=WshShell.RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\outlook.exe\Path")
If WshShell.ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%") = "AMD64" And _
    not instr(strOutlookPath, "x86") > 0 then 
  blnOffice64=True
  wscript.echo "Office 64"
End If

no je n'ai pas encore tester le pas à pas

[popo]

Je n'ai pas dit que la clé n'existait pas.
J'ai dit que si tu compiles en 32 bits, alors C# ne va pas lire la clé que tu crois.

Dire que ça fonctionne via le shell et un code VBS c'est comme demander une flûte à un boulanger et à un musicien. Tu obtiendra deux résultats différents.

Est-ce qu'au moins tu as testé avec le code que j'ai fourni ?

Et le debogage en pas à pas, c'est la base.
Si tu ne maîtrise pas les bases, la suite va être très compliquée.

[binarygirl]

C'est une mauvaise idée de masquer les exceptions. Il est possible que le code plante mais vous ne le voyez pas.

[Thumb down]

Bonjour,
Juste pour m'a culture générale ; pourquoi cherches tu la version ?