Discussion :

[sovan]

Rebonjour,


J'aimerais perfectionner mon scripte HTA mais j'ai toujours des erreurs !!
Je voulais créer une bouton de sauvegarde
Qui fait :
- Vérifier si le lecteur p : existe puis afficher le message erreur et annuler opération.
- Vérifier le dossiers Favoris : si c'est un windows 7 le variable est Favorites si c'est un windows xp le variable est favoris.

- Vérifier si le dossiers "%APPDATA%\Mozilla\Firefox\Profiles" existe sinon il fait que la copie de favoris IE.

si je clique sur le bouton sauvegarde et si tout va bien il va sauvegarder les dossiers Favoris IE et Firefox\profils sur un lecteur P :

Je pense que j'ai des erreur avec des if et end if

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
Sub SauvIE
				Dim objFSO, WshShell, SauvRepIE, sUserProfileIE, FavorisIE, Medoc 
				Dim sUserProfileFX, FavorisFX, SauvRepFX
				Dim VfiriIE
				Dim Reponse 
						Set WshShell=CreateObject("WScript.Shell")
						Set objFSO = CreateObject("Scripting.FileSystemObject")
						sUserProfileIE = WshShell.ExpandEnvironmentStrings("%USERPROFILE%")
						sUserProfileFX = WshShell.ExpandEnvironmentStrings("%APPDATA%")
 
			Medoc = "p:"
		If objFSO.FolderExists(Medoc) Then  ' Il doit arrêter opération et afficher le message ci-dessus'
				FavorisFX = sUserProfileFX & "\Mozilla\Firefox\Profiles" ' lien profile Frefox '
				SauvRepFX = "p:\Favorisfirefox" 'lien sauvegarde ' 
				SauvRepIE = "p:\Favoris" 'lien sauvegarde ' 
				FavorisIE = sUserProfileIE & "\Favorites"   ' lien profile favoris windows 7
						If not objFSO.FolderExists(FavorisIE) Then  
						FavorisIE = sUserProfileIE & "\Favoris"  ' lien profile favoris windows XP
						else 
						 FavorisIE = FavorisIE ' lien profile favoris windows 7
						End if 
 
					if objFSO.FolderExists(FavorisFX) Then 
								MsgBox "Attention fermeture de la fenêtre Firefox",vbExclamation,"Attention"
								If Not objFSO.FolderExists(SauvRepFX) Then Set objFolder = objFSO.CreateFolder(SauvRepFX)
								objFSO.CopyFolder FavorisFX , SauvRepFX, True
 
								If Not objFSO.FolderExists(SauvRepIE) Then Set objFolder = objFSO.CreateFolder(SauvRepIE)
								objFSO.CopyFolder FavorisIE , SauvRepIE, True
								'il copie les deux favoris  IE et firefox  puis affichier le message ci-dessous'		
								MsgBox "Operation de sauvegarde s'est terminée avec succès",vbInformation,"Information"
 
					Else 
					If Not objFSO.FolderExists(FavorisFX) Then 
								If Not objFSO.FolderExists(SauvRepIE) Then Set objFolder = objFSO.CreateFolder(SauvRepIE)
								objFSO.CopyFolder FavorisIE , SauvRepIE, True
								MsgBox "Operation de sauvegarde s'est terminée avec succès",vbInformation,"Information"
 
								' si le dossiers Firefox n'existe pas, il va copier seulement les favoris IE '
					end if
		else
				MsgBox "Erreur ! vous n'avez pas de dossier Mes documents, merci de contactez le service Securité logic",vbInformation,"Information"
		End IF
End Sub

J'ai le probleme ligne 42

Code HTA le bouton

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<input id=runbutton type="button" value="Sauvegarder Favoris Internet explorer" onClick="SauvIE()" STYLE="font:10 pt arial">

Je vous remercie d'avance !!!

[Cachlab]

Salut Sovan !

Voici quelques petits propositions (à intégrer - ou pas - dans ton code) :
. Utilisation de tableaux
. Arrêt des process IE et Firefox
. Traitement en boucle (tests, création répertoires et copie)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Sub SauvIE
	Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject")
	Dim objShell : Set objShell = CreateObject("WScript.Shell")
	Dim objWMIService, objFolder, LectSauv, sUserProfile, sUserAppData, strComputer
	Dim SauvRep(2), DestRep(2)
 
' Destination de la sauvegarde
LectSauv = "P:"
RepSauv = LectSauv & "\Sauvegarde"
 
'Test du lecteur réseau (ici P:) et arrêt du script si inexistant
If Not objFSO.DriveExists(LectSauv) Then MsgBox "Erreur ...", vbInformation, "Information" : WScript.Quit
'Test du répertoire principal de sauvegarde et création si besoin (ici P:\Sauvegarde)
If Not objFSO.FolderExists(RepSauv) Then objFolder = objFSO.CreateFolder(RepSauv)
 
'Recherche et kill des process IE et Firefox
strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
 
Set colProcessList = objWMIService.ExecQuery ("Select * from Win32_Process Where Name = 'iexplore.exe' OR Name = 'firefox.exe'")
For Each objProcess in colProcessList
objProcess.Terminate()
Next
 
'Définition des répertoires locaux (nom court) à rechercher
SauvRep(0) = "\Favoris"
SauvRep(1) = "\Favorites"
SauvRep(2) = "\Profiles"
 
'Création des noms des répertoires de sauvegarde (ex. P:\Sauvegarde\Favoris)
For i = 0 to 2
DestRep(i) = RepSauv & SauvRep(i)
Next
 
'Redéfinition des répertoires locaux (nom complets) à rechercher
sUserProfile = objShell.ExpandEnvironmentStrings("%USERPROFILE%")
sUserAppData = objShell.ExpandEnvironmentStrings("%APPDATA%")
 
SauvRep(0) = sUserProfile & SauvRep(0)
SauvRep(1) = sUserProfile & SauvRep(1)
SauvRep(2) = sUserAppData & "\Mozilla\Firefox" & SauvRep(2)
 
'Boucle de traitement
For i = 0 to 2
if objFSO.FolderExists(SauvRep(i)) Then 'Si le répertoire local existe
	if Not objFSO.FolderExists(DestRep(i)) Then objFolder = objFSO.CreateFolder(DestRep(i)) 'Si le répertoire destination n'existe pas, on le crée
	objFSO.CopyFolder SauvRep(i) , DestRep(i), True ' et on lance la copie
end if
Next
 
MsgBox "Opération terminée !"
End Sub

Continue comme ça, t'es sur la bonne voie !

[sovan]

Ca marche à la perfection !
Merci bien Cachlab, c'est super Sympa !!

Je vais essayer de ne plus m’embrouiller avec des IF et and if !
C'est plus simple avec ton code !!

Encore MERCI