[AC-2016] Comment programmer l'ouverture de l'explorateur Windows

Comment programmer l'ouverture de l'explorateur Windows

Bonjour à tous
J'aimerai transformer ce code pour qu'il ouvre seulement l'explorateur (afin de choisir moi même le fichier) , comment faire :

Code:

oApp.Workbooks.Open ("X:\fichier\Réunion\Tableau.xlsx")

car la partie "fichier" est souvent modifiée et dans ce cas ca bug sur le chemin d’accès...

Dans mon code j'ai aussi cette ligne qui pose aussi la même question :

Code:

Set xlBook = xlApp.Workbooks.Open("X:\fichier\Réunion\Tableau.xlsx"")

Pour info : c'est un code qui me permet de transférer des données d'access vers un tableau excel en appuyant sur un bouton.

Merci d'avance pour votre aide
Mamanhou

Salut,

tu pas la possibilité d'utiliser FileDialog
https://docs.microsoft.com/fr-fr/off...ion.filedialog

Bonjour,

J'ai ceci en magasin :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Function DesigneFichier(FichierDefaut As String, TypeFichier As String) As String
' Renvoi le choix de l'utilisateur ou une chaîne vide
' FichierDefaut peut être rien (!), un lieu seul ou avec nom de fichier
' Il faut cocher Microsoft Office x Object Library
 
    DesigneFichier = ""
 
    ' Paramètres
    Application.FileDialog(msoFileDialogFilePicker).AllowMultiSelect = False ' Un seul (Allow user to make multiple selections in dialog box)
    Application.FileDialog(msoFileDialogFilePicker).Title = "Désigner le fichier " & TypeFichier ' Set the title of the dialog box.
    Application.FileDialog(msoFileDialogFilePicker).InitialFileName = FichierDefaut ' Lieu d'ouverture de la boite
 
    ' Clear out the current filters, and add our own.
    Application.FileDialog(msoFileDialogFilePicker).Filters.Clear
    Select Case TypeFichier
    Case Is = "Excel"
        Application.FileDialog(msoFileDialogFilePicker).Filters.Add "Excel", "*.xls;*.xlsx;*.xlsm"
    Case Is = "Access"
        Application.FileDialog(msoFileDialogFilePicker).Filters.Add "Access", "*.mdb;*.accdb;*.bpu"
    End Select
    Application.FileDialog(msoFileDialogFilePicker).Filters.Add "All Files", "*.*"
 
    ' Show the dialog box. If the .Show method returns True, the
    ' user picked at least one file. If the .Show method returns
    ' False, the user clicked Cancel.
    If Application.FileDialog(msoFileDialogFilePicker).Show = True Then
        DesigneFichier = Application.FileDialog(msoFileDialogFilePicker).SelectedItems(1)
    End If
 
End Function

J'avais récupéré ceci quelque part sur internet. D'habitude, je met le lien en commentaire, mais là j'ai oublié.

Merci à vous pour vos réponses. Je vais étudier ça...

Amicalement
Mamanhou