Discussion :

[BasicZX81]

Bonjour à tous, j'ai un nouveau problème :
Je voudrais afficher une belle ligne bleu sur le bas de la ligne courante, mais quand je clique sur une autre ligne, seule la cellule cliquée se redessine.
De plus les lignes déjà dessinée sur les autres lignes ne s'effacent pas. J'ai bien chercher une solution mais je ne trouve pas.

Si vous avez une idée ça serait vraiment sympa.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub DataGridViewCars_RowPostPaint(sender As Object, e As DataGridViewRowPostPaintEventArgs) Handles DataGridViewCars.RowPostPaint
        If e.RowIndex = DataGridViewCars.CurrentRow.Index Then
            e.Graphics.DrawLine(New Pen(Brushes.Blue, 5), New Point(e.RowBounds.Left, e.RowBounds.Bottom), New Point(e.RowBounds.Right, e.RowBounds.Bottom))
        End If
End Sub

[MABROUKI]

bonjour

1/Les limites du bounding rectangle du Row nécessite d'etre revu

2/Il faut invalider le Row ou ligne dessinée précédemment et pour cela il faut une variable d'index de Row à tenir à jour dans les events ou un re-painting est necessaire :
- DataGridView_CellEnter
- DataGridView_RowEnter

3/Appel a la peinture par défaut des Cells du Row s'il n'est le Row courant


code .vb revu:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
 
 
Public Class Form1
    Private rnd As New Random
    Private oldRowIndex As Int32 = 0
 
    Public Sub New()
        InitializeComponent()
        Me.DataGridView1.Dock = DockStyle.Bottom
        Me.Controls.Add(Me.dataGridView1)
        Me.Text = "DataGridView calendar column demo"
    End Sub
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        SetupColumns()
        AddRows()
    End Sub
    Private Sub SetupColumns()
        Dim col1 As New DataGridViewTextBoxColumn()
        col1.HeaderText = "ID"
        Dim col2 As New DataGridViewTextBoxColumn()
        col2.HeaderText = "Name"
        'add columns
        Me.DataGridView1.Columns.Add(col1)
        Me.DataGridView1.Columns.Add(col2)
    End Sub
    Private Sub AddRows()
        'add 5 rows
        Me.DataGridView1.RowCount = 5
        Dim row As DataGridViewRow
        Dim i As Integer = 1
        For Each row In Me.DataGridView1.Rows
            row.Cells(0).Value = (i * 10).ToString
            row.Cells(1).Value = "Item" + i.ToString
            i += 1
        Next row
    End Sub
 
    Private Sub DataGridView1_CellEnter(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) Handles DataGridView1.CellEnter
        If oldRowIndex <> -1 Then
            Me.DataGridView1.InvalidateRow(oldRowIndex)
        End If
        oldRowIndex = e.RowIndex
    End Sub
    Private Sub DataGridView1_RowEnter(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) Handles DataGridView1.RowEnter
        If oldRowIndex <> -1 Then
            Me.DataGridView1.InvalidateRow(oldRowIndex)
        End If
        oldRowIndex = e.RowIndex
    End Sub
 
    Private Sub DataGridView1_RowPostPaint(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewRowPostPaintEventArgs) Handles DataGridView1.RowPostPaint
        Dim rowBounds As New Rectangle(Me.DataGridView1.RowHeadersWidth,
                e.RowBounds.Top, Me.DataGridView1.Columns.GetColumnsWidth(
                DataGridViewElementStates.Visible) - Me.DataGridView1.HorizontalScrollingOffset + 1, e.RowBounds.Height)
 
        If e.RowIndex = DataGridView1.CurrentRow.Index Then
 
            'pen .
            Dim penLine As New Pen(Brushes.Red, 5.0)
 
            Dim clip As RectangleF = rowBounds
            ' Draw the content that spans multiple columns.
            Dim p0 As New PointF(rowBounds.X, rowBounds.Y + rowBounds.Height / 2)
            Dim p1 As New PointF(rowBounds.X + rowBounds.Width, rowBounds.Y + rowBounds.Height / 2)
 
            e.Graphics.DrawLine(penLine, p0, p1)
            penLine.Dispose()
        Else
            'peinture par defaut de la ligne courante
            e.PaintCells(rowBounds, DataGridViewPaintParts.All)
        End If
 
    End Sub
End Class

bon code...

[BasicZX81]

Merci beaucoup Mabrouki, ça fonctionne parfaitement . Ça ralenti juste un peu l'affichage par contre sur mon vieux Core2Duo sinon c'est parfait.