Discussion :

[Aschel]

Bonjour,
j'ais créé un script qui me permet de choisir, de modifier puis d'importer un fichier texte .txt.
Je souhaiterais que le script me renvoi une erreur si jamais on ne choisit pas un fichier .txt
J'ai essayé avec GetExtensionName mais cela me renvoi une erreur "Objet requis".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
Dim fsot, ft, ts, oFL, p, name
Dim fso, sIniDir, sFilter, sTitle, oDlg
Dim fichierFEC
 
'ouvre la fenêtre de choix de fichier
Function GetFileDlgEx(sIniDir,sFilter,sTitle)
  Set oDlg = CreateObject("WScript.Shell").Exec("mshta.exe ""about:<object id=d classid=clsid:3050f4e1-98b5-11cf-bb82-00aa00bdce0b></object><script>moveTo(0,-9999);eval(new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(0).Read("&Len(sIniDir)+Len(sFilter)+Len(sTitle)+41&"));function window.onload(){var p=/[^\0]*/;new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(p.exec(d.object.openfiledlg(iniDir,null,filter,title)));close();}</script><hta:application showintaskbar=no />""") 
  oDlg.StdIn.Write "var iniDir='" & sIniDir & "';var filter='" & sFilter & "';var title='" & sTitle & "';"
  GetFileDlgEx = oDlg.StdOut.ReadAll
End Function
 
sIniDir = ""
sFilter = "*.*txt"
sTitle = "Choisissez le fichier à importer"
 
fichierFEC = GetFileDlgEx(Replace(sIniDir,"\","\\"),sFilter,sTitle)
 
Set fso = CreateObject("Scripting.FileSystemObject")
Set oFl = fso.GetFile(fichierFEC)
Set name = fso.GetExtensionName(fichierFEC)
 
MsgBox(oFl)
MsgBox(name)
 
'Les modifications et l'import se font après et fonctionnent correctement (grâce à vous par ailleurs)

Il me renvoi une erreur sur la ligne Set name.
Je ne comprend pas d'ou viens mon erreur puisque MsgBox(oFl) me renvoi le chemin complet du fichier.

[ericlm128]

"GetExtensionName" te retourne une chaine de caractère et pas un objet tu ne doit pas mettre "Set" au début.
https://msdn.microsoft.com/en-us/lib...=vs.84%29.aspx

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

name = fso.GetExtensionName(fichierFEC)

[l_autodidacte]

Il me semble que tu n'as pas regardé la modification que j'ai faite sur le filtre (*.txt) et pas (*.*txt) à la ligne 15 de ce POST.
En dehors de la fonction, essaie avec cette modification

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
sIniDir = ""
sFilter = "*.txt"
sTitle = "Choisissez le fichier à importer"
 
fichierFEC = GetFileDlgEx(Replace(sIniDir,"\","\\"),sFilter,sTitle)
If fichierFEC ="" Then WScript.Quit 0
Set fso = CreateObject("Scripting.FileSystemObject")
Set oFl = fso.GetFile(fichierFEC)
' name = fso.GetExtensionName(fichierFEC)
 If UCase(fso.GetExtensionName(fichierFEC)) <> "TXT" Then  MsgBox "Mauvais choix de fichier"
MsgBox(oFl)

[Aschel]

Bonjour,

Merci de vos réponses.
En effet, en faisant la modification sur le filtre de l'extension cela ne permet que de choisir des fichiers .txt. Donc plus de problème de choix.
Pour être exact, le filtre doit être :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
sFilter = "Fichier texte (.txt)|.txt"

pour avoir un affichage correct dans la barre de recherche.
Merci quand même de vos réponses, cela pourra me servir plus tard.
Cordialement

[l_autodidacte]

Pourtant le filtre doit contenir le caractère * juste après la barre verticale sinon pas de retour de fichier :
sFilter = "Fichier texte (*.txt)|*.txt"

[Aschel]

Bonjour,

c'est exact, j'ai oublié de mettre * devant le .txt
Le filtre nécessite en effet de le rajouter.

Cordialement.