Discussion :

[zebrette]

Bonjour,

J'ai une datagridview, DGV, dont la datasource, DS, est une list(of obj), LOf.
Il semble que même avec la propriété de la DGV "AllowuserToAddRow" sur "True", je ne puisse pas ajouter de ligne directement depuis la grille.

Alors j'ai bien vu que je pouvais le faire en ajoutant un objet à ma LOf, mais ca demande d'ajouter deux bouton sur le formulaire, un pour ajouter des entrées, un autre pour les supprimer, et d'écrire des handler et tout et tout.

c'est pas si compliqué que ca à faire, mais j'aimerais pouvoir me baser sur la grille: que la ligne "NewRow" apparaisse et que quand l'utilisateur entre de nouvelles valeurs, les objets correspondant soient ajoutés à la LOf, quitte à écrire un peu de code dans le handler "NewRowNeeded" de la DGV ou quelquechose du genre... et le luxe serait de supprimer les objets de la LOf quand ils sont supprimés de la grille...

Est-ce possible?
merci,

Zebrette

[MABROUKI]

bonjour zebrette.
Oui c'est possible mais tu dois gerer explicitement ton BindingSource sous-jacent qui est à l'oeuvre behind the scene ......
Tu utilises pour ce faire lors de:
1/Ajout d'un row:
-son event adding_new pour creer un nouvel Objet "factice" avec ton constructeur New qui est ensuite "editable" par l'user ou bien carrement le populer soit par saisie de l'User soit par toute autre Source...
2/Suppression d'un row (le luxe pas cher de 2012):
-un appui sur la touche supprime positionne sur la row visee fait simplement le boulot...
le code du form avec un dgv ,un listbox et un textbox bindes à un BindindSource lequel .........est lie à ta liste (of Person).....
Il y a egalement un statusStrip avec un statusStripLabel pour "ecouter" l'event ListChanged du BindindSource(itemAdded,itemRemoved....).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
 
Public Class Form2
    Private MyListPerson As New List(Of Person)
    Private WithEvents binding1 As New BindingSource
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
 
        With MyListPerson
            .Add(New Person("ItemFName1", "ItemLName1"))
            .Add(New Person("ItemFName2", "ItemLName2"))
            .Add(New Person("ItemFName3", "ItemLName3"))
            .Add(New Person("ItemFName4", "ItemLName4"))
        End With
 
 
        Me.binding1.AllowNew = True
        Me.binding1.DataSource = MyListPerson
 
        Me.ListBox1.DataSource = Me.binding1
        Me.ListBox1.DisplayMember = "FirstName"
        Me.DataGridView1.DataSource = Me.binding1
        Me.textBox1.DataBindings.Add("Text", Me.binding1, "FirstName")
 
 
    End Sub
 
    Private Sub binding1_AddingNew(ByVal sender As Object, ByVal e As System.ComponentModel.AddingNewEventArgs) Handles binding1.AddingNew
        e.NewObject = New Person()
    End Sub
 
    Private Sub binding1_ListChanged(ByVal sender As Object, ByVal e As System.ComponentModel.ListChangedEventArgs) Handles binding1.ListChanged
        Me.ToolStripStatusLabel1.Text = e.ListChangedType.ToString()
 
    End Sub
 
 
End Class
 
Public Class Person
    Public Sub New()
 
    End Sub
    Public Sub New(ByVal FName As String, ByVal LName As String)
        FirstName = FName
        mLastName = LName
    End Sub
    Private mFirstName As String
    Public Property FirstName() As String
        Get
            Return mFirstName
        End Get
        Set(ByVal value As String)
            mFirstName = value
        End Set
    End Property
    Private mLastName As String
    Public Property LastName() As String
        Get
            Return mLastName
        End Get
        Set(ByVal value As String)
            mLastName = value
        End Set
    End Property
End Class

bon code...........

[zebrette]

parfait, c'est ce qu'il me fallait.

en très résumé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
        Dim binding1 as New bindingsource
        binding1.datasource= List(Of obj)
        binding1.AllowNew = True

Merci par ailleurs pour les bonus, l'event ListChanged et le code sample.


Zebrette