Discussion :

[rabso007]

Salut tout le monde
J'ai besoin d'aide SVP
Mon problème c'est que je veux sauvegarder des éléments de fichier GroupePriority.XML dans un tableau de type ArrayList trié dans un ordre croissant selon les priorités :o
Pourriez vous m'indiquer comment faire ?
Merci en avance )
mon fichier GroupePriority.XML est le suivante :

[-N4w4k-]

Salut,

Tu peux utiliser une classe Groupe:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
'Classe représentant un GROUPE
Class Groupe
    Implements IComparable(Of Groupe)
 
 
    Public Property Name As String
    Public Property Priority As Integer
 
    Sub New(ByVal Name As String, ByVal Priority As Integer)
        Me.Name = Name
        Me.Priority = Priority
    End Sub
 
    Public Function CompareTo(ByVal other As Groupe) As Integer Implements System.IComparable(Of Groupe).CompareTo
        Return Me.Priority.CompareTo(other.Priority)
    End Function
End Class

Et extraire les données comme ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Imports System.Xml
 
Module ModuleMain
 
    Sub Main()
        Dim groupes As List(Of Groupe) = ExtractionGroupes("test.xml")
 
        For Each groupe As Groupe In groupes
            MsgBox(groupe.Name + " - " + groupe.Priority.ToString)
        Next
    End Sub
 
    'Retourne une liste de Groupe à partir d'un fichier xml
    Private Function ExtractionGroupes(ByVal filename As String) As List(Of Groupe)
        'nouvelle list
        ExtractionGroupes = New List(Of Groupe)
 
        'Lecture
        Try
            'Ouverture du fichier xml
            Dim xmlDoc As New XmlDocument
            xmlDoc.Load(filename)
            Dim root As XmlElement = xmlDoc.DocumentElement
 
            'Pour chaque groupe du fichier xml..
            For Each groupeElem As XmlElement In root.GetElementsByTagName("GROUPE")
                'On récupère les données
                Dim name As String = groupeElem.Attributes("name").Value
                Dim priority As Integer = groupeElem.Attributes("priority").Value
                'On crée un nouveau Groupe..
                Dim groupe As New Groupe(name, priority)
                '.. qu'on ajoute à la list à retourner
                ExtractionGroupes.Add(groupe)
            Next
            'On finit par trier la list
            ExtractionGroupes.Sort()
        Catch ex As Exception
            MsgBox("Erreur concernant la lecture du fichier xml.")
        End Try
 
    End Function
 
End Module

[tomlev]

ArrayList, ça fait des années que c'est dépassé... utilise plutôt des listes génériques.

Sinon, avec Linq to XML tu peux faire quelque chose comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim doc = XDocument.Load("GroupPriority.xml")
Dim groupes =
    From g in doc.Root.Elements("GROUPE")
    Select Name = CType(g.Attribute("name"), String),
           Priority = CType(g.Attribute("priority"), Int32)
    Order By priority
 
Dim liste = groupes.ToList()

[rabso007]

enfin mon problème est résolue donc je veux le partager avec vous :




et le résultat ==>