ping DOS sur liste de PC, mettre résultat dans un fichier

Version imprimable

04/12/2016, 17h38
eric0000

ping DOS sur liste de PC, mettre résultat dans un fichier

bonjour

j'ai une liste de machine dans le fichier nomPC.txt

machine1
machine2
machine3
je voudrais faire un ping sur chaque nom de pc et avoir un retour dans un fichier selon la règle suivant :
le PC est allumé, le ping répond , le script écrit dans un fichier resultping.txt "machine1 ok"
Si le pc est éteint le ping ne donne rien, le script écrit à la suite dans le fichier de réponse "machine2 ko"

ce qui donnerait un fichier resultping.txt de ce style

machine1 ok
machine2 ko
machine3 ok

qui peut m'aider à écrire le batch qui convient ?
04/12/2016, 21h19
hackoofr

Multi Ping Tester with colors

:salut:
Je vous poste un batch un peu compliqué, je ne sais pas s'il peut répondre a vos besoin ou non ?
Dans votre cas en changeant la liste des machines dans le fichier URLS.txt , donc c'est à vous de organiser ceci ;)
Multi Ping Tester with colors

https://i.stack.imgur.com/qFXC8.jpg
05/12/2016, 09h01
eric0000

bonjour,
merci pour votre réponse.
j'ai tenté d'adapter le script, mais comme je ne connais pas toutes les commandes qui sont utilisées je n'ai pas réussis à le faire tourner à ma convenance
05/12/2016, 12h45
hackoofr

Citation:

Envoyé par eric0000

bonjour,
merci pour votre réponse.
j'ai tenté d'adapter le script, mais comme je ne connais pas toutes les commandes qui sont utilisées je n'ai pas réussis à le faire tourner à ma convenance

Ok, dans votre fichier ListPC.txt il y a juste les noms des machines ou bien leurs ip ?
05/12/2016, 14h58
eric0000

il n'y a que les noms DNS des ordinateurs

voici le code que j'ai brouilloné
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 @echo off rem parametrage de l'endroit ou se trouve la liste des pc set nomPC=listePC.txt rem parametrage du fichier de resultat set result=resultping.txt rem purge du fichier résultat If exist %result% Del %result% Setlocal EnableDelayedExpansion rem ping avec option -n 1 pour ne pinguer qu'une fois for /f "delims=" %%i in (%nomPC%) do ( ping %%i -n 1 | FIND "TTL=" > nul if errorlevel 1 ( echo %%i ko >> %result% ) else ( echo %%i ok >> %result% ) ) endlocal pause
______________________
en entrée j'ai mis dans listePC.txt

monproprepc
toto
monproprepc
titi

résultat attendu 2 ok puisque je ping ma propre machine et 2 ko puisque qu'il y a 2 noms fantaisistes
voici le contenu de resultping.txt

monproprepc ok
toto ko
monproprepc ok
titi ko

Le script fait donc ce que je demandais au départ. Cependant il est sans doute perfectible. Alors si vous avez des suggestions d'améliorations je suis preneur

:salut:
Testez ce :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
@echo off
Title Multi-Ping hosts Tester with colors by Hackoo 2016
call :init
set "nomPC=listePC.txt"
If Not exist %nomPC% goto error
mode con cols=70 lines=35
set "LogFile=PingResults.txt"
If exist %LogFile% Del %LogFile%
echo(
call :color 0E "      ------- Ping status of targets hosts -------" 1
echo(
(
    echo ******************************************************
    echo   PingTest executed on %Date% @ Time %Time%
    echo ******************************************************
    echo(
) > %LogFile%
Setlocal EnableDelayedExpansion
for /f "usebackq delims=" %%a in ("%nomPC%") do (
    ping -n 1 %%a | find "TTL=" >nul
    if errorlevel 1 (
        call :color 0C " Host %%a not reachable KO" 1 & echo Host %%a not reachable KO >>%LogFile%
    ) else (
        call :color 0A " Host %%a reachable OK" 1 & echo Host %%a reachable OK >>%LogFile%
    )
)
EndLocal
Start "" %LogFile%
pause>nul & exit
::************************************************************************************* 
:init
prompt $g
for /F "delims=." %%a in ('"prompt $H. & for %%b in (1) do rem"') do set "BS=%%a"
exit /b
::*************************************************************************************
:color
set nL=%3
if not defined nL echo requires third argument & pause > nul & goto :eof
if %3 == 0 (
    <nul set /p ".=%bs%">%2 & findstr /v /a:%1 /r "^$" %2 nul & del %2 2>&1 & goto :eof
) else if %3 == 1 (
    echo %bs%>%2 & findstr /v /a:%1 /r "^$" %2 nul & del %2 2>&1 & goto :eof
)
exit /b
::*************************************************************************************
:error
mode con cols=70 lines=3
color 0C
cls
echo(
 echo   ATTENTION !!!  Verifier bien si le fichier "%nomPC%" existe !
pause>nul & exit
::*************************************************************************************

05/12/2016, 21h40
Erik0000

1 pièce(s) jointe(s)

j'ai testé:
ça fonctionne , voici une copie d'écran :
Pièce jointe 227013

ce qui donne dans le fichier texte
******************************************************
PingTest executed on 05/12/2016 @ Time 21:03:37.38
******************************************************

Host Poste not reachable KO
Host PO100926 not reachable KO
Host PO39010 not reachable KO
Host PO39410 not reachable KO
Host PO39436 not reachable KO
Host PO41105 reachable OK
Host PO41123 not reachable KO

Par contre le petit hic c'est qu'une fois arrivé sur la dernière ligne, le programme ne se ferme pas il reste bloqué sur la dernière ligne traitée

Merci en tout cas
05/12/2016, 22h39
hackoofr

Citation:

Envoyé par Erik0000

Le petit hic c'est qu'une fois arrivé sur la dernière ligne, le programme ne se ferme pas il reste bloqué sur la dernière ligne traitée

Juste tu enlèves à la ligne N°29 pause>nul & exit et tu la remplace par exit ;)
Si ton problème est résolu alors n’oublies surtout pas de le marquer comme :resolu: et aussi mon +1 :plusser: :mouarf:
08/02/2017, 17h37
Erik0000

la solution fonctionne merci :-)

j'aurai besoin d'un autre script sur le même thème
* pas d'affichage à l'écran pendant le traitement, pour aller plus vite (des milliers de lignes à traiter)
* tester le ping et retourner nom du pc + IP (même si poste non connecté ) ou le mot "pas d'IP (si poste non trouvé dans DNS) + résultat du ping (Ok / pas OK )
23/02/2017, 16h17
Erik0000

Bonjour

quelqu'un a t-il une solution à la question posée plus tôt ?
28/02/2017, 19h00
ericlm128

Vu l'effort fourni par hackoofr, pour répondre à ton besoin, je pense que tu pourrai considérer la demande initial comme "Résolu".
Les dernières modifications demandées ne sont pas si simple à implémenter.

Peut être recréer un post.
01/03/2017, 11h00
eric0000

fermeture de la discussion

bonjour ericlm128
je ferme cette page en indiquant comme résolu
J'en ouvrirai une autre plus tard
Merci
Eric
07/03/2018, 12h36
Psyhodelik

Un très grand merci pour ce script Hackoo.
J'ai une cinquantaine de serveur a chercher chaque jours, ça va grandement me soulager la tâche !! :)

résultat ping liste pc dans un fichier

voici un script qui prend les postes à scanner dans un fichier texte et met le résultat des ping dans un fichier de sortie :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
@echo off
 
echo debut du traitement...
 
set nomPC=listePC.txt
set result=resultping.csv
 
If exist %result% Del %result%
 
Setlocal EnableDelayedExpansion
 
rem le chiffre derriere -n donne le nombre de tentative de ping
 
for /f "delims=" %%a in (%nomPC%) do (
										set status=KO
										set ip=pas_d'IP
 
										for /f "delims=[] tokens=1,2,3" %%b in ('ping "%%a" -n 4 -4') do (
																									IF NOT "%%b"=="" echo "%%b"|FIND "TTL=">nul 2>nul&&set status=OK
																									IF NOT "%%c"=="" set ip=%%c
																									)
 
										echo %%a
										echo %%a;!status!;!IP!>> %result%
									)
endlocal
 
pause

INFO

le script ac couleurs vérifie simplement que l'IP existe il ne fais pas la différence entre une machine qui répond et celle qui ne répond pas, voici la modification du code

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
@echo off
Title Multi-Ping hosts Tester with colors by Hackoo 2016
call :init
set "nomPC=URLpc.txt"
If Not exist %nomPC% goto error
mode con cols=70 lines=35
set "LogFile=PingResults.txt"
If exist %LogFile% Del %LogFile%
set "%%b=ip"
echo(
call :color 0E "      ------- Ping status of targets hosts -------" 1
echo(
(
    echo ******************************************************
    echo   PingTest executed on %Date% @ Time %Time%
    echo ******************************************************
    echo(
) > %LogFile%
Setlocal EnableDelayedExpansion
for /f "usebackq delims=" %%a in ("%nomPC%") do (
	for /f "tokens=2 delims=[]" %%b in ('ping -n 1 %%a') do set "ip=%%b"
    ping -n 1 %%a | find "TTL=" >nul
    if errorlevel 1 (
        call :color 0C " Host %%a - !ip! - pas connecte KO" 1 & echo Host %%a - %%b - pas connecte KO >>%LogFile%
    ) else (
        call :color 0A "Host %%a - !ip! - connecte OK" 1 & echo Host %%a - %%b - connecte OK >>%LogFile%
    )
)
EndLocal
Start "" %LogFile%
pause>nul & exit
::************************************************************************************* 
:init
prompt $g
for /F "delims=." %%a in ('"prompt $H. & for %%b in (1) do rem"') do set "BS=%%a"
exit /b
::*************************************************************************************
:color
set nL=%3
if not defined nL echo requires third argument & pause > nul & goto :eof
if %3 == 0 (
    <nul set /p ".=%bs%">%2 & findstr /v /a:%1 /r "^$" %2 nul & del %2 2>&1 & goto :eof
) else if %3 == 1 (
    echo %bs%>%2 & findstr /v /a:%1 /r "^$" %2 nul & del %2 2>&1 & goto :eof
)
exit /b
::*************************************************************************************
:error
mode con cols=70 lines=3
color 0C
cls
echo(
 echo   ATTENTION !!!  Verifier bien si le fichier "%nomPC%" existe !
pause>nul & exit
::*************************************************************************************

13/03/2019, 14h37
Psyhodelik

Merci pour la réponse, même 1 an après... Ca va m''être grandement utile ^^
22/07/2019, 14h53
Ptitgillou

Citation:

Envoyé par Psyhodelik

Merci pour la réponse, même 1 an après... Ca va m''être grandement utile ^^

Bonjour,
Ce petit programme me simplifie la vie pour la maintenance de mon parc de caméras... Cependant, je n’arrive pas à créer la liste ou seul le nom de la caméra apparait dans le résultat du test...
J'ai dû louper une étape.
Merci pour votre aide.
Ptitgillou (grand débutant)
02/09/2019, 16h11
Johnny_Guitare

question sur le code

Citation:

Ce petit programme me simplifie la vie pour la maintenance de mon parc de caméras... Cependant, je n’arrive pas à créer la liste ou seul le nom de la caméra apparait dans le résultat du test...
J'ai dû louper une étape.
Merci pour votre aide.
Ptitgillou (grand débutant)

as-tu essayé de créer la liste ac les adresse ip des cameras et si oui cela fonctionne-t-il ??
27/06/2023, 19h24
GIPET77

ping DOS d'après liste IP, avec export temps moyen du ping en csv

Bonjour
Je voudrais commissionner les connexions IP en classant les temps de réponse au ping ?
Le batch fait ici répond parfaitement, il manque jusque la variable moyenne temps que je voudrais mettre dans un csv horodaté du genre 22/12/31 17:50 192.168.0.1 7ms
Si le temps dépasse un seuil, ce la révèle une saturation de bande passante ou autre => génération alarme.
Est ce réaliste, et n'étant pas informaticien, je n'arrive pas à modifier le script ci-dessous qui me parait une excellente base.
merci d'avance pour votre aide