[VBA-E] Encore un problème avec les limites de RANGE

Version imprimable

01/07/2007, 19h12
durdesfois

[VBA-E] Encore un problème avec les limites de RANGE

Bonjour à tous,

Je suis sûr que c'est encore ouskel'nor ou starec qui va me répondre.....

Je ne veux pas ressasser les vieux problèmes..... mais...

Alors, voilà:

J'ai des zones (Range) sur une seule colonne (Cx) qui démarrent à la colonne L1 et qui finissent à la ligne L2

Je voudrais avoir la première ligne renseignée , et la dernière ligne renseignée (Attention: Dans la zone définie ci-dessus)

J'ai ratissé les contributions,la FAQ,etc...

Si il y a une solution, j'aimerais bien la connaître.

Evidemment, je le fais actuellement en bouclant sur lignes et colonnes: ça marche mais ... ça coûte cher en temps d'éxécution.

Merci

Daniel

Bonsoir,

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Sub PremiereDerniere()
    Dim Premiere As Range, Derniere As Range
    With Range("MaZone") 'Plage à définir
        Select Case WorksheetFunction.CountA(.Cells)
            Case 0
                MsgBox "Aucune donnée dans la zone: MaZone"
            Case 1
                If Intersect(.Cells, .Cells(1).End(xlDown)) Is Nothing Then
                    Set Premiere = .Cells(1)
                Else
                    Set Premiere = .Cells(1).End(xlDown)
                End If
                Set Derniere = Premiere
                MsgBox Premiere.Address & " " & Derniere.Address
            Case Else
                If .Cells(1).Value <> "" Then
                    Set Premiere = .Cells(1)
                Else
                    Set Premiere = .Cells(1).End(xlDown)
                End If
                If .Cells(.Cells.Count).Value <> "" Then
                    Set Derniere = .Cells(.Cells.Count)
                Else
                    Set Derniere = .Cells(.Cells.Count).End(xlUp)
                End If
                MsgBox Premiere.Address & " " & Derniere.Address
        End Select
    End With
End Sub

Sous réserve d'avoir bien compris ce que tu veux, je crois que c'est complet.

Cordialement,

Tirex28/

02/07/2007, 19h56
durdesfois

Merci beaucoup,

Ca fonctionne très bien.

Je devais avoir la tête ailleurs, car je connais pourtant ces propriétés.

Bonne Soirée.