Discussion :

[Katalz]

Bonsoir,
Dans le cadre d'une application de reconnaissance facial, il faut que lors d'un clic de l'utilisateur sur une image, une croix se place à l'endroit où justement celui-ci a cliqué. J'ai donc plusieurs possibilité, je peux afficher un label avec un "X" suffisamment grand et de placer le label là où l'utilisateur à cliquer, mais il faut que le label soit transparent et ne laisse passer que le caractères "X". Je peux également superposé une pictureBox contenant une image de croix et là placer à l'endroit où l'utilisateur à cliquer. Mon problème dans ces deux situations est que je n'arrive pas malgré les solutions proposés pas d'autres internautes, à rendre la pictureBox ou le label transparent, voici un exemple de code que j'ai mis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
        lblX.parent = pbImageCharger
        lblX.BackColor = Color.Transparent

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
        pbImageCharger.Control.add(lblX)
        lblX.BackColor = Color.Transparent

J'ai fais exactement la même chose lors du cas avec un pictureBox superposé à une autre pictureBox mais le résultat est le même, mon label/pictureBox disparaît et n'ait pas affiché.

Merci d'avance pour les réponses.

[MABROUKI]

bonjour
Pour obtenir un Control transparent il faut le personnaliser.
Voici un Control transparent & tète carré comme l'eau de Vittel,une vraie usine à gaz.

Projet lib vb.net du custom control:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
 
Public Class CroixControl
 
    Inherits Control
 
    Private borderColor As Color = Color.Black
    Public enab As Boolean = False
    Private alpha As Integer
    Private mdrag As Boolean = False
    Public Property Drag() As Boolean
        Get
            Return mdrag
        End Get
        Set(ByVal value As Boolean)
            mdrag = value
            If (Me.Parent IsNot Nothing) Then
                Me.Parent.Invalidate(Me.Bounds, True)
            End If
        End Set
    End Property
    Private mfillColor As Color = Color.White
    Public Property FillColor() As Color
        Get
            Return mfillColor
        End Get
        Set(ByVal value As Color)
            mfillColor = value
            If (Me.Parent IsNot Nothing) Then
                Me.Parent.Invalidate(Me.Bounds, True)
            End If
        End Set
    End Property
    Private mopacity As Integer = 100
    Public Property Opacity() As Integer
        Get
            If (mopacity > 100) Then
                mopacity = 100
            ElseIf mopacity < 1 Then
                mopacity = 1
            End If
            Return mopacity
        End Get
        Set(ByVal value As Integer)
            mopacity = value
            Me.Invalidate(Me.Bounds, True)
        End Set
    End Property
    Private mborderstyle As BorderStyle
    Public Property BorderStyle() As BorderStyle
        Get
            Return mborderstyle
        End Get
        Set(ByVal value As BorderStyle)
            mborderstyle = value
            If (Me.Parent IsNot Nothing) Then
                Me.Parent.Invalidate(Me.Bounds, True)
            End If
        End Set
    End Property
    Public Sub New()
 
        ' Cet appel est requis par le concepteur.
        InitializeComponent()
 
        SetStyle(ControlStyles.SupportsTransparentBackColor, True)
        SetStyle(ControlStyles.Opaque, True)
        Me.BackColor = Color.Transparent
        Me.BorderStyle = BorderStyle.FixedSingle
        Me.Text = "X"
    End Sub
    Protected Overrides ReadOnly Property CreateParams As System.Windows.Forms.CreateParams
        Get
            Dim cp As CreateParams = MyBase.CreateParams
            cp.ExStyle = cp.ExStyle Or &H20
            Return cp
        End Get
    End Property
    Protected Overrides Sub OnPaint(ByVal e As System.Windows.Forms.PaintEventArgs)
 
 
        Dim gr As Graphics = e.Graphics
        Dim bounds As Rectangle = New Rectangle(0, 0, Me.Width - 1, Me.Height - 1)
        If Me.BorderStyle = BorderStyle.FixedSingle Then
            Using p As New Pen(borderColor)
                gr.DrawRectangle(p, New Rectangle(0, 0, Width - 1, Height - 1))
            End Using
        End If
 
        Dim frmColor As Color = Me.Parent.BackColor
        Dim brushColor As Brush
        Dim bckColor As Brush
 
        alpha = CInt((Opacity * 255) / 100)
 
        If Drag Then
            Dim dragFillColor As Color
            Dim dragBckColor As Color
 
            If (BackColor <> color.Transparent) Then
                Dim Rb As Integer = BackColor.R * alpha / 255 + frmColor.R * (255 - alpha) / 255
                Dim Gb As Integer = BackColor.G * alpha / 255 + frmColor.G * (255 - alpha) / 255
                Dim Bb As Integer = BackColor.B * alpha / 255 + frmColor.B * (255 - alpha) / 255
                dragBckColor = color.FromArgb(Rb, Gb, Bb)
            Else
                dragBckColor = frmColor
            End If
            If (FillColor <> color.Transparent) Then
                Dim Rf As Integer = FillColor.R * alpha / 255 + frmColor.R * (255 - alpha) / 255
                Dim Gf As Integer = FillColor.G * alpha / 255 + frmColor.G * (255 - alpha) / 255
                Dim Bf As Integer = FillColor.B * alpha / 255 + frmColor.B * (255 - alpha) / 255
                dragFillColor = color.FromArgb(Rf, Gf, Bf)
            Else
                dragFillColor = dragBckColor
            End If
            alpha = 255
            brushColor = New SolidBrush(Color.FromArgb(alpha, dragFillColor))
            bckColor = New SolidBrush(Color.FromArgb(alpha, dragBckColor))
        Else
            Dim color As Color = FillColor
            brushColor = New SolidBrush(color.FromArgb(alpha, color))
            bckColor = New SolidBrush(color.FromArgb(alpha, Me.BackColor))
 
        End If
        Dim pen As New Pen(Me.ForeColor)
 
        If (Me.BackColor <> Color.Transparent Or Drag) Then 'remplit le fond avec backolor opacity du control
            gr.FillRectangle(bckColor, bounds)
 
        ElseIf (FillColor <> Color.Transparent Or Drag) Then 'remplit le fond avec FillColor opacity du control
            gr.FillRectangle(brushColor, bounds)
        Else
            gr.FillRectangle(New SolidBrush(Color.FromArgb(1, Color.White)), bounds)
        End If
        Dim p0 As New Point(0, 0) : Dim p1 As New Point(Width, Height)
        Dim p2 As New Point(0, Height) : Dim p3 As New Point(Width, 0)
 
        gr.DrawLine(New Pen(Me.ForeColor), p0, p1)
        gr.DrawLine(New Pen(Me.ForeColor), p2, p3)
        pen.Dispose()
        brushColor.Dispose()
        bckColor.Dispose()
        gr.Dispose()
 
        MyBase.OnPaint(e)
    End Sub
    Protected Overrides Sub OnBackColorChanged(e As System.EventArgs)
        If Me.Parent IsNot Nothing Then Parent.Invalidate(Me.Bounds, True)
        MyBase.OnBackColorChanged(e)
    End Sub
    Protected Overrides Sub OnParentBackColorChanged(e As System.EventArgs)
        Me.Invalidate()
        MyBase.OnParentBackColorChanged(e)
    End Sub
    Protected Overrides Sub OnSizeChanged(e As System.EventArgs)
        MyBase.OnSizeChanged(e)
        Me.Size = New Size(Me.Width, Me.Width)
        Me.Invalidate()
    End Sub
 
 
End Class

projet test du form user avec picturebox:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Imports MyControlLib
 
Public Class Form1
    Private croix As CroixControl
    Private Sub PictureBox1_MouseClick(sender As System.Object, e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseClick
        croix = GetConfiguredCroix(e.Location)
        PictureBox1.Controls.Add(croix)
    End Sub
    Private Function GetConfiguredCroix(pt As Point) As CroixControl
        Dim crx As New CroixControl
        crx.FillColor = Color.White
        crx.Opacity = 50
        crx.Width = 50
        crx.Location = New Point(pt.X - crx.Width / 2, pt.Y - crx.Height / 2)
        Return crx
    End Function
End Class

bon code...

[excalybur]

Bonjour Mabrouki,

Très intéressant, mais j'obtiens une erreur : BC30451 'InitializeComponent' n'est pas déclaré. Il peut être inaccessible en raison de son niveau de protection.

Peux-tu nous éclairer sur ce sub qui semble manquer et dont il est fait appel dans Public Sub New()?

En te remerciant

[MABROUKI]

Bonjour Mabrouki,

Très intéressant, mais j'obtiens une erreur : BC30451 'InitializeComponent' n'est pas déclaré. Il peut être inaccessible en raison de son niveau de protection.

Peux-tu nous éclairer sur ce sub qui semble manquer et dont il est fait appel dans Public Sub New()?

En te remerciant

Et comment as-tu creer le custom control?
Tu as pour de sur créé un class .vb et tu as copier-coller le code donné du Control personnalisé communiqué .
La méthode de base standard est de créer un Control personnalisé en faisant :

projet => ajouter un nouvel élément -> Control personnalisé
tu lui donnes le nom qui te plaira( excalybur.vb)

Ensuite tu copie-colle le code donne entre:
"Public Class CroixControl et "End class" dans ton Control perso entre "Public Class excalybur et "End class" .
Pourquoi?

Eh ben parce que le designer VS génère en coulisse un code ou se trouve le maudit
sub InitializeComponent()
C 'est une erreur courant de débutant .
Pour t'en convaincre ,après avoir crée ton Control personnalisé et avant de copier-coller le code donné tu fais:
1/au dessus de l’explorateur de solution,la ou il y a 6 icônes ,
=> tu cliques sur le 2eme icone à partir de la gauche.
=> Ensuite dans ton projet tu cliques sur l'icone de "excalybur"
Il apparait en dessous un fichier Control excalybur.Designer.vb.
Tu l'ouvre et tu découvriras le sésame.
Attention il ne faut jamais apporter de modif à ce type de fichier ,mais le contempler seulement comme le Saint des Saints ,sous peine de bousiller ton projet.
bon code.

[excalybur]

Bonjour Mabrouki,

Merci pour ta réponse très précise.

Effectivement j'ai bien suivi le parcours que tu indique, ça me rassure car je suis un modeste autodidacte depuis longtemps.... La lecture de designer.vb est très instructive, merci pour le conseil.

En fait dans mon cas mon soucis est qu'il me manque dans le Class CroxsControl le sub :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
  Private Sub InitializeComponent()
 ' Aucun code ?
    End Sub

En ajoutant simplement ce sub sans aucun code, à ma grande surprise le programme fonctionne parfaitement et les X dans un carrée apparaissent bien dans la zone PictureBox1. Il y a surement une raison mais laquelle ?

A vous lire.

[MABROUKI]

La raison en est que tu est un étourdi probablement et il suffit de jeter un coup d’œil au code posté du control perso CroixControl ou figure bien le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
  Public Sub New()
 
        ' Cet appel est requis par le concepteur.
        InitializeComponent()
 
        SetStyle(ControlStyles.SupportsTransparentBackColor, True)
        SetStyle(ControlStyles.Opaque, True)
        Me.BackColor = Color.Transparent
        Me.BorderStyle = BorderStyle.FixedSingle
        Me.Text = "X"
    End Sub

bon code..