Récuperer adresse MAC ou nom de l'hôte

Version imprimable

21/02/2019, 20h32
FLSORT

Récuperer adresse MAC ou nom de l'hôte
Bonjour, j'essaie de récuperer l'adresse MAC et/ou nom d'hôte de l'ordinateur via commandes, jusque la tout fonctionne, mais j'essaie de supprimer dans le .txt généré :" Nom de l'h“te . . . . . . . . . . : ", j'utilise un .bat avec ces commandes :
Code:

1 2 3 for /F "delims=," %%i in ('ipconfig /all^|find "Adresse physique"') do set MAC=%%i echo %MAC% > mac.txt
mais cela ne marche pas, j'essaie depuis environ deux jours sans vraiment trouver de solution, j'ai essayé d'adapter d'autres codes pour l'adresse MAC mais je n'ai pas réussi.
Il me suffit juste d'obtenir l'adresse MAC seule dans un .txt

Bonjour,

Ton approche n'est pas bonne, IPCONFIG /ALL liste toutes les cartes présentes sur le pc, il peut y en avoir des dizaines (physiques ou virtuelles), comment vas-tu filtrer la carte dont tu désires l'adresse MAC ?

Je te suggère l'utilisation de WMIC, tu pourras filtrer facilement les cartes "parasites" pour obtenir le bon résultat.

Voilà la commande pour lister toutes tes cartes réseau : wmic nic get MACAddress,ProductName

Voilà la commande pour lister et trier pour n'obtenir que les cartes intéressantes :

Code:

wmic nic get MACAddress,ProductName | findstr /v "ISATAP Miniport bouclage Apple Teredo VirtualBox TAP- RAS"

Il suffit de mettre cette commande dans une boucle FOR /F pour récupérer l'adresse MAC dans une variable :
Code:

1 2 3 4 5 6 7 8 9 10 11 @echo off Setlocal EnableExtensions EnableDelayedExpansion chcp 1252 >nul set compteur=0 for /f "skip=1 tokens=1,2" %%A in ('wmic nic get MACAddress^,ProductName^| findstr /v "ISATAP Miniport bouclage Apple Teredo VirtualBox TAP- RAS"') do ( set /a compteur+=1 if !compteur! EQU 1 (set MAC=%%A) ) echo.Adresse MAC de la première carte listée : !MAC! echo. & pause

:salut:
Voici un petit exemple pour récupérer (LAN IP) , (WAN IP) et MAC Adresse ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
@echo off
Title Get (LAN ,Public) (IP) and MAC Addresses by Hackoo 2017
mode con cols=80 lines=5 & Color 9E
echo( & echo(
echo   Please Wait a While ... Searching for (LAN ,Public)(IP) and MAC addresses ...
Set "LogFile=%~dpn0.txt"
@for /f "delims=[] tokens=2" %%a in ('ping -4 -n 1 %ComputerName% ^| findstr [') do (
    set "LAN_IP=%%a"
)
 
for /f "tokens=3 delims== " %%A in (
  'nslookup -debug myip.opendns.com. resolver1.opendns.com 2^>NUL^|find "internet address"'
) Do set ExtIP=%%A
 
 
@For /f %%a in ('getmac /NH /FO Table') do  (
    @For /f %%b in ("%%a") do (
        If /I NOT "%%b"=="N/A" (
            Set "MY_MAC=%%b"
        )
    )
)
    Cls 
    echo(
    echo                My Private LAN IP       : %LAN_IP%
    echo                My External Public IP   : %ExtIP%
    echo                MAC Address             : %MY_MAC%
 
(
    echo My Private LAN IP      : %LAN_IP%
    echo My External Public IP  : %ExtIP%
    echo MAC Address            : %MY_MAC%
 
)>"%LogFile%"
Timeout /T 5 /NoBreak>nul
Start "" "%LogFile%"

24/02/2019, 03h14
FLSORT

Merci à vous pour vous réponses !
ça marche, je pense maintenant envoyer ceci dans un ftp avec une commande ls %MAC% avec l'application portable WinSCP.com mais j'ai quelques problèmes cependant...
24/02/2019, 09h26
barnabe0057

Je ne vois pas le rapport entre la commande LS et l'adresse MAC.
Si tu veux envoyer quelque chose sur le FTP ce n'est pas la commande LS qu'il faut utiliser.