[Batch] convert txt to ASCII art

convert txt to ASCII art

Bonjour,

je viens convertir le texte : Information... en ASCII Art mais j'arrive a afficher dans le fichier batch.
le lien text to ascii : http://patorjk.com/software/taag/#p=...on...%0A%0A%0A

le code :
Code:

1 2 3 4 5 6 7 8 9 10 11 @echo off echo. echo _____ __ _ _ echo|_ _| / _| | | (_) echo | | _ __ | |_ ___ _ __ _ __ ___ __ _ | |_ _ ___ _ __ echo | | | '_ \ | _|/ _ \ | '__|| '_ ` _ \ / _` || __|| | / _ \ | '_ \ echo | |_ | | | || | | (_) || | | | | | | || (_| || |_ | || (_) || | | | _ _ _ echo|_____||_| |_||_| \___/ |_| |_| |_| |_| \__,_| \__||_| \___/ |_| |_|(_)(_)(_) echo. echo. pause
mais j'ai une erreur qui afficher pour afficher ascii art :

Citation:

_____ __ _ _
| était inattendu.

est-il moyen de convertir ascii art en batch? merci d'avance
exemple :
Code:

1 2 for /f "delims=" %%i in (Figlet.txt) do echo %%i....etc

https://www.developpez.net/forums/d2...eres-speciaux/

Bonjour ericlm128,

merci pour cette explication mais j'ai modifier le code mais j'arrive pas a à l'afficher dans echo et dans le txt.
voici le code :
Code:

1 2 3 4 5 6 7 8 9 @echo off color 0A for /f "tokens=* delims=*" %%a in (Figlet.txt) do ( set line=%%a set line=!line:^|=^^^|! echo !line! echo echo !line! >> "code.txt" ) pause
l'erreur :

Citation:

!line!
!line!
!line!
!line!
!line!
!line!
!line!
!line!...etc

Comment puis je faire pour corriger cela? merci d'avance

Je comprend que finalement ton ASCII art sera dans un fichier texte à part.

Figlet.txt
Code:

1 2 3 4 5 6 _____ __ _ _ |_ _| / _| | | (_) | | _ __ | |_ ___ _ __ _ __ ___ __ _ | |_ _ ___ _ __ | | | '_ \ | _|/ _ \ | '__|| '_ ` _ \ / _` || __|| | / _ \ | '_ \ | |_ | | | || | | (_) || | | | | | | || (_| || |_ | || (_) || | | | _ _ _ |_____||_| |_||_| \___/ |_| |_| |_| |_| \__,_| \__||_| \___/ |_| |_|(_)(_)(_)
1)

Code:

type Figlet.txt

2)
Si tu préfère boucler pour une raison inconnu, ceci fonctionne aussi
Code:

1 2 3 4 5 6 @echo off color 0A for /f "delims=" %%a in (Figlet.txt) do echo %%a pause
3)
Pour utiliser ! au lieu de % (dans les blocs par exemple) tu dois activer l'expansion des variables d'environnement avant avec ceci SETLOCAL ENABLEDELAYEDEXPANSION

4)
Je viens peut être de comprendre ce que tu souhaite faire :D

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
@echo off
color 0A
SETLOCAL ENABLEDELAYEDEXPANSION
 
del "%~dpn0_2.bat" 2> nul
for /f "delims=" %%a in (%~dp0Figlet.txt) do (
	set "var=%%~a"
	echo echo !var:^|=^^^|!
)>>"%~dpn0_2.bat"
 
call %~dpn0_2.bat
 
pause

:salut:
Il faut ajouter

Code:

SetLocal EnableDelayedExpansion

en début du script pour activer l'expansion retardée.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
@echo off
SetLocal EnabledelayedExpansion
color 0A
echo @echo off>"Ascii_Art_Gen.bat"
@for /f "tokens=* delims=*" %%a in (Figlet.txt) do (
    set line=%%a
    set line=!line:^|=^^^|!
    set line=!line:^)=^^^)!
    set line=!line:^>=^^^>!
    set line=!line:^<=^^^<!
    echo. !line!
    echo echo. !line! >> "Ascii_Art_Gen.bat"
)
pause
echo pause>>"Ascii_Art_Gen.bat"
Start "" "Ascii_Art_Gen.bat"

Effectivement il y a d'autres caractères spéciaux

Figlet

Code:

1
2
3
4
5
6
7
 _____          __                                _    _                        
|_   _|        / _|                              | |  (_)                       
  | |   _ __  | |_  ___   _ __  _ __ ___    __ _ | |_  _   ___   _ __           
  | |  | '_ \ |  _|/ _ \ | '__|| '_ ` _ \  / _` || __|| | / _ \ | '_ \          
  | |_ | | | || | | (_) || |   | | | | | || (_| || |_ | || (_) || | | | _  _  _ 
|_____||_| |_||_|  \___/ |_|   |_| |_| |_| \__,_| \__||_| \___/ |_| |_|(_)(_)(_)
^&|<>%()

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
@echo off
color 0A
SETLOCAL ENABLEDELAYEDEXPANSION
 
 
del "%~dpn0_2.bat" 2> nul
for /f "delims=" %%a in (%~dp0Figlet.txt) do (
	set "var=%%~a"
	set var=!var:^^=^^^^!
	set var=!var:^&=^^^&!
	set var=!var:^<=^^^<!
	set var=!var:^>=^^^>!
	set var=!var:^|=^^^|!
	set var=!var:^(=^^^(!
	set var=!var:^)=^^^)!
	set var=!var:%%=%%%%!
 
	echo echo !var!
)>>"%~dpn0_2.bat"
 
call %~dpn0_2.bat
 
pause

Seul le % semble poser problème

Je pense que c'est pas mal pour commencer :D

EDIT : C'est corrigé pour le %, c'est un coquin
Et Bienvenue dans l'enfer du batch

Il ne restera que le caractère ! apparemment.
Je laisse @hackoofr l’échapper à la liste si il le souhaite :P

:salut:
Voici une version avec glisser et déposer du fichier texte en question :king:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
@echo off
Title Generate ASCII ART with drag and drop a text file
SetLocal EnabledelayedExpansion
If ["%~1"] EQU [""] Goto :Help
color 0A
echo @echo off ^& color 0A ^& Title ASCII ART>"%~n1_Ascii_Art_Gen.bat"
for /f "tokens=* delims=" %%a in ('Type "%~1"') do (
    set "Line=%%~a"
    set Line=!Line:^^=^^^^!
    set Line=!Line:^&=^^^&!
    set Line=!Line:^<=^^^<!
    set Line=!Line:^>=^^^>!
    set Line=!Line:^|=^^^|!
    set Line=!Line:^(=^^^(!
    set Line=!Line:^)=^^^)!
    set Line=!Line:%%=%%%%!
    echo echo. !Line! >> "%~n1_Ascii_Art_Gen.bat"
)
echo pause>>"%~n1_Ascii_Art_Gen.bat"
Start "" "%~n1_Ascii_Art_Gen.bat"
EXIt /b
::---------------------
:Help
Color 0C
echo( & echo( You should Drag and Drop a txt file over this batch script "%~nx0"
TimeOut /T 5 /NoBreak>nul
Exit /B
::---------------------

Merci hackoofr et ericlm128,

pour avoir répondu à mon problème. Merci encore de votre soutien.