Propriété fichiers MP3 par VBA Excel

Version imprimable

13/01/2008, 23h13
AIFOL

Propriété fichiers MP3 par VBA Excel

Bonjour, je démarre sur ce forum, mais je programme (en amateur) sur VBA pour Excel depuis 10ans.
Je voudrais comparer mes fichiers MP3, supprimer des doublons et complèter les infos TAG ( artiste, titre, numéro de piste, année... ) ou récupérer les infos d'un CD MP3 pour en faire la jaquette sous Excel, j'ai réussi en partie mais il me manque la durée des morceaux, pouvez-vous m'aider?
14/01/2008, 14h29
Dolphy35

Bonjour et bienvenue sur le Forum,

je pense que cela devrait t'intérrésser :

:fleche: Utiliser Windows Media Player en VB et VBA

Dolphy ;)
17/01/2008, 00h36
AIFOL

Merci Dolphy,

j'étais déjà passé sur cette rubrique mais si j'ai bien compris il faut lancer WMP, démarrer une séquence pour obtenir les infos sur celle-ci, j'aimerai plutôt accéder directement aux infos telles qu'on les lits dans l'explorateur...

J'ai déjà utilisé ce type de fonction : Function SHGetPathFromIDList Lib "shell32.dll" et Function SHBrowseForFolder Lib "shell32.dll" et récupérer ces fonctions:
- FileDateTime
- FileLen

mais apparement c'est tout ce qu'on peut en tirer.
Si vous avez d'autres infos???

bonjour

Il est possible d'accéder à l'ensemble des propriétés avancées (onglet Résumé) en utilisant la bibliothèque "Microsoft Shell Controls and Automation".

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub Test()
    Dim sFich As String
 
    sFich = "C:\Documents and Settings\mimi\dossier\mamusique.mp3"
    ListeProprietesFichier_getDetailsOf sFich
 
End Sub
 
 
 
Sub ListeProprietesFichier_getDetailsOf(Fichier As String)
    'source:
    'http://www.microsoft.com/resources/documentation/windows/2000/server/
    'scriptguide/en-us/sas_fil_lunl.mspx
    '
    'Nécessite d'activer la référence Microsoft Shell Controls and Automation
    '
    Dim Fso As Object, oFichier As Object
    Dim objShell As Shell32.Shell
    Dim objFolder As Shell32.Folder
    Dim strFileName As Shell32.FolderItem
    Dim Chemin As String, NomFich As String, Resultat As String
    Dim i As Byte
 
    '-----
    Set Fso = CreateObject("Scripting.FileSystemObject")
    Set oFichier = Fso.GetFile(Fichier)
    Chemin = Fso.GetParentFolderName(oFichier)
    NomFich = Fso.GetFileName(oFichier)
    '-----
 
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.Namespace(Chemin)
    Set strFileName = objFolder.Items.Item(NomFich)
 
    For i = 0 To 34
        'Cet exemple n'affiche pas les propriétés vides
        If objFolder.GetDetailsOf(strFileName, i) <> "" Then _
        Resultat = Resultat & objFolder.GetDetailsOf(objFolder.Items, i) _
        & ":  " & objFolder.GetDetailsOf(strFileName, i) & vbLf
    Next
 
    MsgBox Resultat
End Sub

IV-C. Lister les propriétés avancées

bonne journée
michel

20/01/2008, 22h46
AIFOL

Excellent!!!, je vous remercie.
A bientôt, j'ai d'autres sujets interressants en attente.