Discussion :

[Frédodido94520]

Bonjour à tous et à toutes,

J'aurai besoin, dans le cadre de la réalisation d'une application de gestion locative, de récupérer la dernière valeur connu de l'indice de référence des loyers de l'INSEE de façon automatique, en VB6.

Merci d'avance pour votre aide précieuse.

[l_autodidacte]

Salut et bienvenu sur DVP

Ton message n'est très éloquent et manque de précisions.
Je doute que quiconque puisse le comprendre pour pouvoir te répondre.

[Frédodido94520]

Bonjour, et merci de ton message, je vais essayer de préciser un peu...

Je sais trouver, sur le Net, l'indice de révision des loyers fourni chaque trimestre par l'INSEE, j'ai besoin, pour le calcul annuel de révision des loyers dans mon application, de cet indice afin d'indexer le loyer.

Le problème est que je ne veux pas que l'utilisateur soit obligé de faire cette recherche et de renseigner ce paramètre.

Je voudrai donc une fonction, ou je ne sais quoi d'autre, qui soit capable d'aller récupérer cet indice (je ne sais pas trop comment car je ne developpe que depuis peu de temps) sur le net, et que je puisse enregistrer cet indice dans ma base pour effectuer mes calculs...

Voilà, j'espère avoir été un peu plus clair et et que mon problème succitera de l’intérêt pour beaucoup d'entre vous...

Merci d'avance.

[DanielB]

Est-ce aussi compliqué que cela d'entrer l'indice manuellement une fois et qu'il serve à tous les utilisateurs ?

[Frédodido94520]

Cet indice change chaque trimestre, et une fois que mon application sera dans les mains des utilisateurs, je ne pourrai plus intervenir, c'est pour cela qu'il faudrait que l'indice se mette à jour automatiquement...

En fait, le logiciel vérifie à l'ouverture si un (ou plusieurs) des contrat de bail est arrivé à sa date anniversaire, si c'est le cas, il propose à l'utilisateur de modifier le loyer et d'en informer le locataire par mail (pour mise à jour de son virement). Toute cette procédure se fait automatiquement, à condition de connaitre la dernière valeur de l'indice de révision des loyers.

J'ai donc 2 solutions, soit je télécharge cet indice automatiquement (d’où ma question sur ce post), soit je demande à l'utilisateur d'en entrer la valeur, mais si c'est l'utilisateur qui le rentre, cela ajoute un risque d'erreur que je préférerai éviter.

Merci d'avance!

[ProgElecT]

Salut

.....
Je sais trouver, sur le Net, l'indice de révision des loyers fourni chaque trimestre par l'INSEE
.....
Merci d'avance.

Pourrais tu nous donner l'adresse URL de la page ou tu sais faire cela.
J'ai fais cette recherche et je suis tombé sur des sites et des pages ou différents indices sont exposés, mais apparemment cela reste bien aléatoire pour le récupérer automatiquement, possible oui, mais pour quelle durée .
Un risque subsistera car l'architecture des pages sur internet changent souvent, donc le code faisant l'opération automatiquement serra forcément fragile dans le temps.

[Frédodido94520]

Bonjour progelect,

Merci beaucoup pour ton aide, voici le lien ou je récupère l'indice :

http://www.insee.fr/fr/themes/conjon...dice_loyer.asp

Ou encore dans les bases de données de l'INSEE ou on peut téléchargé l'historique des indices au format Excel ou CSV :

http://www.insee.fr/fr/bases-de-donn...bank=001515333

Merci beaucoup et bonne journée.

[ProgElecT]

Salut

Le code qui fonctionne mais qui risque de ne pas être bien stable dans le temps et surement pas des plus propre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
Option Explicit
Dim ValeurIndice As String
 
'--------------------------------------------- Gestion/manipulation de page internet ---------------------------------
Public Function IeAtt(IeApp As Object, Optional ByVal TempoReadyComplet As Double = 10.5) As Boolean
'Attente d'un chargement complet suite à l'appel d'une page internet
'IeApp: Objet de type InternetExplorer
'TempoReadyComplet: temporisation au delà du quel il est considérée que la connexion à échouée
Dim TpFin As Double
IeAtt = True
    TpFin = Timer + TempoReadyComplet
    Do While IeApp.readyState <> READYSTATE_COMPLETE
        DoEvents
        If Timer > TpFin Then IeAtt = False: Exit Do
    Loop
End Function
Public Function IeDocAtt(IeApp As Object, Optional ByVal TempoDocLoading As Double = 0.25, Optional ByVal TempoDocComplet As Double = 0.5) As Boolean
'Attente du document suite a une action qui recharge une page internet
'TempoDocLoading: tempo au delà du quel il est considérée que le loading est déjà dépassé
'TempoDocComplet: tempo au delà du quel il est considérée que le document n'est pas récupérable
Dim TpFin As Double
IeDocAtt = True
    TpFin = Timer + TempoDocLoading
    Do While IeApp.document.readyState <> "loading"
        DoEvents
        If Timer > TpFin Then IeDocAtt = False: Exit Do
    Loop
    TpFin = Timer + TempoDocComplet
    Do While IeApp.document.readyState <> "complete"
        DoEvents
        If Timer > TpFin Then IeDocAtt = False: Exit Do
    Loop
If IeApp.document.readyState = "complete" Then IeDocAtt = True
End Function
Public Function IeAttUrl(IeApp As Object, AdrsUrlAttendue As String, Optional ByVal TempoComplet As Double = 2.5) As Boolean
'Attente d'une page internet avec verification du bon branchement à une adresse précisée par AdrsUrlAttendue
Dim TpFin As Double
IeAttUrl = True
    TpFin = Timer + TempoComplet
    Do While IeApp.LocationURL <> AdrsUrlAttendue
        DoEvents
        If Timer > TpFin Then IeAttUrl = False: Exit Do
    Loop
End Function
 
Private Sub Form_Load()
Dim IE As InternetExplorer
Dim IEDoc As HTMLDocument
Dim DocTbl As HTMLTable
Dim TblCollectionLgn As HTMLTableCell
Dim AdrssUrl As String
 
Set IE = New InternetExplorer
 
AdrssUrl = "http://www.insee.fr/fr/bases-de-donnees/bsweb/serie.asp?idbank=001515333"
IE.navigate AdrssUrl
If IeAtt(IE, 5.5) = False Then
    MsgBox "Cela ne fonctionne pas", vbCritical, "Zut"
    Set IE = Nothing
    Exit Sub
End If
 
If IeAttUrl(IE, AdrssUrl, 2.2) = False Then
    MsgBox "vous avez été redirigé sur une autre page" & vbNewLine _
    & "Le titre de la page affichée est:" & vbNewLine _
    & IE.document.Title, vbCritical, "Pour info"
    IE.Quit
    Set IE = Nothing
End If
 
Set IEDoc = IE.document
 
If IEDoc.Title = "HTTP 500 Erreur interne au serveur" Then
    MsgBox "Le document attendue n'est pas present" & vbNewLine _
    & "Le titre du document est:" & vbNewLine _
    & IEDoc.Title, vbCritical, "Pour info"
    Set IEDoc = Nothing
    IE.Quit
    Set IE = Nothing
End If
'Là on est bien sur la bonne page
'IE.Visible = True
Set DocTbl = IEDoc.All("contenu")
Set TblCollectionLgn = DocTbl.children(5)
Set TblCollectionLgn = TblCollectionLgn.children(1)
Set TblCollectionLgn = TblCollectionLgn.children(1)
Set TblCollectionLgn = TblCollectionLgn.children(2)
ValeurIndice = TblCollectionLgn.innerText
 
Set TblCollectionLgn = Nothing
Set DocTbl = Nothing
Set IEDoc = Nothing
 
IE.Quit
Set IE = Nothing
 
MsgBox "Indice de référence des loyers de l'INSEE : " & ValeurIndice
End Sub

Pour apprendre à manipuler des informations d'une page internet, j'ai appris beaucoup en lisant de multiples fois ce tutoriel Interaction avec Internet Explorer via VBA Excel