Discussion :

[Elcocco]

Bonjour,

j'ai une petite question pour vous, cela fait quelques heures que je galère à créer mes tranches via SAS.

je m'explique j'ai une table qui fait environ 120 000 lignes avec dedans deux colonnes la première un flag et la deuxième une série de valeur numérique

exemple
NA 0
P 5.053
M 6.025
G 8.035

J'aurais aimer mettre les valeurs numérique en tranche de pas de 1, mais le soucis c'est que j'ai des valeurs comprises entre 0 et 386.

J'ai donc besoin de votre aide pour écrire quelques choses d'efficace et rapide?

Merci d'avance

[MEGAMIND2]

On peut voir ce que tu as commencé?

[Elcocco]

Pour l'instant j'avais commencer la méthode barbare :

If 0<=PM<1 then tranche = 'entre 0 et 1';
else if 1<=PM<2 then tranche = 'entre 1 et 2'; et ainsi de suite.

Je voulais passer par une boucle mais je bloque à ce niveau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
data tranche_de_panier;
	set panier_boucherie;
	format tranche = $20.;
	do i=&min. to &max.;
        if i<=PM<i+1 then tranche(i)

[Manoutz]

J'aurais aimer mettre les valeurs numérique en tranche de pas de 1, mais le soucis c'est que j'ai des valeurs comprises entre 0 et 386.

tu peux expliquer?

[olivier.decourt]

Bonjour.
La boucle est une bonne idée, mais plutôt pour créer un format. Ensuite, tu appliques ton format de manière légère (instruction FORMAT, la variable garde sa vraie valeur stockée) ou en créant une nouvelle variable texte (fonction PUT).
Pour créer ton format, il faut une étape DATA qui génère les variables suivantes : FMTNAME, TYPE, START, END et LABEL. Plus EEXCL pour indiquer l'ouverture à droite de l'intervalle.
La table ainsi créée est mise en entrée de la proc Format via l'option CNTLIN.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
DATA work.format ;
  fmtname="tranche" ; /* nom du format */
  type="N" ; /* format numérique */
  DO i=0 TO 386 ;
    start=i ; /* borne inf */
	end=i+1 ; /* borne sup */
	eexcl="Y" ; /* intervalle ouvert à droite : [i;i+1[ */
	label=COMPBL(CAT("entre ",start," et ",end)) ; /* valeur rendue par le format */
	OUTPUT ;
  END ;
RUN ;
PROC FORMAT CNTLIN=work.format ;
RUN ;
DATA work.test ; /* jeu d'essai */
  DO i=1 TO 50 ;
    x = ROUND(RANUNI(1)*386) ;
	tranche = PUT(x,tranche.) ; /* crée une variable texte avec les tranches */
    OUTPUT ;
  END ;
RUN ;

Bon courage.
Olivier

[Elcocco]

Merci pour l'astuce cela marche nickel.
Grâce à cela je viens de gagner beaucoup de temps et d'énergie.

[MEGAMIND2]

Sans utiliser une boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
data test;
input id$ var;
cards;
NA 0
P 5.053
M 6.025
G 8.035
;
run;
 
proc sort data=test;
by var;run;
 
 
data test2;
set test;
sup=int(var);
if sup ne 0 then do;
inf=sup-1;
end;
if sup=0 then inf=0;
inf2=put(inf,best.);
sup2=put(sup,best.);
tranche="Entre"!!inf2!!' et '!!sup2;
drop inf sup;
run;

[Elcocco]

merci pour la deuxième solution, je viens de la tester elle marche nickel je me suis juste permis de rajouter l'option COMPBL au niveau de la définition de la tranche.

Encore Merci