Mise à jour Windows Defender en VBScript

Version imprimable

Bonjour à vous,

je met a jour windows defender avec un script mais bloc sur un sujet.

Actuellement, j'ouvre le navigateur pour la mise à jour et télécharge celle-ci.

Et il possible de ne pas ouvrir le navigateur pour réaliser le téléchargement de la mise à jour.

ci-joint mon script.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
'Definition des variables d'environnement
Set ws = CreateObject("Wscript.Shell")
Set objShell = CreateObject("Shell.Application")
 
'********** Télécharge les mises à jour de Windows Défender **********
Call objShell.ShellExecute("C:\Program Files\Mozilla Firefox\firefox.exe", "-private-window https://go.microsoft.com/fwlink/?LinkID=187316&arch=x64&nri -p Bruno", "", "open", 0)
Call objShell.ShellExecute("C:\Program Files\Mozilla Firefox\firefox.exe", "-private-window https://go.microsoft.com/fwlink/?LinkID=121721&arch=x64 -p Bruno", "", "open", 0)
WScript.Sleep 8000
ws.SendKeys "^{F4}"
ws.SendKeys "^{F4}"
 
'********** Installe les mises à jour **********
WScript.Sleep 2000
Call objShell.ShellExecute("G:\nis_full.exe", "", "", "runas", 0)
Call objShell.ShellExecute("G:\mpam-fe.exe", "", "", "runas", 0)
 
'Quitte le script
WScript.Quit

Par avance Merci.

20/03/2024, 19h28
umfred

voir avec l'option -headless, mais le processus restera actif en arrière plan (visible dans l'onglet détails du gestionnaire des tâches)

Une autre solution serait de passer par curl, en lui donnant un nom (et emplacement) de fichier de sortie

Code:

curl -o dl.exe -L "https://go.microsoft.com/fwlink/?LinkID=187316&arch=x64&nri"
20/03/2024, 19h35
BBlacolombe14

Bonjour umfred,

Merci de ton retour,

-headless ne fonctionne pas chez moi.

je ne connais pas curl, j’e regarde cela et te tien informé du résultat.

Bien à toi

:salut:
Ce Vbscript utilise PowerShell pour télécharger les fichiers directement depuis les URLs spécifiées, sans ouvrir de navigateur.
Vous devez vous assurer que PowerShell est installé sur votre système pour que ce script fonctionne.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
'Définition des variables d'environnement
Set ws = CreateObject("Wscript.Shell")
Set objShell = CreateObject("Shell.Application")
 
'********** Télécharge les mises à jour de Windows Défender **********
' Télécharge la mise à jour des définitions de virus
Call objShell.ShellExecute("cmd.exe", "/c powershell -command ""Invoke-WebRequest -Uri 'https://go.microsoft.com/fwlink/?LinkID=121721&arch=x64' -OutFile 'G:\mpam-fe.exe'""", "", "open", 0)
' Télécharge la mise à jour complète de Windows Defender
Call objShell.ShellExecute("cmd.exe", "/c powershell -command ""Invoke-WebRequest -Uri 'https://go.microsoft.com/fwlink/?LinkID=187316&arch=x64&nri' -OutFile 'G:\nis_full.exe'""", "", "open", 0)
 
'********** Installe les mises à jour **********
WScript.Sleep 2000
Call objShell.ShellExecute("G:\nis_full.exe", "", "", "runas", 0)
Call objShell.ShellExecute("G:\mpam-fe.exe", "", "", "runas", 0)
 
'Quitte le script
WScript.Quit

:king:

20/03/2024, 22h26
BBlacolombe14

1 pièce(s) jointe(s)

Bonsoir hackoofr,

Merci de votre retour, avec le script rien ne se passe.

Sous Powershell j’obtiens ceci :

Pièce jointe 652400

Bien à vous,

:salut:
Vous pouvez utiliser l'objet MSXML2.ServerXMLHTTP pour envoyer des requêtes HTTP GET aux URLs spécifiées et récupérer les réponses.
Ensuite, il enregistre les réponses dans les fichiers spécifiés localement sur votre système.
Assurez-vous de disposer des autorisations nécessaires pour enregistrer des fichiers sur l'emplacement spécifié (par exemple, "G:").

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
'Définition des variables d'environnement
Set ws = CreateObject("Wscript.Shell")
Set objShell = CreateObject("Shell.Application")
Set http = CreateObject("MSXML2.ServerXMLHTTP")
 
' Fonction pour télécharger un fichier depuis une URL et l'enregistrer localement
Function Download(URL, SaveFile)
    On Error Resume Next
    http.Open "GET", URL, False
    http.Send
    If Err.Number <> 0 Then
        Download = False
        Exit Function
    End If
    If http.Status = 200 Then
        Set stream = CreateObject("ADODB.Stream")
        stream.Open
        stream.Type = 1 ' binaire
        stream.Write http.ResponseBody
        stream.SaveToFile SaveFile, 2 ' overwrite
        stream.Close
        Download = True
    Else
        Download = False
    End If
End Function
 
'********** Télécharge les mises à jour de Windows Défender **********
' Télécharge la mise à jour des définitions de virus
If Download("https://go.microsoft.com/fwlink/?LinkID=121721&arch=x64", "G:\mpam-fe.exe") Then
    WScript.Echo "Téléchargement de la mise à jour des définitions de virus réussi."
Else
    WScript.Echo "Échec du téléchargement de la mise à jour des définitions de virus."
End If
 
' Télécharge la mise à jour complète de Windows Defender
If Download("https://go.microsoft.com/fwlink/?LinkID=187316&arch=x64&nri", "G:\nis_full.exe") Then
    WScript.Echo "Téléchargement de la mise à jour complète de Windows Defender réussi."
Else
    WScript.Echo "Échec du téléchargement de la mise à jour complète de Windows Defender."
End If
 
'********** Installe les mises à jour **********
Call objShell.ShellExecute("G:\nis_full.exe", "", "", "runas", 0)
Call objShell.ShellExecute("G:\mpam-fe.exe", "", "", "runas", 0)
 
'Quitte le script
WScript.Quit

:king:

21/03/2024, 12h40
BBlacolombe14

Bonjour hackoofr,

Merci de votre retour,

Cette solution fonctionne parfaitement et correspond entièrement à ce que je chercher.

Merci beaucoup.

Bien à vous,