[XL-MAC 2016] action après impression

Bonjour,
Ce qui suit ne fait pas exactement ce qui est souhaité, mais vous permettra certainement de vous faire une idée sur comment y arriver.
Dans l'éditeur, ajouter au niveau de ThisWorkbook cette macro:

Code:

1
2
3
4
5
6
7
8
9
10
Option Explicit
 
Private Sub Workbook_BeforePrint(Cancel As Boolean)
   If Cancel Then
      '--- si impression annulée, ne rien faire
   Else
      '--- indiquer dans la cellule A50 de la feuille qu'elle vient d'être imprimée
      Range("A50") = "Imprimé le " & Format(Now(), "dd/mm/yyyy \à hh\hmm")
   End If
End Sub

et au niveau d'un module ajouter celle-ci:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Option Explicit
 
Sub ListerFeuilles()
   Dim wSh As Worksheet, kR As Long
   ActiveWorkbook.Sheets("Tâches").Select
   Cells.ClearContents        '--- vide la feuille (sans modifier les formatages)
   Range("B1") = "Freins"     '--- réécrire le titre
   kR = 1                     '--- n° de première ligne de la liste
   For Each wSh In Worksheets
      Select Case wSh.Name    '--- selon le nom de la feuille
         Case "Tâches", "Lien"
            '--- ne rien faire (ne pas reprendre dans la liste)
         Case Else
            '--- n° de la ligne suivante
            kR = kR + 1
            '--- ajouter le lien hypetexte en colonne 2
            ActiveSheet.Hyperlinks.Add Anchor:=Cells(kR, 2), _
                                       Address:="", _
                                       SubAddress:="'" & wSh.Name & "'!A1", _
                                       TextToDisplay:=wSh.Name
            '--- ajouter la formule en colonne 3
            Cells(kR, 3).FormulaR1C1 = "=INDIRECT(""'"" & RC[-1] &""'!A50"")"
      End Select
   Next
End Sub

Bonne continuation.