Discussion :

[tmryuga]

Bonjour,

Je travail sur une application proposant un calendrier avec gestion de rendez vous à l'identique de celle de outlook et de exchange.

Cependant je voudrai pouvoir synchroniser mon calendrier avec celui des utilisateurs de outlook exchange. Vu qu'ils passent par outlook pour leur boite exchange, j'aurai voulu savoir si le calendrier etait par défaut celui de outlook, celui d'exchange ou s'il y a une synchronisation des 2 calendriers avec une sauvegarde locale et serveur.

Je vous pose la question car je n'ai pas de serveur exchange sous la main pour tester.

je vous remercie d'avance pour toutes vos réponses.

[cow_boy]

bonjour, je suis sur un projet similaire !!
J'ai déja posté le forum.

[Théolude]

Idem...

Voir les posts :
http://www.developpez.net/forums/sho...d.php?t=574733

http://www.developpez.net/forums/sho...49#post3422049

Cherche solution désepéremment

[Théolude]

Le script qui fonctionne côté client pour exporter l'agenda de Outlook vers un serveur FTP:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
Dim objOutlook
Dim objNameSpace
Dim objFolder
Dim MyItems
Dim CurrentAppointment
Dim strOutput

' Positionnement des variables / constantes----------------------------------------------------------
olMailItem = 0
olTaskItem = 3
olFolderTasks = 13
olFolderCalender = 9
olFree = 0
olTentative  = 1
olBusy = 2
olOutOfOffice = 3
boolSuccess = 0

' Récupération du nom d'utilisateur loggé-------------------------------------------------------------
Set objNetwork = WScript.CreateObject("WScript.Network")
strUserName = objNetwork.username

Set objFileSystem = WScript.CreateObject("Scripting.FileSystemObject")
Set objOutPutFile = objFileSystem.CreateTextFile(strUserName & ".data", True)
Set objFtpCmdFile = objFileSystem.CreateTextFile("ftpagenda.cmd", True)
Set objOutlook = WScript.CreateObject("Outlook.application")
Set objNameSpace = objOutlook.GetNameSpace("MAPI")
Set shellCmd = WScript.CreateObject("WScript.Shell")

' On test 10 fois une connexion au serveur FTP--------------------------------------------------------
While intCount < 10
	Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}!\\").ExecQuery("select * from Win32_PingStatus where address = 'url.de.mon.serveur.ftp'")
	For Each objStatus in objPing
		If objStatus.Statuscode = 0 Then

			' Il y a une connexion réseau (réussite du ping)
			' On se connecte au calendrier Outlook de l'utilisateur sur le poste
			Set objFolder = objNameSpace.GetDefaultFolder(olFolderCalender)
			Set MyItems = objFolder.Items

			' Calcul de l'intervalle dans lequel on va exporter l'agenda
			strDateStart = DateAdd("d", +0, date)
			strDateEnd = DateAdd("d", +28, date)

			' On recherche les rendez-vous correspondant à l'intervalle
			Set objCurrentAppointment = MyItems.Find("[Start] >= """ & strDateStart & """ and [Start] <= """ & strDateEnd & """")

			' Tant qu'il y a un rendez-vous
			While TypeName(objCurrentAppointment) <> "Nothing"

				' Et si celui-ci correspond a un état occupé ou absent
				If objCurrentAppointment.BusyStatus = olBusy Or objCurrentAppointment.BusyStatus = olOutOfOffice Then

					' Ecriture du fichier d'export au format texte
					objOutPutFile.WriteLine objCurrentAppointment.Start & vbTab & objCurrentAppointment.End & vbTab & objCurrentAppointment.Subject & vbTab & objCurrentAppointment.Location & vbTab & objCurrentAppointment.Categories & vbTab & objCurrentAppointment.AllDayEvent
				End If

				Set objCurrentAppointment = MyItems.FindNext
			Wend

			' On ferme tout
			objOutPutFile.Close
			Set objFolder = Nothing
			Set objMsg = Nothing

			' Création du fichier de commandes FTP
			With objFtpCmdFile
			 .WriteLine "utilisateurFtp"
			 .WriteLine "motdepasseFtp"
			 .WriteLine "PUT *.data"
			 .WriteLine "DISCONNECT"
			 .WriteLine "QUIT"
			 .Close
			End With

			' On envoie le fichier en FTP et on le supprime du poste
			' On attend la fin de l'exécution (option true), et on masque la fenêtre (option 0)
			shellCmd.Run "ftp -v -s:ftpagenda.cmd url.de.mon.serveur.ftp", 0, true

			' Suppression des fichiers cmd et data (sécurité)
			objFileSystem.deleteFile("*.data")
			objFileSystem.deleteFile("*.cmd")
			boolSuccess = 1

		End If
	Next

	' On compte le nombre de tentatives, en cas de succès on arrête
	intCount = intCount + 1
	If (boolSuccess) Then
		intCount = 10
	End If
Wend

[Senji]

Salut,

le client MAPI se connecte au serveur exchange grâce à l'identifiant de la boîte aux lettres et télécharge les messages depuis celle-ci. Si l'option Mise en cache est coché l'utilisateur aura une copie de sa boîte aux lettres en locale, ce qui lui permet de le consulter même si il n'est pas connecté au réseau local. dans la boite aux lettres y a aussi le calendrier. donc on ne peut pas parler à proprement dit d'une synchronisation, mais plutôt d'une connexion client-Serveur.

bye

[Théolude]

le client MAPI se connecte au serveur exchange grâce à l'identifiant de la boîte aux lettres et télécharge les messages depuis celle-ci. Si l'option Mise en cache est coché l'utilisateur aura une copie de sa boîte aux lettres en locale, ce qui lui permet de le consulter même si il n'est pas connecté au réseau local. dans la boite aux lettres y a aussi le calendrier. donc on ne peut pas parler à proprement dit d'une synchronisation, mais plutôt d'une connexion client-Serveur.

Bonjour Senji,

(tu es joueur ? Le pseudo Senji ça te vient d'où ?)

En ce qui me concerne je parlais d'export, par ailleurs pour des clients hors domaine sans connexions MAPI, le calendrier Outlook est autonome, selon ce que tu fais de ton export, on peut parler de synchronisation

Théo

[Senji]

zut, sorry, j'avais mal compris.

bye

[osmos]

Bonjour tout le monde,

Pouvez vous svp me renseigner sur la solution Microsoft permettant de synchroniser crm 2013 et Exchange.?
et connaitre les enjeux (que synchronise-t-on, sous quelles conditions ...) et un point sécurité (est on obligé de synchroniser tous les contacts, et comment faire pour les contacts qui ne sont pas affectés à un vendeur) ?