Discussion :

[id301077]

Bonjour,

Voila tout est dans le titre.
Je voudrais commander le classement des modalités d'une variable dans une table SAS.
Je m'explique :

J'ai une variable: VARA qui a les modalités : A,B,C;D,E,F
J'aimerais les classer dans la table suivant l'ordre suivant : D,C,F,A,E,B.

Merci de votre réponse

[RemiBousquet]

Sur le jeu de données

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
data Unsorted ;              
    VARA = "A" ; output ;
    VARA = "B" ; output ;
    VARA = "C" ; output ;
    VARA = "D" ; output ;
    VARA = "E" ; output ;
    VARA = "F" ; output ;
run ;

Je gère l'ordre voulu via un format (plus facile à maintenir) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
proc format ;
    value $VARA_TRI
        "D" = "1"
        "C" = "2"
        "F" = "3"
        "A" = "4"
        "E" = "5" 
        "B" = "6" ;
run ;

Et voilà une méthode efficace avec SQL :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
PROC SQL;
CREATE TABLE Sorted AS SELECT * FROM Unsorted ORDER BY PUT(VARA, $VARA_TRI.);
RUN; QUIT;

Méthode alternative, moins optimisée, plus "old school", avec étapes data :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
data unsorted_2 ;
    set unsorted ;
    VARA_TRI = PUT(VARA, $VARA_TRI.);
run ; 
proc sort data = unsorted_2 out = Sorted_2 ;
    by VARA_TRI ;
run ;

Have fun

[hossward]

Bonjour,
C'est une proposition à l'aide de Call symputx :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
data test ;
input VARA $ ;
cards ;
C
A
B
D
E
A
E
F
B
D
F
C
; run ;  
 
data _null_ ;
do j='D','C','F','A','E','B' ;
i+1 ;
call symputx(j, i) ;	 
end ;
run ; 	   
 
data test_1 ;
set test ;
Temp=symget(VARA) ;
run ; 	   
proc sort data=test_1 ; by Temp ; run ;

Cordialement
Ward

[s_a_m]

Hello,
Je te rajoute deux exemples :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
data test ;
input VARA $ ;
cards ;
C
A
B
D
E
A
E
F
B
D
F
C
; run ;
 
data test1;
set test (where=(vara='D'))
   test (where=(vara='C'))
   test (where=(vara='F'))
   test (where=(vara='A'))
   test (where=(vara='E'))
   test (where=(vara='B'));
run;

Si t'as plusieurs modalités, je te conseil la Call execute. Elle fait bien le boulot :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
data tab;
input v $;
cards;
D
C
F
A
E
B
;
run;
 
data _null_;
set tab;
call execute ("data _tmp"!! strip(_n_)!!"; set " !! "test (where =(vara= "!! quote(strip(v)) !! " )); "
 
);
run;
 
 
 
data finale ;
set _:;
run;
 
proc datasets lib=work noprint;
delete _:;
run;
quit;

[id301077]

Merci beaucoup pour votre aide.