Discussion :

[Souleyre]

Bonjour à tous,
Lorsque j'ouvre une appli dans l'environnement IDE de VB6, les feuilles de code et d'objet s'ouvrent en format réduit. Quelqu'un connaîtrait-il la méthode ou le paramétrage qui permettrait d'ouvrir en agrandi?
Merci pour votre aide.
Souleyre

[DarkVader]

Bonjour,
Sauf à utiliser une configuration exotique (multi écrans de résolutions différentes)
la disposition des fenêtres est mémorisée en taille et en position avec la sauvegarde du projet dans le fichier vbw :
il suffit donc de sauvegarder le projet avec la disposition voulue et quitter en utilisant le menu
(principe des applications Office.)

Remarque :
Il existe d'autres options (Outils>Options) concernant la disposition et le comportement des fenêtres :
Onglet Général : Réduire le projet masque les fenêtres
Onglet Ancrage : Ancrer ou non les fenêtres
Onglet Etendues : Environnement de développement SDI => très utile si vous disposez d'un environnement multi écrans.

[Souleyre]

Bonjour DarkVader,
Effectivement en jouant sur le paramètres du vbw on peut arriver faire occuper une plus grande place aux fenêtres de l'éditeur, mais je ne réussis pas à faire mémoriser l'espace maximum que l'on peut obtenir en 2ble-cliquant sur la barre de titre de la fenêtre.
Par vailleurs, j'ai essayé un tas d'options diverses du menu 'option' sans grand succès.

[DarkVader]

Ce sont les lettres qui déterminent l'état de la fenêtre.

Si tu désires un environnement particulier que l'ide ne gère pas,
tu as aussi la possibilité (très facile) de créer un addin dédié :
il suffit d'ajouter la librairie "VB6 ...extensibility" et de configurer la collection CodePanes.

[Souleyre]

Tu dis que ce sont les lettres qui déterminent l'état de la fenêtre, j'ai supposé que tu parlais de la lettre finale de la ligne du vbw; j'ai essayé de la modifier mais je n'en connais pas la signification, en tout état de cause, cette lettre redevient "C" après avoir quitté.
La librairie "VB6 extensibility" me paraît prometteuse, où peut-on la trouver et comment l'utiliser?

[DarkVader]

Dans le dossier VB98

[Souleyre]

Je dois être un peu lourd mais qu'est-ce que le dossier VB98?
Quid à propos des "lettres"?

[DarkVader]

VB98 est le répertoire d'installation de VB6.
Si tu n'en disposes pas, y a un blème

Plus simplement, comme je suis dans un bon jour,
ci-joint un addin pour VB6 qui répondra à ta demande :
il est nécessaire de modifier l'ext txt en dll et d'effectuer un regsvr32 pour qu'il soit fonctionnel

[Souleyre]

Cela marche!
Cela faisait des années que j'essayais d'agrandir mes fenêtres.
Un grand merci à toi DarkVader et bravo si tu es l'auteur de la ddl!
Amicalement.

[DarkVader]

Quand on peut rendre service d'autant que c'est moins de 10 lignes de codes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private WithEvents VBPs As VBProjects
 
Private Sub AddinInstance_OnConnection(ByVal Application As Object, ByVal ConnectMode As AddInDesignerObjects.ext_ConnectMode, ByVal AddInInst As Object, custom() As Variant)
    Set VBPs = Application.VBProjects
End Sub
 
Private Sub VBPs_ItemActivated(ByVal VBProject As VBIDE.VBProject)
    Maximise VBProject
End Sub
 
Private Sub VBPs_ItemAdded(ByVal VBProject As VBIDE.VBProject)
    Maximise VBProject
End Sub
 
Sub Maximise(vbp As VBProject)
    Dim vbc As VBComponent, bRet As String
 
    On Error Resume Next
 
    For Each vbc In vbp.VBComponents
        If vbc.HasOpenDesigner Then vbc.DesignerWindow.WindowState = vbext_ws_Maximize
        vbc.CodeModule.CodePane.Window.WindowState = vbext_ws_Maximize
    Next
End Sub

[Souleyre]

...10 lignes de code oui, mais quel code; je serais bien incapable d'en écrire une ligne!
Encore bravo et merci.

[DarkVader]

Pourquoi ! On en reparle dans quelques temps.

[Souleyre]

DarkVader, ta dll fonctionne à merveille mais j'ai un petit effet collatéral que tu vas sûrement me permettre d'éliminer.
Lorsque j'ai plusieurs Forms dans un projet (par exemple toto.frm et toto.bas), d'habitude ledit projet s'ouvrait sur le module principal, ici toto.frm, depuis que j'ai installé ta dll, il s'ouvre sur le toto.bas.
Vois-tu un remède à cette situation?

[DarkVader]

Dans le fichier vbp tu recherches l'entrée Startup
puis dans l'énumération de la collection Components tu sauvegardes une copie du VBcomponent correspondant
et ensuite tu effectues un Setfocus à l'object Window correspondant.

C'est une bonne entrée en matière pour progresser.

Sinon plus simplement,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
        Set vbc = vbp.VBComponents.StartUpObject
        If TypeName(vbc) = "VBComponent" Then  vbc.CodeModule.CodePane.Window.SetFocus

devrait aussi le faire, sinon vbc.CodeModule.CodePane.Window dispose d'une propriété hwnd
(=> BringWindowToTop ?)

[Souleyre]

La ligne StartUp du vbp est correcte.
Après je ne comprends plus tes explications.
Où trouve-t-on l'énumération de la collection Components ?
Excuses-moi d'être aussi Newbee!

[DarkVader]

Le code à ajouter après l'énumération «for each vbc ...» est

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    If TypeName(vbp.VBComponents.StartUpObject) <> "Long" Then
        Set vbc = vbp.VBComponents.StartUpObject
        vbc.CodeModule.CodePane.Window.SetFocus
    End If

[DarkVader]

Pour le fun (mais aussi parce que j'en avais l'utilité), j'ai légèrement amélioré l'addin.

Il ne dispose pas d'interface de gestion des préférences (celles-ci sont directement modifiable depuis la base de registre)
mais permet désormais une gestion multi-écrans de l'ide en mode SDI en fonction du type de module,
ce qui permet d'avoir un environnement standardisé quelquesoit le projet.
Le code sera plus parlant.

Le code -
Designer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
' PROJECT_NAME           : VBIDE_Maximize (Addin pour IDE VB6)                          '
'———————————————————————————————————————————————————————————————————————————————————————'
' < UTILISATION >                                                                       '
'       Modifiez les clés de registre «WSMode/WSDesigners/WSMain» situées dans          '
'       «HKEY_CURRENT_USER\Software\VB and VBA Program Settings\...\Prefers\»           '
'       en fonction du résultat désiré                                                  '
'======================================================================================='
 
    Option Explicit
    '___________________________________________________________________'
 
 
    Private WithEvents VBPs As VBProjects
 
    Private Const Section   As String = "Prefers"
    Private Const key1      As String = "WSMode"            ' WindowState                           '
    Private Const key2      As String = "WSDesigners"
    Private Const key3      As String = "WSMain"
 
    Private Const key4      As String = "ScreenStandart"
    Private Const key5      As String = "ScreenDesigner"
    Private Const key6      As String = "ScreenClass"
 
    ' Valeurs par défaut                    '
    Private Const defkey1   As String = "2"                 '   WindowState: Maximize               '
    Private Const defkey2   As String = "0"                 '   Ne pas appliquer aux designers      '
    Private Const defkey3   As String = "1"                 '   Module principal au 1er plan        '
 
    Private Const defkey4   As String = "3"                 ' Ecran destination pour mod Standart   '
    Private Const defkey5   As String = "2"                 ' Ecran desti. pour designer (0=rien)   '
    Private Const defkey6   As String = "2"                 ' Ecran destination pour mod de classe  '
 
'======================================================================================='
 
 
Private Sub AddinInstance_OnConnection(ByVal Application As Object, ByVal ConnectMode As AddInDesignerObjects.ext_ConnectMode, ByVal AddInInst As Object, custom() As Variant)
    GetMonitorInfos
    Set VBPs = Application.VBProjects
End Sub
 
        Private Sub VBPs_ItemActivated(ByVal VBProject As VBIDE.VBProject):         Maximise VBProject:                                                 End Sub
        Private Sub VBPs_ItemAdded(ByVal VBProject As VBIDE.VBProject):             Maximise VBProject:                                                 End Sub
 
        Private Sub Maximise(vbp As VBProject)
            Dim vbc As Object, pVbc As VBComponent
            Dim ret As String, AppName As String
            Dim S1 As Long, S2 As Boolean, S3 As Boolean, S4 As Long, S5 As Long, S6 As Long
 
            On Error Resume Next
 
            AppName = App.EXEName
            ' Récupérer les préférences                         '
            '---------------------------------------------------'
 
            ' WindowState : 0/Normal, 1/Minimize, 2/Maximize    '
            ret = GetSetting(AppName, Section, key1)
            If ret = "" Or Val(ret) > 2 Or Val(ret) < 0 Then
                S1 = CLng(Val(defkey1))
                SaveSetting AppName, Section, key1, defkey1
            Else
                S1 = CLng(Val(ret))
            End If
 
            ' Seulement les modules de code et ? designers      '
            ret = GetSetting(AppName, Section, key2)
            If ret = "" Then
                S2 = CBool(Val(defkey2))
                SaveSetting AppName, Section, key2, defkey2
            Else
                S2 = CBool(Val(ret))
            End If
 
            ' Code de l'object de démarrage au premier plan     '
            ret = GetSetting(AppName, Section, key3)
            If ret = "" Then
                S3 = CBool(Val(defkey3))
                SaveSetting AppName, Section, key3, defkey3
            Else
                S3 = CBool(Val(ret))
            End If
 
            If VBPs.VBE.DisplayModel = vbext_dm_SDI Then
 
                ' Ecrans de destination                             '
                ret = GetSetting(AppName, Section, key4)
                If ret = "" Then
                    S4 = CLng(Val(defkey4))
                    SaveSetting AppName, Section, key4, defkey4
                Else
                    If CLng(Val(ret)) <= MonitorCount Then S4 = CLng(Val(ret))
                End If
 
                ret = GetSetting(AppName, Section, key5)
                If ret = "" Then
                    S5 = CLng(Val(defkey5))
                    SaveSetting AppName, Section, key5, defkey5
                Else
                    If CLng(Val(ret)) <= MonitorCount Then S5 = CLng(Val(ret))
                End If
 
                ret = GetSetting(AppName, Section, key6)
                If ret = "" Then
                    S6 = CLng(Val(defkey6))
                    SaveSetting AppName, Section, key6, defkey6
                Else
                    If CLng(Val(ret)) <= MonitorCount Then S6 = CLng(Val(ret))
                End If
 
                ' Appliquer les préférences en mode SDI             '
                '---------------------------------------------------'
                For Each vbc In vbp.VBComponents
                    If vbc.Type = vbext_ct_StdModule And S4 > 0 And S4 <= MonitorCount Then
                        vbc.CodeModule.CodePane.Window.Left = Monitors(S4).Left
                        vbc.CodeModule.CodePane.Window.Top = Monitors(S4).Top
 
                    ElseIf vbc.Type = vbext_ct_ClassModule And S6 > 0 And S6 <= MonitorCount Then
                        vbc.CodeModule.CodePane.Window.Left = Monitors(S6).Left
                        vbc.CodeModule.CodePane.Window.Top = Monitors(S6).Top
 
                    ElseIf S5 > 0 And S5 <= MonitorCount Then
                        vbc.CodeModule.CodePane.Window.Left = Monitors(S5).Left
                        vbc.CodeModule.CodePane.Window.Top = Monitors(S5).Top
                    End If
 
                    If vbc.HasOpenDesigner And S2 Then vbc.DesignerWindow.WindowState = S1
                    vbc.CodeModule.CodePane.Window.WindowState = S1
                Next
            End If
 
 
            ' Module principal au premier plan                  '
            '---------------------------------------------------'
            If TypeName(vbp.VBComponents.StartUpObject) <> "Long" And S3 Then
                Set vbc = vbp.VBComponents.StartUpObject
                vbc.CodeModule.CodePane.Window.SetFocus
 
            ElseIf S3 Then
                If vbp.VBComponents.StartUpObject = 0 Then
                    ' rechercher le module contenant la procédure Main
                    For Each pVbc In vbp.VBComponents
                        If pVbc.Type = vbext_ct_StdModule Then
                            If pVbc.CodeModule.ProcBodyLine("Main", vbext_pk_Proc) > 0 Then
                                pVbc.CodeModule.CodePane.Window.SetFocus
                                Exit Sub
                            End If
                        End If
                    Next
                End If
            End If
        End Sub

module.bas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
    Option Explicit
    '___________________________________________________________________'
 
    Private Type Rect
        Left                As Long
        Top                 As Long
        Right               As Long
        Bottom              As Long
    End Type
    Private Declare Function EnumDisplayMonitors Lib "user32.dll" (ByVal hdc As Long, ByRef lprcClip As Any, ByVal lpfnEnum As Long, ByVal dwData As Long) As Long
 
    Public Type POSMON
        Left                As Long
        Top                 As Long
        Width               As Long
        Height              As Long
    End Type
 
    Public Monitors()       As POSMON
    Public MonitorCount     As Long
 
'———————————————————————————————————————————————————————————————————————————————————————'
 
Public Sub GetMonitorInfos()
    MonitorCount = 0
    EnumDisplayMonitors ByVal 0&, ByVal 0&, AddressOf MonitorEnumProc, ByVal 0&
End Sub
        Private Function MonitorEnumProc(ByVal hMonitor As Long, ByVal hdcMonitor As Long, lprcMonitor As Rect, ByVal dwData As Long) As Long
            MonitorCount = MonitorCount + 1
            ReDim Preserve Monitors(1 To MonitorCount)
 
            With lprcMonitor
                Monitors(MonitorCount).Top = .Top
                Monitors(MonitorCount).Left = .Left
                Monitors(MonitorCount).Width = .Right - .Left
                Monitors(MonitorCount).Height = .Bottom - .Top
            End With
 
            MonitorEnumProc = 1
        End Function

Ci-joint l'addin dont l'ext txt est à restaurer en dll etc.

[Souleyre]

Excuses-moi, DarkVader, de ne pas avoir répondu à ton dernier message, mais il m'a laissé dans un tel état de perplexité que je n'ai pas su quoi te dire.
Ta première dll me satisfait pleinement dans le sens qu'elle me permet d'ouvrir mes feuilles en maximisé, je ne suis pas sûr d'utiliser ta deuxième si elle concerne le mode multi-écran en mode SDI qui n'a pas d'intérêt pour moi.
J'ai beaucoup cherché sur le net la signification des codes utilisés dans le .vbw sans aucun résultat (à croire qu'il s'agit d'un secret d'état!). J'ai fini par trouver une astuce qui résout à moitié mon problème: je colle un Z à la fin de la ligne du module que je souhaite voir ouvert en premier (ou plutôt en dernier pour qu'il apparaisse à l'écran) et je sauve mon vbw en lui imposant la propriété "lecture seule". De cette façon la feuille principale est bien affichée, le seul problème restant est qu'elle s'ouvre sur page objet et non sur la page code comme je le souhaiterais.
Voilà, j'en suis là!
Je regrette vraiment que Mr Gates n'ait pas prévu ce type de paramétrage dans son VB6, par ailleurs réellement excellent.
Merci pour les efforts que tu as déployés dans cette affaire.