Erreur execution script

**help57** · 18/08/2013, 19h56

Bonjour,
j'ai un message d'erreur lors de l'exécution d'un script.
Je précise que j'utilise le même repertoire pour d'autre script est tout se déroule normalement
Si quelqu'un a une idée
Merci
message d'erreur:
Script : C:\Users\habib\Desktop\testnew.vbs
Ligne : 15
Caract. : 12
Erreur : Chemin d'accès introuvable
Code : 800A004C
Source : Erreur d'exécution Microsoft VBScript

ci-dessous mon script

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Dim filesys, file, folderName, objFile, folderObj, fileColl, objRegExp, newFile
Set filesys = CreateObject("Scripting.FileSystemObject")
 
folderName = "C:\Users\reptest"
Set folderObj = filesys.GetFolder(folderName)
Set fileColl = folderObj.Files
 
Set objRegExp = New RegExp
objRegExp.Pattern = ".txt" 'looking for .txt (extension) match
objRegExp.IgnoreCase = True
 
For Each objFile In fileColl
     If objRegExp.Test(objFile.Name) Then
           newFile = objRegExp.Replace(objFile.Name, ".bak") 
           filesys.MoveFile objFile, folderName & "backup\" & newFile 
     End If
Next

**hackoofr** · 19/08/2013, 05h18

Si je suppose que le dossier backup existe alors :
Dans la ligne N°15 il manque "\"

filesys.MoveFile objFile, folderName & "backup\" & newFile

filesys.MoveFile objFile, folderName & "\backup\" & newFile

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
Dim filesys,file,folderName,objFile,folderObj,fileColl,objRegExp,newFile,BackupFolder
Set filesys = CreateObject("Scripting.FileSystemObject")
folderName = "C:\Users\reptest"
If Not filesys.FolderExists(folderName) Then
    MsgBox "Erreur le Dossier "&qq(folderName)&" n'existe pas !",16,"Erreur le Dossier "&qq(folderName)
    Wscript.Quit
end if
BackupFolder = folderName & "\backup\"
SmartCreateFolder(BackupFolder)
Set folderObj = filesys.GetFolder(folderName)
Set fileColl = folderObj.Files
Set objRegExp = New RegExp
objRegExp.Pattern = ".txt" 'looking for .txt (extension) match
objRegExp.IgnoreCase = True
 
For Each objFile In fileColl
    If objRegExp.Test(objFile.Name) Then
        newFile = objRegExp.Replace(objFile.Name,".bak") 
        filesys.MoveFile objFile,BackupFolder & newFile 
    End If
Next
MsgBox "Tous les fichiers de type "& qq(objRegExp.Pattern) &" sont renommés et déplacés dans le dossier "& qq(BackupFolder),64,"Backup Files"
Ouvrir(qq(BackupFolder))
 
Sub SmartCreateFolder(strFolder)
    Dim oFSO:Set oFSO = CreateObject("Scripting.FileSystemObject")
    If oFSO.FolderExists(strFolder) Then
        Exit Sub
    Else
        SmartCreateFolder(oFSO.GetParentFolderName(strFolder))
    End If
    oFSO.CreateFolder(strFolder)
    Set oFSO = Nothing    
End Sub
 
Function qq(strIn)
    qq = Chr(34) & strIn & Chr(34)
End Function 
 
Sub Ouvrir(Dossier)
    Dim ws
    Set ws = createobject("Wscript.Shell")
    ws.run "explorer " & Dossier
End Sub