Discussion :

[BeanzMaster]

Salut à tous,

je vous explique. Je cherche à créer un petit logiciel pour capturer la couleur du pixel situé à la position actuelle de la souris. Jusque la pas de soucis. Maintenant je souhaiterai activer cette fonction à l'appuie des touches ALT+G lorsque mon application n'a pas le focus (elle est placé dans la barre de notification).
Sous windows c'est pas très compliqué avec un "hook" mais je souhaiterai que ce soit multi-plateforme. (Win,Linux, Mac)
J'ai essayé avec les fonctions de l'unité "Keyboard" dans un "threadtimer" ça ne fonctionne pas. L'appli se compile sans erreurs mais ça bloque le processus du timer.

J'ai trouvé dans la doc quelques références : http://wiki.lazarus.freepascal.org/LCL_Key_Handling et http://wiki.lazarus.freepascal.org/N...hortcut_system
Je ne sais pas par ou prendre le problème. Quelqu'un aurait-il de l'expérience avec Application.NotifyKeyDownBeforeHandler , Application.AddOnKeyDownBeforeHandler, Application.OnShortcut ou Application.OnUserInput car je pense qu'il faut passer par une de ces 4 possibilités mais je ne sais pas comment la documentation n'étant pas excessive et je pas trouvé de piste sur le web. Si vous avez des pistes je suis preneur.

Merci d'avance

[BeanzMaster]

Bonjour, voilà après quelques recherches, il m'est maintenant évident que pour avoir quelque chose de compatible Win/Linux et Mac, je vais devoir passer par des directives de compilation, du moins pour Mac car d'après ce que j'ai pu lire et comprendre, le mapping des touches est un peu différent sous Mac.

L'événement OnShorcut fonctionne mais uniquement lorsque l'application a le focus. Il semblerait bien qu'il faille passer par Application.AddOnKeyDownBeforeHandler et/ou Application.OnUserInput. Malheureusement, mon niveau d'anglais n'est pas encore assez élévé. J'ai bien trouvé quelques exemples, mais c'est pour l'interface Cocoa et je ne comprends pas tout aux explications IT données dans la langue de Shakespeare. Y aurait-il un "guru" qui pourrait me donner des chemins à explorer ?

Merci d'avance.

[BeanzMaster]

Salut à tous, j'ai plongé plus profond dans le web pour denicher des infos et j'ai trouvé quelques pistes :
La façon dont est mis en place la gestion des "Hotkeys" est différentes sur chaque plateforme "win/linux/mac" et en plus sous linux ca depend de l'environnement gnome, kde xfce..
Je suis tombé sur ce code source d'un lecteur de musique multiplateforme http://code.google.com/p/ovoplayer/s...c=svn206&r=206
Dans ce programme l'auteur à une solution pour ces trois plateforme (gnome pour linux). C'est très très bien codé, c'est complexe mais propre.
Je vais donc maintenant analysé ce code pour essayer d'en sortir un petit composant.

Pour Linux comme je le disais plus haut la gestion des touches est différent suivant l'environnement. D'apres ce que j'ai pu lire et comprendre il faudrait passer par la librairie de plus bas niveau X11 si l'on veux que ce soit portable si j'ai bien compris. Mais la le hic, pour trouver la façon de faire il faudrait faire des recherches sur des codes source en C

Pour plus d'infos pour linux cf :
http://stackoverflow.com/questions/2...em-wide-hotkey
http://stackoverflow.com/questions/1...-library-for-c
http://www.xfree.org/current/XGrabKey.3.html


Je vais donc commencer par le plus facile en 1er Windows . Et mettrai les sources a dispos ici sur ce forum

A+

[BeanzMaster]

Bonsoir à tous comme je vous l'ai dis voici le debut du petit composant que vous avais parler. Ce n'est qu'un debut y a que Windows qui est pris en charge.
Je ferai un petit Zip avec un exemple si vous arriver pas a vous en servir.

Dans tous les cas chez ca fonctionne nickel.

Voila la bete :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
unit BZApplicationHotKey;
 
{$mode objfpc}{$H+}
 
interface
 
//==============================================================================
 
uses
  Classes, SysUtils, LResources,
  {$IFDEF WINDOWS}
  windows,
  {$ENDIF}
  Forms, Controls, Graphics, Dialogs ;
//==============================================================================
 
{$IFDEF WINDOWS}
const
  WinClassName: string = 'HOTKEYBZAPPLICATIONHOTKEY';
  HotKeyAtomPrefix : string = 'BeanzHotKeyAtom';
{$ENDIF}
 
//==============================================================================
//==============================================================================
//==== [ TBZApplicationHotKey ]=================================================
//==============================================================================
 
type
  TBZApplicationHotKey = class(TComponent)
  private
    { Private declarations }
    FActive : boolean;
    FHotKey : Cardinal; //TShortCut;
 
    FOnHotKey : TNotifyEvent;
 
    //FHasRegistered: Boolean;
 
    //----------------------------------------------------------------------------
    // Variables pour intercepter les "HotKeys" sous Windows
    {$IFDEF WINDOWS}
      FHKID: Integer;
    {$ENDIF}
 
    //--------------------------------------------------------------------------
    // Fonctions pour intercepter les "HotKeys" sous Windows
    {$IFDEF WINDOWS}
      //procedure GetWndProc;
      //function WndProc(M:Message):boolean;
      function  CreateAppWindow: boolean;
    {$ENDIF}
 
    //--------------------------------------------------------------------------
    // Fonctions pour intercepter les "HotKeys" sous Linux
    {$IFDEF LINUX}
    {$ENDIF}
 
    //--------------------------------------------------------------------------
    // Fonctions pour intercepter les "HotKeys" sous Mac
    {$IFDEF DARWIN}
    {$ENDIF}
 
    //--------------------------------------------------------------------------
    // Fonctions internes du composant
    procedure DoRegisterHotKey();
    procedure DoUnregisterHotKey();
 
    procedure DoOnHotKey();
 
    procedure SetActive(Value: Boolean);
    procedure SetHotKey(Value: Cardinal);
 
 
  protected
    { Protected declarations }
 
    {$IFDEF WINDOWS}
    function getHotKeyID:Integer;
    {$ENDIF}
  public
    { Public declarations }
    constructor Create(AOwner: TComponent);override;
    destructor Destroy; override;
 
    function CreateHotKey(Modifiers, Key: Word): Cardinal;
  published
    { Published declarations }
    property Active:Boolean read FActive write setActive default false;
    property HotKey:Cardinal read FHotKey write setHotKey;
 
    property OnHotKey : TNotifyEvent read FOnHotKey write FOnHotKey;
  end;
 
//==============================================================================
 
procedure SeparateHotKey(HotKey: Cardinal; var Modifiers, Key: Word);
 
//==============================================================================
 
//procedure Register;
 
//==============================================================================
 
implementation
 
//==============================================================================
var
  //----------------------------------------------------------------------------
  // Variables pour intercepter les "HotKeys" sous Windows
  {$IFDEF WINDOWS}
    HWindow: HWND;
    WindowClassAtom: ATOM; // Renvoyer par RegisterWindowClass en cas de succes.
    WindowClassInfo: WNDCLASSEX; // Structure des infos d'une fenetre
  {$ENDIF}
 
{**-----------------------------------------------------------------------------
 * @Name        :
 * @Description :
 -----------------------------------------------------------------------------**}
//procedure Register;
//begin
//  {$I bzapphotkey_icon.lrs}
//  RegisterComponents('BeanzLaz',[TBZApplicationHotKey]);
//end;
 
 
//==============================================================================
//==============================================================================
// 1. TBZApplicationHotKey
//==============================================================================
 
//==== PRIVATE =================================================================
 
{$IFDEF WINDOWS}
 
{**-----------------------------------------------------------------------------
 * @Name        :  WinProc
 * @Description :  Handler pour Intercepter les message WM_HOTKEY
 *                 Nb: Vous pouvez intercepter d'autre messages comme ceux de la
 *                     souris, suffit d'ajouter des conditions au CASE ce qui
 *                     permettrai avec un peu d'ingéniosité de faire des HotKeys
 *                     genre : CRTL + ALT + G + SOURIS_BOUTON_GAUCHE
 -----------------------------------------------------------------------------**}
function WinProc(hw: HWND; uMsg: UINT; wp: WPARAM; lp: LPARAM): LRESULT;stdcall; export;
var
 obj : TBZApplicationHotKey;
begin
  Result := 0;
  case uMsg of
    WM_HOTKEY :
    begin
        obj := TBZApplicationHotKey(GetWindowLongPtr(HWindow,GWL_USERDATA));
       // showmessage(string(wp));
        if wp=obj.getHotKeyID then obj.DoOnHotKey;
    end
    else
      Result := DefWindowProc(hw, uMsg, wp, lp);
    end; // Case
end; // WinProc
 
{**-----------------------------------------------------------------------------
 * @Name        : CreateAppWindows
 * @Description : Creation d'une fenetre virtuelle avec notre Hook
 -----------------------------------------------------------------------------**}
function  TBZApplicationHotKey.CreateAppWindow: boolean;
 
  function RegisterWindowClass: boolean;
  begin
    WindowClassInfo.cbSize := sizeof(WindowClassInfo);
    WindowClassInfo.Style := 0;
    WindowClassInfo.lpfnWndProc := @WinProc;
    WindowClassInfo.cbClsExtra := 0;
    WindowClassInfo.cbWndExtra := 0;
    WindowClassInfo.hInstance := HInstance;
    WindowClassInfo.hIcon := 0;
    WindowClassInfo.hCursor := 0;
    WindowClassInfo.hbrBackground := 0;
    WindowClassInfo.lpszMenuName := nil;
    WindowClassInfo.lpszClassName := PChar(WinClassName);
    WindowClassInfo.hIconSm := 0;
    WindowClassAtom := RegisterClassEx(WindowClassInfo);
    Result := WindowClassAtom <> 0;
  end; // RegisterWindowClass - Nested Function
 
begin
  Result := False;
  if not RegisterWindowClass then
  begin
     exit;
  end;
  HWindow := CreateWindowEx(WS_EX_NOACTIVATE or WS_EX_TRANSPARENT,
    PChar(WinClassName), PChar(WinClassName), Ws_popup or WS_CLIPSIBLINGS, 0,
    0, 0, 0, 0, 0, HInstance, nil);
  if HWindow <> 0 then
  begin
    ShowWindow(HWindow, SW_HIDE);
    SetWindowLongPtr(HWindow,GWL_USERDATA,PtrInt(Self));
    UpdateWindow(HWindow);
    Result := True;
    Exit;
  end;
end;
{$ENDIF}
 
{**-----------------------------------------------------------------------------
 * @Name        : DoRegisterHotKey
 * @Description : Ajoute un HotKey Global dans le systeme d'exploitation
 -----------------------------------------------------------------------------**}
procedure TBZApplicationHotKey.DoRegisterHotKey;
var   Modifiers, Key: Word;
begin
  SeparateHotKey(FHotKey, Modifiers, Key);
  {$IFDEF WINDOWS}
  FHKID := GlobalAddAtom(PChar(HotKeyAtomPrefix + IntToStr(FHotKey)));
  RegisterHotKey(HWindow, Longint(FHKID), Modifiers, Key);
  {$ENDIF}
end;
 
{**-----------------------------------------------------------------------------
 * @Name        : DoUnRegisterHotKey
 * @Description : Supprime un HotKey Global dans le systeme d'exploitation
 -----------------------------------------------------------------------------**}
procedure TBZApplicationHotKey.DoUnRegisterHotKey;
begin
  {$IFDEF WINDOWS}
  UnRegisterHotkey( HWindow, Longint(FHKID));
  GlobalDeleteAtom(FHKID);
  {$ENDIF}
end;
 
 
{**-----------------------------------------------------------------------------
 * @Name        :  SetHotKey
 * @Description :  Definit la combinaison de touche à intercepter
 -----------------------------------------------------------------------------**}
procedure TBZApplicationHotKey.SetHotKey(Value: Cardinal);
var
  B: Boolean;
begin
  if FHotKey <> Value then
  begin
    B := FActive;
    SetActive(False);
    FHotKey := Value;
    SetActive(B);
  end;
end;
 
{**-----------------------------------------------------------------------------
 * @Name        : SetActive
 * @Description : Active/Désactive l'interception des HotKeys
 -----------------------------------------------------------------------------**}
procedure TBZApplicationHotKey.SetActive(Value: Boolean);
begin
  if FActive <> Value then
  begin
      FActive := Value;
      if FActive then
      begin
        if not (csDesigning in ComponentState) then
        begin
          {$IFDEF WINDOWS}
          DoRegisterHotKey;
          {$ENDIF}
        end;
      end;
  end;
end;
 
{**-----------------------------------------------------------------------------
 * @Name        : DoOnHotKey
 * @Description : Lance une action lorsque le HotKey est intercepté
 -----------------------------------------------------------------------------**}
procedure TBZApplicationHotKey.DoOnHotKey;
begin
  if Assigned(FOnHotKey) then
    FOnHotKey(Self);
end;
 
//==== PROTECTED ===============================================================
 
{$IFDEF WINDOWS}
{**-----------------------------------------------------------------------------
 * @Name        : getHotkeyID
 * @Description : Retourne l'ID de notre HotKey
 -----------------------------------------------------------------------------**}
function TBZApplicationHotKey.getHotKeyID:integer;
begin
  result:=FHKID;
end;
{$ENDIF}
 
//==== PUBLIC ==================================================================
 
{**-----------------------------------------------------------------------------
 * @Name        : Create
 * @Description : Construction de notre composant
 -----------------------------------------------------------------------------**}
constructor TBZApplicationHotKey.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  //HotKeyList := TList.Create;
 
  if not (csDesigning in ComponentState) then
  begin
    //FHandle := Classes.AllocateHWnd(HookProc);
    {$IFDEF WINDOWS}
    CreateAppWindow;
    {$ENDIF}
  end;
end;
 
{**-----------------------------------------------------------------------------
 * @Name        : Destroy
 * @Description : Destruction de notre composant
 -----------------------------------------------------------------------------**}
destructor TBZApplicationHotKey.Destroy;
begin
  {$IFDEF WINDOWS}
  DoUnRegisterHotKey;
  DestroyWindow(HWindow);
  {$ENDIF}
  inherited Destroy;
end;
 
{**-----------------------------------------------------------------------------
 * @Name        :  CreateHotKey
 * @Description :  Creation du raccourcis clavier HotKey
 * @Exemple     :  CreateHotKey(MOD_CONTROL+MOD_ALT,VK_G); // CTRL+ALT+G
 -----------------------------------------------------------------------------**}
function TBZApplicationHotKey.CreateHotKey(Modifiers, Key: Word): Cardinal;
const
  VK2_SHIFT   =  32;
  VK2_CONTROL =  64;
  VK2_ALT     = 128;
  VK2_WIN     = 256;
var
  hk: Cardinal;
begin
  hk := 0;
  if (Modifiers and MOD_ALT) <> 0 then
    Inc(hk, VK2_ALT);
  if (Modifiers and MOD_CONTROL) <> 0 then
    Inc(hk, VK2_CONTROL);
  if (Modifiers and MOD_SHIFT) <> 0 then
    Inc(hk, VK2_SHIFT);
  if (Modifiers and MOD_WIN) <> 0 then
    Inc(hk, VK2_WIN);
  hk := hk shl 8;
  Inc(hk, Key);
  Result := hk;
end;
 
//==============================================================================
//==============================================================================
 
//==============================================================================
// Fonctions Internes
//==============================================================================
 
{$IFDEF WINDOWS}
{**-----------------------------------------------------------------------------
 * @Name        : SeparateHotKey
 * @Description : Separe les touches normal et les touches de controle du Hotkeys
 *                pour les utiliser avec RegisterHotKey
 -----------------------------------------------------------------------------**}
procedure SeparateHotKey(HotKey: Cardinal; var Modifiers, Key: Word);
const
  VK2_SHIFT   =  32;
  VK2_CONTROL =  64;
  VK2_ALT     = 128;
  VK2_WIN     = 256;
var
  Virtuals: Integer;
  V: Word;
  x: Word;
begin
  Key := Byte(HotKey);
  x := HotKey shr 8;
  Virtuals := x;
  V := 0;
  if (Virtuals and VK2_WIN) <> 0 then
    Inc(V, MOD_WIN);
  if (Virtuals and VK2_ALT) <> 0 then
    Inc(V, MOD_ALT);
  if (Virtuals and VK2_CONTROL) <> 0 then
    Inc(V, MOD_CONTROL);
  if (Virtuals and VK2_SHIFT) <> 0 then
    Inc(V, MOD_SHIFT);
  Modifiers := V;
end;
 
 
{$ENDIF}
 
//==============================================================================
//==============================================================================
 
//initialization
 
//------------------------------------------------------------------------------
//finalization
 
//==============================================================================
end.

et voila quelques procedure a placer dans votre application pour tester

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
procedure TForm1.processHotKey(Sender:TObject);
begin
  Form1.WindowState:=wsMaximized;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
var modifiers,key:word;
begin
 modifiers := (MOD_CONTROL + MOD_ALT);
 key := VK_G;
 FHotKeyManager:=TBZApplicationHotKey.Create(self);
 FHotKeyManager.HotKey := FHotKeyManager.CreateHotKey(modifiers,key);
 FHotKeyManager.OnHotKey := @processHotKey;
 FHotKeyManager.Active := True;
end;
 
procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
begin
  FHotKeyManager.free;
end;

A Bientot pour la suite

[BeanzMaster]

Salut me revoila. Bon J'ai peut être trouvé la solution pour Linux en passant directement par la librairie X11 et par un thread (fonctionne peut être sous mac, mais je vais pas trop m'avancer).
Je vous ai fait une petite demo cf zip ci-joint . hotkeys.zip

Le composant peut désormais gérer plusieurs raccourcis. Il fonctionne sous Windows ca c'est fait. Maintenant pour Linux, j'aurais besoin de personnes pour tester si ça marche. N'ayant pas les interfaces des librairie X installées sous Windows je ne suis pas sur que mon code soit à 100% correct (cf procedure WaitForXevent). J'ai essayé de commenter le code le mieux possible. Voili Voilou. Je compte sur vous pour m'aider un petit peu. (me sens seul sur ce sujet sniff ). Et si vous avez des questions n'hésitez pas.

Merci à bientot