[Batch] Comment faire cette boucle ?

Comment faire cette boucle ?

:salut:
Je souhaite faire cette commande dans une boucle for...loop
J'ai par exemples 10 fichiers nommés comme suit 1.reg - 2.reg - 3.reg - 4.reg ......- 10.reg
Donc le nombre maximale je le connais est 10.
Ma question comment je peux faire cette commande dans une boucle for :

Code:

Copy 1.reg+2.reg+3.reg+4.reg+5.reg+6.reg+7.reg+8.reg+9.reg+10.reg All.reg

Salut,
Je ne comprend pas trop ta commande.
Tu cherches à copier tout les .reg quelque part?
Si oui, est-ce qu'une boucle avec un DIR qui recherche tout les .reg suffit?
Code:

1 2 3 4 5 6 7 @echo off&cls for /f "tokens=*" %%a in ('dir /b /s "*.reg"') do ( echo Copy "%%a" ) pause exit

Citation:

Envoyé par devilsnake88

Salut,
Je ne comprend pas trop ta commande.
Tu cherches à copier tout les .reg quelque part?
Si oui, est-ce qu'une boucle avec un DIR qui recherche tout les .reg suffit?

:merci: pour votre réponse
Ce que je cherche vraiment est de regrouper le contenu de tous les fichiers dans un seul fichier All_Keys.reg ;)

J'ai trouvé mon bonheur et je vous le partage :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
@echo off
Title Exporting some reg keys into one file.reg by Hackoo 2016
Set ArrayKeys="HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"^
^ "HKCU\Software\Microsoft\Windows\CurrentVersion\Run"^
^ "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon"^
^ "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options"^
^ "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"^
^ "HKEY_CLASSES_ROOT\exefile\shell\open\command"^
^ "HKEY_CLASSES_ROOT\comfile\shell\open\command"^
^ "HKEY_CLASSES_ROOT\batfile\shell\open\command"^
^ "HKEY_CLASSES_ROOT\vbsfile\shell\open\command"^
^ "HKEY_CLASSES_ROOT\vbefile\shell\open\command"^
^ "HKEY_CLASSES_ROOT\piffile\shell\open\command"^
^ "HKLM\Software\Microsoft\Active Setup\Installed Components"
Set "Count=0"
setlocal ENABLEDELAYEDEXPANSION
For %%K in (%ArrayKeys%) Do ( 
    Set /a "count+=1"
    set "Key[!Count!]=%%K"
)
 
for /L %%i in (1,1,%Count%) Do (
    Call :Display !Key[%%i]!
    Reg Export !Key[%%i]! %tmp%\%%i.reg /y>nul 2>&1
)
 
If Exist %~dp0All_Keys.reg Del %~dp0All_Keys.reg
 
for /L %%i in (1,1,%Count%) Do (
    type %tmp%\%%i.reg>>%~dp0All_Keys.reg
)
Del %tmp%\*.reg
Call :Explorer "%~dp0All_Keys.reg"
exit /b
::************************************
:Explorer <file>
explorer.exe /e,/select,"%~1"
Goto :EOF
::************************************
:Display <key>
mode con cols=90 lines=4
Cls & Color 0A
echo(
echo    Exporting the key "%~1" ...
Timeout /T 1 /Nobreak>nul
goto :eof
::**************************************

Le problème est :resolu: