Sauvegarder valeurs d'une Listview dans My.Settings

Version imprimable

Voir 40 message(s) de cette discussion en une page

28/07/2010, 13h14
methylene

Je te cite :

Citation:

Mon problème est que je ne sais pas du tout comment nommer tous ce qui est écrit dans celle-ci sachant que la liste des éléments est modifiable.

De quoi parles-tu précisément ? Si tu ne parles uniquement des "valeurs" de ta listview pas de problème.

Ensuite ta listview est composée de 4 colonnes, mais de combien de lignes (le nombre de colonnes / lignes est bien fixé ?) ?
30/07/2010, 22h09
aus3004
Dans un de mes projets j'utilise
Code:

1 2 3 For Each Item As String In ListBox2.Items mail.To.Add(New Net.Mail.MailAddress(Item)) Next
Pour envoyer le contenu d'une listeview par mail.

Il n'y aurait-il pas un moyen semblable pour enregistrer le contenu dans My.settings ?

Bonne prog

Citation:
Envoyé par aus3004
Code:

1 2 3 For Each Item As String In ListBox2.Items mail.To.Add(New Net.Mail.MailAddress(Item)) Next
Vous comprenez quoi dans ces 3 lignes ?

31/07/2010, 00h13
aus3004

1 pièce(s) jointe(s)

@methylene, désolé de ne pas t'avoir répondu avant car je n'avais pas remarqué la seconde page et je croyais que vous m'aviez oublié.

Pour répondre à ta question, les 4 colonnes sont générées par le code que j'ai posté et les lignes varient celon les valeurs.

Comment marche mon prog ?
Je rentre une valeur dans 4 textboxs puis je clique sur un bouton et les 4 valeurs apparaissent dans la listview. En gros la listview "marche par ligne" car il faut que je remplisse les 4 textboxs pour valider (je précise ca au cas ou l'enregistrement dans my.settings changerait).

Ce que je cherche c'est de pouvoir sauvegarder ces "lignes" donc enregistrer individuellement chaque item dans my.settings car je crois que c'est la seule solution.

L'exemple avec les mails que je viens de poster montre que c'est possible d'appeler toutes les items d'une listview par un nom et peut être envisager de tout enregistrer dans my.settings d'un coup.

Vala

Salut

Tu n'arrives peut être pas à voir comment tu peux transformer ton tableau (colonnes et lignes) de ton listview en une seule valeur que tu pourras sauvegarder dans My.Settings

Une des solutions pourrait consister à construire une seule grosse String avec l'ensemble des données de ton tableau et enregistrer ensuite cette String dans My.Settings

Pour l'enregistrement dans My.Settings tu as donc d'abord une partie du code qui construit la chaîne et ensuite l'instruction qui enregistre dans My.Settings :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
        'Déclare la chaîne temporaire qui servira à enregistrer le contenu du tableau
        Dim tmpContenu As String = ""
 
        'On va maintenant construire la même chose qu'un fichier .csv :
        '   - Chaque ligne est séparée par le caractère VbLf
        '   -Les données de chaque ligne sont séparées par le caractère ";"
 
        'Prend chacune des lignes de la ListView
        For Each I As ListViewItem In ListView1.Items
 
            'Prend chaque sous-élément de l'item actuel
            For Each SI As ListViewItem.ListViewSubItem In I.SubItems
 
                'Ajoute la valeur du subitem à la string représentant le tableau (avec le ";" pour séparer les valeurs)
                tmpContenu = tmpContenu & SI.Text & ";"
 
            Next
 
            'Ajoute le caractère VbLf à la string représentant le tableau
            tmpContenu = tmpContenu & vbLf
 
        Next
 
        'Retire de la chaîne de la String le ";" excédentaire de chaque ligne
        tmpContenu = tmpContenu.Replace(";" & vbLf, vbLf)
 
        'Enregistre maintenant cette String dans tes settings
        My.Settings("Passwords") = tmpContenu

Pour faire la procédure inverse, on se tape le boulot dans l'autre sens : on récupère l'info de My.Settings et on l'interprète pour construire le ListView :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
        Dim tmpContenu As String
        Dim Lignes As String()
        Dim Cells As String()
        Dim incr As Integer
        Dim Items As ListViewItem()
 
        'Récupère le tableau dans les settings
        tmpContenu = My.Settings("Passwords")
 
        'Divise la String en autant de lignes qu'il y en a (séparées par les VbLf)
        'Attention , comme dans la construction le dernier caractère est VbLf on va se retrouver avec une ligne en trop dont il ne faudra pas tenir compte
        Lignes = Split(tmpContenu, vbLf)
 
        'Indique le nombre d'items que l'on va ajouter à la ListView
        ReDim Items(Lignes.GetUpperBound(0) - 1) '-1 car il y a une ligne vide en trop dans le fichier
 
        'Ajoute chaque ligne dans le tableau de données
        For incr = 0 To Lignes.GetUpperBound(0) - 1
 
            'Divise la ligne en autant de données qu'elle en contient (séparées par des ";")
            Cells = Split(Lignes(incr), ";")
 
            'Ajoute la ligne à la liste des lignes à ajouter
            Items(incr) = New ListViewItem(Cells)
 
        Next
 
        'Ajoute l'ensemble des lignes à la ListView
        ListView1.Items.AddRange(Items)

Vu que tu as une chaîne de caractères, ensuite libre à toi de la crypter avant de l'enregistrer dans les settings et de la décrypter ensuite au moment où tu la récupère.
En tout cas tu as là une des méthodes permettant d'enregistrer dans une seule variable l'ensemble d'un tableau

En espérant que ça réponde à ta demande

01/08/2010, 08h40
aus3004

@mrtrampo merci pour ton code commenté, ca marche très très bien :D

Tu me sauve la vie, a+ et bonne prog :ccool:

Encore moi :)

J'avoue que vous m'avez très bien aidé pour l'enregistrement dans my.settings de la listview mais j'ai maintenant besoin de faire pareil avec une listbox. Dans Google il y a autant de réponse que pour la listview (0) donc je donne suite à notre discussion.

Pour cela j'ai essayé d'adapter le code de la listview et ca m'a donné :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 
            Dim tmpContenu As String
            Dim Lignes As String()
            Dim Cells As String()
            Dim incr As Integer
            Dim Items As ListBox.ObjectCollection()
 
            'Récupère le tableau dans les settings
            tmpContenu = My.Settings("Tableau")
 
            'Divise la String en autant de lignes qu'il y en a (séparées par les VbLf)
            'Attention , comme dans la construction le dernier caractère est VbLf on va se retrouver avec une ligne en trop dont il ne faudra pas tenir compte
 
            Lignes = Split(tmpContenu, vbLf)
            'Indique le nombre d'items que l'on va ajouter à la ListBox
 
            ReDim Items(Lignes.GetUpperBound(0) - 1) '-1 car il y a une ligne vide en trop dans le fichier
            'Ajoute chaque ligne dans le tableau de données
 
            For incr = 0 To Lignes.GetUpperBound(0) - 1
                'Divise la ligne en autant de données qu'elle en contient (séparées par des ";")
 
                Cells = Split(Lignes(incr), ";")
                'Ajoute la ligne à la liste des lignes à ajouter
                Items(incr) = New ListBox(Cells)
            Next
            'Ajoute l'ensemble des lignes à la ListBox
            ListBox3.Items.AddRange(Items)
 
    End Sub

Avec un form_closing également adapté, cela ne marche pas, pouvez-vous me dire si le form1_load ne comporte pas d'erreur pour ensuite que je puisse centraliser mon attention sur la sub qui pose problème ?
Pensez-vous que la conversion du code listview/listbox est faisable ?
Faut-il un autre code qui n'a rien à voire ?

Merci pour votre assistance et bonnes vacances.

et bon dev

PS : Mon accès à internet est limité en ce moment, mes réponses peuvent être lentes, désolé.

Voir 40 message(s) de cette discussion en une page