Discussion :

[Dali29]

Bonjour,
Pour l’export j’ai trouvé une solution qui permet de convertir le fichier « .mm » de freemind vers un fichier « .xls « à partir de l’utilisation de XSLT.

Et après on choisit le fichier freemind/accesoires/mm2xls_utf8.xsl où se trouve l’utilisation de template XSLT pour transformer le fichier .mm en xls

Mais j’ai rencontré un problème au niveau de la conversion des tableaux qui se trouvent dans les commentaires des nœuds vers le fichier excel.

Les tableaux sont enregistrer comme des commentaires dans l’excel et en plus sont pas bien afficher et je veux l’afficher dans les cellules mais je n’ai pas arrivé à le faire.

J’ai essayé de modifier le code de fichier mm2xls_utf8.xsl qui permet de faire l’export est mais pas de résultat.
Avez-vous une idée ( Lignes de codes) pour mettre les commentaires dans des cellules.
Merci à vous.
vous trouvez au dessous le code et des images explicatifs.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
 
<?xml version="1.0" encoding="UTF-8"?>
<!--
    (c) by Naoki Nose, Eric Lavarde 2006-2008
    This code is licensed under the GPLv2 or later.
    (http://www.gnu.org/copyleft/gpl.html)
    Stylesheet to transform a FreeMind map into an Excel sheet, use menu point
    File -> Export -> Using XSLT... to choose this XSL file, and name the
    ExportFile Something.xls or Something.xml.
    2006-12-10: added support for notes and attributes (EWL)
    2008-10-23: corrected issue with ss namespace not being output (EWL)
-->
<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns="urn:schemas-microsoft-com:office:spreadsheet"
 xmlns:o="urn:schemas-microsoft-com:office:office"
 xmlns:x="urn:schemas-microsoft-com:office:excel"
 xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"
 xmlns:duss="urn:schemas-microsoft-com:office:dummyspreadsheet">
  <xsl:output method="xml" indent="yes" encoding="UTF-8" standalone="yes"/>
  <!-- the duss namespace alias is required in order to be able to output
  ss:Data properly, Excel ignores the extraneous dummy namespace. -->
  <xsl:namespace-alias stylesheet-prefix="duss" result-prefix="ss"/>
 
  <xsl:template match="/map">
    <xsl:processing-instruction name="mso-application"> progid="Excel.Sheet"</xsl:processing-instruction>
    <Workbook>
      <Styles>
 
<Style ss:ID="s16" ss:Name="attribute_cell">
<Borders>
<Border ss:Position="Bottom" ss:LineStyle="Continuous" ss:Weight="1"/>
<Border ss:Position="Left" ss:LineStyle="Continuous" ss:Weight="1"/>
<Border ss:Position="Right" ss:LineStyle="Continuous" ss:Weight="1"/>
<Border ss:Position="Top" ss:LineStyle="Continuous" ss:Weight="1"/>
</Borders>
</Style>
<Style ss:ID="s17" ss:Name="attribute_header">
<Borders>
<Border ss:Position="Bottom" ss:LineStyle="Continuous" ss:Weight="1"/>
<Border ss:Position="Left" ss:LineStyle="Continuous" ss:Weight="1"/>
<Border ss:Position="Right" ss:LineStyle="Continuous" ss:Weight="1"/>
<Border ss:Position="Top" ss:LineStyle="Continuous" ss:Weight="1"/>
</Borders>
<Font ss:Bold="1"/>
</Style>
 
  </Styles>
      <!-- we could probably put something more intelligent as worksheet name,
      but it would require name mangling to avoid unallowed characters -->
      <Worksheet ss:Name="FreeMind Sheet">
        <Table>
<xsl:apply-templates select="node">
<xsl:with-param name="index" select="1" />
</xsl:apply-templates>
        </Table>
      </Worksheet>
    </Workbook>
  </xsl:template>
 
<xsl:template match="node">
<xsl:param name="index" />
<Row><Cell ss:Index="{$index}">
<xsl:call-template name="output-node-text-as-data" />
</Cell>
<xsl:if test="attribute">
<Cell ss:StyleID="s17">
<Data ss:Type="String">Names</Data></Cell>
<Cell ss:StyleID="s17">
<Data ss:Type="String">Values</Data></Cell>
</xsl:if>
</Row>
<xsl:apply-templates select="attribute">
<xsl:with-param name="index" select="$index + 1" />
</xsl:apply-templates>
<xsl:apply-templates select="node">
<xsl:with-param name="index" select="$index + 1" />
</xsl:apply-templates>
</xsl:template>
 
<xsl:template match="attribute">
<xsl:param name="index" />
<Row><Cell ss:Index="{$index}" ss:StyleID="s16">
<Data ss:Type="String"><xsl:value-of select="@NAME" /></Data>
     </Cell>
     <Cell ss:StyleID="s16">
<Data ss:Type="String"><xsl:value-of select="@VALUE" /></Data>
     </Cell>
</Row>
</xsl:template>
 
<xsl:template name="output-node-text-as-data">
<xsl:choose>
<xsl:when test="richcontent[@TYPE='NODE']">
<!-- see comments about rich text and HTML format below -->
<duss:Data ss:Type="String" xmlns="http://www.w3.org/TR/REC-html40"><xsl:copy-of select="richcontent[@TYPE='NODE']/html/body/*" /></duss:Data>
</xsl:when>
<xsl:otherwise>
      <Data ss:Type="String"><xsl:value-of select="@TEXT"/></Data>
<!-- xsl:value-of select="normalize-space(@TEXT)" / -->
</xsl:otherwise>
</xsl:choose>
<xsl:call-template name="output-note-text-as-comment" />
</xsl:template>
 
<!-- export of rich text in HTML format should work, but formatting is lost
because Excel understands only HTML tags in capitals, whereas
FreeMind exports in small caps. This can probably be solved but would
require some more tweaking -->
<xsl:template name="output-note-text-as-comment">
<xsl:if test="richcontent[@TYPE='NOTE']">
<Comment><duss:Data xmlns="http://www.w3.org/TR/REC-html40"><xsl:copy-of
select="richcontent[@TYPE='NOTE']/html/body/*" /></duss:Data></Comment>
</xsl:if>
</xsl:template>
 
</xsl:stylesheet>