Uniquement certains jeudis !

Bonjour à tous et toutes
On me demande d'afficher le dernier jeudi de chaque mois pour une durée indéterminée
Disons jusqu'en 2022
Au format jeudi 27 septembre
Et tout ça sur Excel
Auriez vous la formule magique par hasard ???

Tu mets en A1 la date du prochain jeudi (par exemple 27/09/2018).
Tu mets en A2 la formule =A1+7.
Tu mets ces deux cellules au format nombre jjjj jj mmmm.
Tu copies A2 vers la droite autant que nécessaire.

Nan nan, il me faut le DERNIER jeudi de CHAQUE mois
Sinon trop facile 😁

Tu mets en A1 01/01/2018 (ou le premier jour d'un autre mois de ton choix).
Tu mets en A2 =MOIS.DECALER(A1;1). Tu copies A2 vers le bas autant que nécessaire.
Tu mets en B1 =$A1-JOURSEM($A1;15). Tu copies B1 vers le bas autant que nécessaire.

En une fois :
Mettre 25/01/18 en A1
Mettre en A2 =FIN.MOIS(A1;1)-JOURSEM(FIN.MOIS(A1;1);14)+1. Copier A2 vers le bas.

Bonjour,
Voici une solution pour les versions d'Excel pour Office 365, Excel pour Office 365 pour Ma,c Excel 2019, Excel 2016, Plus...
Si en A1 on a un jour quelconque du mois cherché ( le 1er du mois sur la figure ci-dessous avec le format mmmm aaaa), écrire la formule (en B1 sur la même figure) :

Code:

---

=FIN.MOIS(A1;0)-JOURSEM(FIN.MOIS(A1;0);15)*(JOURSEM(FIN.MOIS(A1;0);15)<>7)

---

Pièce jointe 415145

Si en A1 on a déjà le dernier jeudi d'un mois ( 27 septembre sur la figure suivante) et que l'on veut les derniers jeudis des mois suivants à la suite, on peut modifier la formule précédente en B1:

Code:

---

=FIN.MOIS(A1;1)-JOURSEM(FIN.MOIS(A1;1);15)*(JOURSEM(FIN.MOIS(A1;1);15)<>7)

---

et la recopier vers la droite
Pièce jointe 415148

Si vous avez une version d'Excel antérieures à celles citées, dites le et on modifiera la formule.
Cordialement
Claude
Oups ! Salut Menhir ! Plus rapide que moi et tu donnes, je pense, une formule bonne pour toutes les versions.

Moi aussi j'étais parti instinctivement sur le paramètre 15 de JOUR.SEM (voir la première solution proposée) mais je me suis aperçu que c'était plus simple en prenant le paramètre 14 (voir seconde solution).

Bonjour,

Dans n'importe quelle cellule tu mets :

Code:

---

=FIN.MOIS(DATEVAL("01/01/2018");LIGNES($1:1)-1)-MOD(JOURSEM(FIN.MOIS(DATEVAL("01/01/2018");LIGNES($1:1)-1))+2;7)

---

et tu tires vers le bas

ou

Code:

---

=FIN.MOIS(DATEVAL("01/01/2018");COLONNES($A:A)-1)-MOD(JOURSEM(FIN.MOIS(DATEVAL("01/01/2018");COLONNES($A:A)-1))+2;7)

---

et tu tires vers la droite

Remplaces "01/01/2018" par la date de début.