Discussion :

[Mat898]

Bonjour,

j'ai utilisé une boucle pour créer une table contenant des 50-échantillons aléatoires de deux variables W et Q.
Comment puis-je estimer la formule (les coefficients de Q=aW+b) par la méthode des moindres carrés sur SAS ?
Suis-je mieux de passer par la proc iml et de transformer mes résultats en vecteurs ? Et comment faire pour en arriver à la formule ?
Sinon, y a-t-il méthode plus efficace ? merci

[Clairant]

Bonjour,
oui j'essaie de comprendre votre préoccupation mais j'y arrive pas. Prenez un petit exemple avec quelques données, cela permet de vous dire l'outil le mieux adapté à votre problème. Sinon "proc reg" permet d'obtenir l'estimateur des Moindres Carrés Ordinaires (MCO).

[Mat898]

Désolé de la confusion. Je crois que j'ai essayé de poser trop de questions en même temps.
Voici mes variables :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
data varuniforme;
	call streaminit(5159362);
	do i=1 TO 50 ;
		W=-5+10*rand("Uniform");
		e=rand("Normal", 0, 0.25);		
      	output;
  	end;
run ;
 
data variablesWQ;
  set varuniforme;
  Q= 2*W+1+e;
  keep W Q;
run;

Je veux, à l'aide d'un code dans SAS, estimer les coefficients du modèle linéaire par la méthode des moindres carrés, c.a.d trouver a et b tels que Q= aW+b.
J'espère que ceci clarifie ma question!

Edit : Ma 2e question était : d'un point de vu d'efficience, est-ce que j'aurais pu créer ces variables aléatoires d'une autre façon (par exemple, sous forme de vecteurs avec une proc iml?) pour sauver du temps d’exécution dans le calcul des données et dans l'estimation des coefficients du modèle linéaire ? Si oui, de quelle manière? Un exemple de code serait apprécié, merci beaucoup!

[Clairant]

tu peux essayer pour la première question d'écrire simplement ce code ci-dessous :

proc reg data=variablesWQ outest=Tabestimation tableout; * outest te renvoit le tableau d'estimation et tableout y ajout les intervalles de confiances paramètres ;
title 'Régression de Q sur W ';
WQ: model Q= W;
run;
Par rapport à la possibilité de proc iml. Je pense que c'est bien possible. J'essaie de te voir ça.

[Clairant]

Voici le code de la proc IML

/* proc iml */
%let N=50;
proc iml;
call randseed(4321);
W=j(&N,1);
e=j(&N,1);
call randgen(W,"uniform",-5,5); /* créer la variable W */
call randgen(e,"normal",0,0.25); /* générer e */
Q= 2*W+1+e; /* créer la variable Q */
Z=W || j(&N,1,1);
T=inv(Z`*Z)*Z`*Q; /* estimation des paramètres de MCO */
print T; /* affichage à l'écran des paramètres (a b) */
quit;


Par ailleurs, je ne vois pas pertinent cette approche d'iml car la proc Reg te fournit une panoplie de résultat ce qui nécessitera beaucoup de code si on devrait le faire avec proc iml. En outre, le modèle est mal spécifié je pense vu la construction de ta variable expliquée ou dépendante.
Bon courage.